Buildings.Templates.Components.Data
Records for design and operating parameters
Information
This package provides records for design and operating parameters.
Extends from Modelica.Icons.MaterialPropertiesPackage (Icon for package containing property classes).
Package Content
| Name | Description |
|---|---|
 Chiller
|
Record for chiller model |
| Coil
|
Record for coil model |
| Damper
|
Record for damper model |
| Fan
|
Record for fan model |
| HeatPump
|
Record for heat pump model |
| PumpMultiple
|
Record for multiple-pump models |
| PumpSingle
|
Record for single pump model |
| Valve
|
Record for valve model |
Buildings.Templates.Components.Data.Chiller
Record for chiller model
Information
This record provides the set of sizing and operating parameters for
the classes within
Buildings.Templates.Components.Chillers.
It is composed of a set of parameters corresponding to the design
(selection) conditions and a sub-record per providing
the chiller performance data.
The design capacity is used to parameterize the chiller model.
The capacity (and power) computed from the external performance data file
is automatically scaled by the chiller model to match the value provided
at design conditions.
Note that the design value for condenser cooling fluid (e.g., condenser water) mass flow rate is only required for water-cooled chillers. Air-cooled chillers use a default outdoor air flow assignment since the chiller model doesn't explicitly calculate fan power based on outdoor air flow and condenser pressure drop. Instead, fan power is integrated into the chiller power computed from the performance data. This is because both US (AHRI Standard 550/590) and European (EN14511) chiller performance rating standards incorporate fan power into the rated total input power.
Extends from Modelica.Icons.Record (Icon for records).
Contents
| Type | Name | Default | Description |
|---|---|---|---|
| Generic | per | per(mCon_flow_nominal=mCon_f... | Cooling performance data |
| Power | P_min | 0 | Minimum power when system is enabled with compressor cycled off [W] |
| Configuration | |||
| Chiller | typ | Type of chiller | |
| Nominal condition | |||
| MassFlowRate | mChiWat_flow_nominal | CHW mass flow rate [kg/s] | |
| MassFlowRate | mCon_flow_nominal | Condenser cooling fluid (e.g. CW) mass flow rate [kg/s] | |
| HeatFlowRate | cap_nominal | Cooling capacity [W] | |
| PressureDifference | dpChiWat_nominal | CHW pressure drop [Pa] | |
| PressureDifference | dpCon_nominal | Condenser cooling fluid pressure drop [Pa] | |
| Temperature | TChiWatSup_nominal | CHW supply temperature [K] | |
| Temperature | TCon_nominal | Condenser entering or leaving fluid temperature (depending on per.use_TConOutForTab) [K] | |
Modelica definition
record Chiller
"Record for chiller model"
extends Modelica.Icons.Record;
parameter Buildings.Templates.Components.Types.Chiller typ
"Type of chiller";
parameter Modelica.Units.SI.MassFlowRate mChiWat_flow_nominal(
final min=0)
"CHW mass flow rate";
parameter Modelica.Units.SI.MassFlowRate mCon_flow_nominal(
start=if typ == Buildings.Templates.Components.Types.Chiller.WaterCooled
then mChiWat_flow_nominal elseif typ == Buildings.Templates.Components.Types.Chiller.AirCooled
then Buildings.Templates.Data.Defaults.ratMFloAirByCapChi * abs(cap_nominal)
else 0,
final min=0)
"Condenser cooling fluid (e.g. CW) mass flow rate";
parameter Modelica.Units.SI.HeatFlowRate cap_nominal
"Cooling capacity";
parameter Modelica.Units.SI.PressureDifference dpChiWat_nominal(
final min=0,
start=Buildings.Templates.Data.Defaults.dpChiWatChi)
"CHW pressure drop";
parameter Modelica.Units.SI.PressureDifference dpCon_nominal(
final min=0,
start=if typ == Buildings.Templates.Components.Types.Chiller.WaterCooled
then Buildings.Templates.Data.Defaults.dpConWatChi
elseif typ == Buildings.Templates.Components.Types.Chiller.AirCooled
then Buildings.Templates.Data.Defaults.dpAirChi else 0)
"Condenser cooling fluid pressure drop";
parameter Modelica.Units.SI.Temperature TChiWatSup_nominal(
final min=260)
"CHW supply temperature";
parameter Modelica.Units.SI.Temperature TCon_nominal(
final min=273.15)
"Condenser entering or leaving fluid temperature (depending on per.use_TConOutForTab)";
replaceable parameter Buildings.Fluid.Chillers.ModularReversible.Data.TableData2DLoadDep.Generic
per(
mCon_flow_nominal=mCon_flow_nominal,
mEva_flow_nominal=mChiWat_flow_nominal,
dpCon_nominal=dpCon_nominal,
dpEva_nominal=dpChiWat_nominal,
tabLowBou=[
TCon_nominal - 30, TChiWatSup_nominal - 2;
TCon_nominal + 10, TChiWatSup_nominal - 2],
devIde="") constrainedby Buildings.Fluid.Chillers.ModularReversible.Data.TableData2DLoadDep.Generic
"Cooling performance data";
parameter Modelica.Units.SI.Power P_min(final min=0)=0
"Minimum power when system is enabled with compressor cycled off";
end Chiller;
Buildings.Templates.Components.Data.Coil
Record for coil model
Information
This record provides the set of sizing parameters for the classes within Buildings.Templates.Components.Coils.
Extends from Modelica.Icons.Record (Icon for records).
Contents
| Type | Name | Default | Description |
|---|---|---|---|
| Carrier_Centurion_50PG06 | datCoi | redeclare parameter Building... | Performance data record of evaporator coil |
| Configuration | |||
| Coil | typ | Equipment type | |
| Valve | typVal | Type of valve | |
| Nominal condition | |||
| MassFlowRate | mAir_flow_nominal | Air mass flow rate [kg/s] | |
| PressureDifference | dpAir_nominal | Air pressure drop [Pa] | |
| MassFlowRate | mWat_flow_nominal | Liquid mass flow rate [kg/s] | |
| PressureDifference | dpWat_nominal | Liquid pressure drop across coil [Pa] | |
| PressureDifference | dpValve_nominal | Liquid pressure drop across fully open valve [Pa] | |
| HeatFlowRate | cap_nominal | Coil capacity [W] | |
| Temperature | TWatEnt_nominal | Nominal entering liquid temperature [K] | |
| Temperature | TAirEnt_nominal | Nominal entering air temperature [K] | |
| MassFraction | wAirEnt_nominal | Nominal entering air humidity ratio [1] | |
Modelica definition
record Coil "Record for coil model"
extends Modelica.Icons.Record;
parameter Buildings.Templates.Components.Types.Coil typ
"Equipment type";
parameter Buildings.Templates.Components.Types.Valve typVal
"Type of valve";
/*
For evaporator coils this is also provided by the performance data record.
The coil model shall generate a warning in case the design value exceeds
the maximum value from the performance data record.
*/
parameter Modelica.Units.SI.MassFlowRate mAir_flow_nominal(
final min=0,
start=if typ==Buildings.Templates.Components.Types.Coil.EvaporatorMultiStage or
typ==Buildings.Templates.Components.Types.Coil.EvaporatorVariableSpeed then
datCoi.sta[datCoi.nSta].nomVal.m_flow_nominal
else 1)
"Air mass flow rate";
parameter Modelica.Units.SI.PressureDifference dpAir_nominal(
final min=0,
displayUnit="Pa",
start=if typ==Buildings.Templates.Components.Types.Coil.None then 0 else
100)
"Air pressure drop";
parameter Modelica.Units.SI.MassFlowRate mWat_flow_nominal(
final min=0,
start=if typ==Buildings.Templates.Components.Types.Coil.WaterBasedHeating then
Q_flow_nominal / 4186 / 10 elseif
typ==Buildings.Templates.Components.Types.Coil.WaterBasedCooling then
-Q_flow_nominal / 4186 / 5 else
0)
"Liquid mass flow rate";
parameter Modelica.Units.SI.PressureDifference dpWat_nominal(
final min=0,
displayUnit="Pa",
start=if typ==Buildings.Templates.Components.Types.Coil.WaterBasedHeating then
0.5e4 elseif typ==Buildings.Templates.Components.Types.Coil.WaterBasedCooling then
3e4 else
0)
"Liquid pressure drop across coil";
parameter Modelica.Units.SI.PressureDifference dpValve_nominal(
final min=0,
displayUnit="Pa",
start=if typVal==Buildings.Templates.Components.Types.Valve.None then 0
else dpWat_nominal / 2)
"Liquid pressure drop across fully open valve";
parameter Modelica.Units.SI.HeatFlowRate cap_nominal(
start=if typ==Buildings.Templates.Components.Types.Coil.None then 0
elseif typ==Buildings.Templates.Components.Types.Coil.EvaporatorMultiStage or
typ==Buildings.Templates.Components.Types.Coil.EvaporatorVariableSpeed then
datCoi.sta[datCoi.nSta].nomVal.Q_flow_nominal
elseif typ==Buildings.Templates.Components.Types.Coil.WaterBasedCooling then -1E4
else 1E4)
"Coil capacity";
/*
For evaporator coils this is also provided by the performance data record.
The coil model shall generate a warning in case the design value exceeds
the maximum value from the performance data record.
*/
final parameter Modelica.Units.SI.HeatFlowRate Q_flow_nominal=
if typ==Buildings.Templates.Components.Types.Coil.WaterBasedHeating or
typ==Buildings.Templates.Components.Types.Coil.ElectricHeating then abs(cap_nominal)
else -1 * abs(cap_nominal)
"Nominal heat flow rate";
parameter Modelica.Units.SI.Temperature TWatEnt_nominal(
final min=273.15,
displayUnit="degC",
start=if typ==Buildings.Templates.Components.Types.Coil.WaterBasedHeating then 50+273.15
elseif typ==Buildings.Templates.Components.Types.Coil.WaterBasedCooling then 7+273.15
else 273.15)
"Nominal entering liquid temperature";
parameter Modelica.Units.SI.Temperature TAirEnt_nominal(
final min=243.15,
displayUnit="degC",
start=if typ==Buildings.Templates.Components.Types.Coil.WaterBasedCooling then 30+273.15
else 273.15)
"Nominal entering air temperature";
parameter Modelica.Units.SI.MassFraction wAirEnt_nominal(
final min=0,
start=0.01)
"Nominal entering air humidity ratio";
replaceable parameter Buildings.Fluid.DXSystems.Cooling.AirSource.Data.SingleSpeed.Carrier_Centurion_50PG06
datCoi
constrainedby Buildings.Fluid.DXSystems.Cooling.AirSource.Data.Generic.DXCoil
"Performance data record of evaporator coil";
end Coil;
Buildings.Templates.Components.Data.Damper
Record for damper model
Information
This record provides the set of sizing parameters for the class Buildings.Templates.Components.Actuators.Damper.
Extends from Modelica.Icons.Record (Icon for records).
Contents
| Type | Name | Default | Description |
|---|---|---|---|
| Configuration | |||
| Damper | typ | Equipment type | |
| Nominal condition | |||
| MassFlowRate | m_flow_nominal | Air mass flow rate [kg/s] | |
| PressureDifference | dp_nominal | Air pressure drop [Pa] | |
| PressureDifference | dpFixed_nominal | 0 | Air pressure drop of fixed elements in series with damper [Pa] |
Modelica definition
record Damper "Record for damper model"
extends Modelica.Icons.Record;
parameter Buildings.Templates.Components.Types.Damper typ
"Equipment type";
parameter Modelica.Units.SI.MassFlowRate m_flow_nominal(
final min=0,
start=1)
"Air mass flow rate";
parameter Modelica.Units.SI.PressureDifference dp_nominal(
final min=0,
displayUnit="Pa",
start=if typ==Buildings.Templates.Components.Types.Damper.None then 0
elseif typ==Buildings.Templates.Components.Types.Damper.PressureIndependent then 50
else 15)
"Air pressure drop";
parameter Modelica.Units.SI.PressureDifference dpFixed_nominal(
final min=0,
displayUnit="Pa")=0
"Air pressure drop of fixed elements in series with damper";
end Damper;
Buildings.Templates.Components.Data.Fan
Record for fan model
Information
This record provides the set of sizing parameters for the classes within Buildings.Templates.Components.Fans.
Extends from Modelica.Icons.Record (Icon for records).
Contents
| Type | Name | Default | Description |
|---|---|---|---|
| Generic | per | per(pressure(V_flow={0,1,2}*... | Performance data |
| Configuration | |||
| Fan | typ | Equipment type | |
| Integer | nFan | Number of fans | |
| Nominal condition | |||
| MassFlowRate | m_flow_nominal | Total air mass flow rate [kg/s] | |
| PressureDifference | dp_nominal | Total pressure rise [Pa] | |
Modelica definition
record Fan "Record for fan model"
extends Modelica.Icons.Record;
parameter Buildings.Templates.Components.Types.Fan typ
"Equipment type";
parameter Integer nFan(
final min=0,
start=if typ==Buildings.Templates.Components.Types.Fan.None then 0 else 1)
"Number of fans";
parameter Modelica.Units.SI.MassFlowRate m_flow_nominal(
final min=0,
start=1)
"Total air mass flow rate";
parameter Modelica.Units.SI.PressureDifference dp_nominal(
final min=0,
displayUnit="Pa",
start=if typ==Buildings.Templates.Components.Types.Fan.None then 1
else 500)
"Total pressure rise";
replaceable parameter Buildings.Fluid.Movers.Data.Generic per(
pressure(
V_flow={0, 1, 2} * m_flow_nominal / 1.2 / max(1, nFan),
dp={1.5, 1, 0} * dp_nominal))
constrainedby Buildings.Fluid.Movers.Data.Generic
"Performance data";
end Fan;
Buildings.Templates.Components.Data.HeatPump
Record for heat pump model
Information
This record provides the set of sizing and operating parameters for heat pump models that can be found within Buildings.Templates.Components.HeatPumps.
Performance data
The design capacity is used to parameterize the heat pump model. The capacity (and power) computed from the external performance data file will be scaled to match the value provided at design conditions.
Also note that placeholders values are assigned to some parameters
of the subrecord perCoo which is used to specify
the performance data in cooling mode.
These values should be overwritten for reversible heat pumps.
This overwriting happens automatically when redeclaring or reassigning
the performance record perCoo.
Extends from Modelica.Icons.Record (Icon for records).
Contents
| Type | Name | Default | Description |
|---|---|---|---|
| GenericHeatPump | perHea | perHea(mCon_flow_nominal=mHe... | Performance data in heating mode |
| Generic | perCoo | perCoo(mCon_flow_nominal=mSo... | Performance data in cooling mode |
| Power | P_min | 0 | Minimum power when system is enabled with compressor cycled off [W] |
| Configuration | |||
| HeatPump | typ | Equipment type | |
| Boolean | is_rev | Set to true for reversible heat pumps, false for heating only | |
| SpecificHeatCapacity | cpHeaWat_default | Buildings.Utilities.Psychrom... | HW default specific heat capacity [J/(kg.K)] |
| SpecificHeatCapacity | cpSou_default | if typ == Buildings.Template... | Source fluid default specific heat capacity [J/(kg.K)] |
| Nominal condition | |||
| MassFlowRate | mHeaWat_flow_nominal | HW mass flow rate [kg/s] | |
| PressureDifference | dpHeaWat_nominal | Pressure drop at design HW mass flow rate [Pa] | |
| HeatFlowRate | capHea_nominal | Heating capacity [W] | |
| Temperature | THeaWatSup_nominal | (Highest) HW supply temperature [K] | |
| MassFlowRate | mChiWat_flow_nominal | CHW mass flow rate [kg/s] | |
| HeatFlowRate | capCoo_nominal | Cooling capacity [W] | |
| Temperature | TChiWatSup_nominal | (Lowest) CHW supply temperature [K] | |
| Temperature | TSouHea_nominal | OAT or source fluid supply temperature (evaporator entering) in heating mode [K] | |
| MassFlowRate | mSouWwHea_flow_nominal | Source fluid mass flow rate in heating mode [kg/s] | |
| PressureDifference | dpSouWwHea_nominal | Source fluid pressure drop in heating mode [Pa] | |
| Temperature | TSouCoo_nominal | OAT or source fluid supply temperature (condenser entering) in cooling mode [K] | |
| MassFlowRate | mSouWwCoo_flow_nominal | Source fluid mass flow rate in cooling mode [kg/s] | |
Modelica definition
record HeatPump "Record for heat pump model"
extends Modelica.Icons.Record;
parameter Buildings.Templates.Components.Types.HeatPump typ
"Equipment type";
parameter Boolean is_rev
"Set to true for reversible heat pumps, false for heating only";
// Default fluid properties
parameter Modelica.Units.SI.SpecificHeatCapacity cpHeaWat_default=
Buildings.Utilities.Psychrometrics.Constants.cpWatLiq
"HW default specific heat capacity";
/*
cpChiWat_default is for internal use only.
It is the same as cpChiWat_default for reversible HP.
Non-reversible HP that can be controlled to produce either HW or CHW
shall be modeled with chiller components (as a chiller/heater).
*/
final parameter Modelica.Units.SI.SpecificHeatCapacity cpChiWat_default=
cpHeaWat_default
"CHW default specific heat capacity";
parameter Modelica.Units.SI.SpecificHeatCapacity cpSou_default=
if typ==Buildings.Templates.Components.Types.HeatPump.AirToWater then
Buildings.Utilities.Psychrometrics.Constants.cpAir else
Buildings.Utilities.Psychrometrics.Constants.cpWatLiq
"Source fluid default specific heat capacity";
parameter Modelica.Units.SI.MassFlowRate mHeaWat_flow_nominal(
final min=0)
"HW mass flow rate";
parameter Modelica.Units.SI.PressureDifference dpHeaWat_nominal(
min=0,
start=Buildings.Templates.Data.Defaults.dpChiWatChi)
"Pressure drop at design HW mass flow rate";
parameter Modelica.Units.SI.HeatFlowRate capHea_nominal
"Heating capacity";
parameter Modelica.Units.SI.Temperature THeaWatSup_nominal(
final min=273.15)
"(Highest) HW supply temperature";
final parameter Modelica.Units.SI.Temperature THeaWatRet_nominal=
THeaWatSup_nominal-abs(capHea_nominal)/cpHeaWat_default/mHeaWat_flow_nominal
"HW return temperature";
parameter Modelica.Units.SI.MassFlowRate mChiWat_flow_nominal(
start=0,
final min=0)
"CHW mass flow rate";
final parameter Modelica.Units.SI.PressureDifference dpChiWat_nominal=
dpHeaWat_nominal * (mChiWat_flow_nominal/mHeaWat_flow_nominal)^2
"Pressure drop at design CHW mass flow rate";
parameter Modelica.Units.SI.HeatFlowRate capCoo_nominal(
start=0)
"Cooling capacity";
parameter Modelica.Units.SI.Temperature TChiWatSup_nominal(
start=Buildings.Templates.Data.Defaults.TChiWatSup,
final min=253.15)
"(Lowest) CHW supply temperature";
final parameter Modelica.Units.SI.Temperature TChiWatRet_nominal=
if is_rev then
TChiWatSup_nominal+abs(capCoo_nominal)/cpChiWat_default/mChiWat_flow_nominal
else Buildings.Templates.Data.Defaults.TChiWatRet
"CHW return temperature";
parameter Modelica.Units.SI.Temperature TSouHea_nominal(
start=Buildings.Templates.Data.Defaults.TOutHpHeaLow,
final min=220)
"OAT or source fluid supply temperature (evaporator entering) in heating mode";
parameter Modelica.Units.SI.MassFlowRate mSouWwHea_flow_nominal(
start=mHeaWat_flow_nominal,
final min=0)
"Source fluid mass flow rate in heating mode";
parameter Modelica.Units.SI.PressureDifference dpSouWwHea_nominal(
min=0,
start=Buildings.Templates.Data.Defaults.dpChiWatChi)
"Source fluid pressure drop in heating mode";
final parameter Modelica.Units.SI.MassFlowRate mSouHea_flow_nominal=
if typ==Buildings.Templates.Components.Types.HeatPump.WaterToWater then
mSouWwHea_flow_nominal else
Buildings.Templates.Data.Defaults.ratMFloAirByCapChi * abs(capHea_nominal)
"Source fluid mass flow rate in heating mode";
final parameter Modelica.Units.SI.PressureDifference dpSouHea_nominal=
if typ==Buildings.Templates.Components.Types.HeatPump.WaterToWater then
dpSouWwHea_nominal else Buildings.Templates.Data.Defaults.dpAirChi
"Source fluid pressure drop in heating mode";
parameter Modelica.Units.SI.Temperature TSouCoo_nominal(
start=Buildings.Templates.Data.Defaults.TOutHpCoo,
final min=273.15)
"OAT or source fluid supply temperature (condenser entering) in cooling mode";
parameter Modelica.Units.SI.MassFlowRate mSouWwCoo_flow_nominal(
start=mChiWat_flow_nominal,
final min=0)
"Source fluid mass flow rate in cooling mode";
final parameter Modelica.Units.SI.MassFlowRate mSouCoo_flow_nominal=
if typ==Buildings.Templates.Components.Types.HeatPump.WaterToWater then
mSouWwCoo_flow_nominal else
Buildings.Templates.Data.Defaults.ratMFloAirByCapChi * abs(capCoo_nominal)
"Source fluid mass flow rate in cooling mode";
final parameter Modelica.Units.SI.PressureDifference dpSouCoo_nominal=
dpSouHea_nominal * (mSouCoo_flow_nominal/mSouHea_flow_nominal)^2
"Source fluid pressure drop in cooling mode";
// Propagation of mass flow rate and pressure drop to the subrecords perHea
// and perCoo is for reference only. The mass flow rate and pressure drop in
// the HP component are parameterized by the values from this record,
// not from those subrecords.
replaceable parameter Fluid.HeatPumps.ModularReversible.Data.TableData2DLoadDep.GenericHeatPump
perHea(
mCon_flow_nominal=mHeaWat_flow_nominal,
mEva_flow_nominal=mSouHea_flow_nominal,
dpCon_nominal=dpHeaWat_nominal,
dpEva_nominal=dpSouHea_nominal,
devIde="")
constrainedby Buildings.Fluid.HeatPumps.ModularReversible.Data.TableData2DLoadDep.GenericHeatPump
"Performance data in heating mode";
replaceable parameter Fluid.Chillers.ModularReversible.Data.TableData2DLoadDep.Generic
perCoo(
mCon_flow_nominal=mSouCoo_flow_nominal,
mEva_flow_nominal=mChiWat_flow_nominal,
dpCon_nominal=dpSouCoo_nominal,
dpEva_nominal=dpChiWat_nominal,
fileName="",
PLRSup={1},
tabLowBou=[TSouCoo_nominal-30, TChiWatSup_nominal-2;
TSouCoo_nominal+10, TChiWatSup_nominal-2],
devIde="",
use_TConOutForTab=false,
use_TEvaOutForTab=true)
constrainedby Buildings.Fluid.Chillers.ModularReversible.Data.TableData2DLoadDep.Generic
"Performance data in cooling mode";
parameter Modelica.Units.SI.Power P_min(final min=0)=0
"Minimum power when system is enabled with compressor cycled off";
end HeatPump;
Buildings.Templates.Components.Data.PumpMultiple
Record for multiple-pump models
Information
This record provides the set of sizing and operating parameters for the multiple-pump model Buildings.Templates.Components.Pumps.Multiple.
A default flow characteristic is provided, which goes through the design operating point and spans over 0 and twice the design flow rate at maximum speed. This default characteristic is based on a least squares polynomial fit of the characteristics from Buildings.Fluid.Movers.Data.Pumps.Wilo. The user may refer to the documentation of Buildings.Fluid.HydronicConfigurations.UsersGuide.ModelParameters for further details. Note that a default medium density is used to parameterize the pump characteristic. So models that use this record should overwrite this default value with the density of the medium in use, especially in the case of a water/glycol mix.
In order to modify the default characteristic, one may use either of the following methods.
- Assign the whole subrecord
peror only its componentper.pressure. In this case the elementsper[i]may differ one from another. This is the recommended approach for unequally sized units such as dedicated pumps. - Redeclare the component
per. In this case the elementsper[i]are all equal to the redeclared record instance. This is the recommended approach for equally sized units such as headered pumps.
Those various use cases are illustrated in Buildings.Templates.Components.Validation.PumpMultipleRecord.
Extends from Modelica.Icons.Record (Icon for records).
Contents
| Type | Name | Default | Description |
|---|---|---|---|
| Generic | per[max(nPum, 1)] | per(pressure(V_flow=if typ <... | Performance data - Each pump |
| Density | rho_default | Buildings.Media.Water.d_const | Default medium density [kg/m3] |
| Configuration | |||
| Pump | typ | Equipment type | |
| Integer | nPum | Number of pumps | |
| Nominal condition | |||
| MassFlowRate | m_flow_nominal[nPum] | Mass flow rate - Each pump [kg/s] | |
| PressureDifference | dp_nominal[nPum] | Total pressure rise - Each pump [Pa] | |
Modelica definition
record PumpMultiple "Record for multiple-pump models"
extends Modelica.Icons.Record;
parameter Buildings.Templates.Components.Types.Pump typ
"Equipment type";
parameter Integer nPum(
final min=0,
start=0)
"Number of pumps";
parameter Modelica.Units.SI.MassFlowRate m_flow_nominal[nPum](
each start=1,
each final min=0)
"Mass flow rate - Each pump";
parameter Modelica.Units.SI.PressureDifference dp_nominal[nPum](
each start=0,
each final min=0)
"Total pressure rise - Each pump";
// To avoid missing support for zero-sized record in case of nPum=0 we use max(nPum, 1).
replaceable parameter Fluid.Movers.Data.Generic per[max(nPum, 1)](
pressure(
V_flow=if typ<>Buildings.Templates.Components.Types.Pump.None then
{{0, 1, 2} * m_flow_nominal[i] / rho_default for i in 1:nPum} else [0],
dp=if typ<>Buildings.Templates.Components.Types.Pump.None then
{{1.14, 1, 0.42} * dp_nominal[i] for i in 1:nPum} else [0]))
constrainedby Buildings.Fluid.Movers.Data.Generic
"Performance data - Each pump";
parameter Modelica.Units.SI.Density rho_default=Buildings.Media.Water.d_const
"Default medium density";
end PumpMultiple;
Buildings.Templates.Components.Data.PumpSingle
Record for single pump model
Information
This record provides the set of sizing and operating parameters for the single pump model Buildings.Templates.Components.Pumps.Single.
A default flow characteristic is provided and can be overwritten as described in the documentation of Buildings.Templates.Components.Data.PumpMultiple in the more generic case of multiple units.
Extends from Modelica.Icons.Record (Icon for records).
Contents
| Type | Name | Default | Description |
|---|---|---|---|
| Generic | per | per(pressure(V_flow=if typ <... | Performance data |
| Density | rho_default | Buildings.Media.Water.d_const | Default medium density [kg/m3] |
| Configuration | |||
| Pump | typ | Equipment type | |
| Nominal condition | |||
| MassFlowRate | m_flow_nominal | Mass flow rate [kg/s] | |
| PressureDifference | dp_nominal | Total pressure rise [Pa] | |
Modelica definition
record PumpSingle "Record for single pump model"
extends Modelica.Icons.Record;
parameter Buildings.Templates.Components.Types.Pump typ
"Equipment type";
parameter Modelica.Units.SI.MassFlowRate m_flow_nominal(
start=1,
final min=0)
"Mass flow rate";
parameter Modelica.Units.SI.PressureDifference dp_nominal(
start=0,
final min=0)
"Total pressure rise";
replaceable parameter Buildings.Fluid.Movers.Data.Generic per(
pressure(
V_flow=if typ<>Buildings.Templates.Components.Types.Pump.None then
{0, 1, 2} * m_flow_nominal / rho_default else {0,0,0},
dp=if typ<>Buildings.Templates.Components.Types.Pump.None then
{1.14, 1, 0.42} * dp_nominal else {0,0,0}))
constrainedby Buildings.Fluid.Movers.Data.Generic
"Performance data";
parameter Modelica.Units.SI.Density rho_default=Buildings.Media.Water.d_const
"Default medium density";
end PumpSingle;
Buildings.Templates.Components.Data.Valve
Record for valve model
Information
This record provides the set of sizing parameters for the class Buildings.Templates.Components.Actuators.Valve.
Extends from Modelica.Icons.Record (Icon for records).
Contents
| Type | Name | Default | Description |
|---|---|---|---|
| Configuration | |||
| Valve | typ | Equipment type | |
| Nominal condition | |||
| MassFlowRate | m_flow_nominal | Nominal mass flow rate of fully open valve [kg/s] | |
| PressureDifference | dpValve_nominal | Nominal pressure drop of fully open valve [Pa] | |
| PressureDifference | dpFixed_nominal | 0 | Nominal pressure drop of pipes and other equipment in flow leg [Pa] |
| PressureDifference | dpFixedByp_nominal | dpFixed_nominal | Nominal pressure drop in the bypass line [Pa] |
Modelica definition
record Valve "Record for valve model"
extends Modelica.Icons.Record;
parameter Buildings.Templates.Components.Types.Valve typ
"Equipment type";
parameter Modelica.Units.SI.MassFlowRate m_flow_nominal(
final min=0,
start=1)
"Nominal mass flow rate of fully open valve";
parameter Modelica.Units.SI.PressureDifference dpValve_nominal(
final min=0,
displayUnit="Pa",
start=0)
"Nominal pressure drop of fully open valve";
parameter Modelica.Units.SI.PressureDifference dpFixed_nominal(
final min=0,
displayUnit="Pa")=0
"Nominal pressure drop of pipes and other equipment in flow leg";
parameter Modelica.Units.SI.PressureDifference dpFixedByp_nominal(
final min=0,
displayUnit="Pa")=dpFixed_nominal
"Nominal pressure drop in the bypass line";
end Valve;