Package with example models
Information
This package contains examples for the use of models that can be found in
Buildings.Electrical.AC.ThreePhasesUnbalanced.Lines.
Extends from Modelica.Icons.ExamplesPackage (Icon for packages containing runnable examples).
Package Content
| Name |
Description |
 ACLine
|
Test model for a three-phase unbalanced commercial cable without neutral |
| ACLineMatrix_RL
|
Test model for a three-phase unbalanced inductive-resistive line specified by a Z matrix |
| ACLineMatrix_RLC
|
Test model for a three-phase unbalanced RLC line specified by Z and B matrices |
| ACLineMatrix_RLC_N
|
Test model for a three-phase unbalanced RLC line with neutral cable specified by Z and B matrices |
| ACLineMatrix_RL_N
|
Test model for a three-phase unbalanced inductive-resistive line with neutral cable specified by a Z matrix |
| ACLine_L
|
Test model for a three-phase unbalanced inductive line |
| ACLine_L_N
|
Test model for a three-phase unbalanced inductive line with neutral cable |
| ACLine_N
|
Test model for a three-phase unbalanced commercial cable with neutral |
| ACLine_R
|
Test model for a three-phase unbalanced resistive line |
| ACLine_RL
|
Test model for a three-phase unbalanced inductive-resistive line |
| ACLine_RLC
|
Test model for a three-phase unbalanced RLC line |
| ACLine_RLC_N
|
Test model for a three-phase unbalanced RLC line with neutral cable |
| ACLine_RL_N
|
Test model for a three-phase unbalanced inductive-resistive line with neutral cable |
| ACLine_R_N
|
Test model for a three-phase unbalanced resistive line with neutral cable |
| ACSimpleGrid
|
Test model for a network model for three-phase unbalanced systems without neutral cable |
| ACSimpleGrid_N
|
Test model for a network model for three-phase unbalanced systems with neutral cable |
Test model for a three-phase unbalanced commercial cable without neutral
Information
This example demonstrates how to use a cable model without neutral line
to connect a source to a load.
The model has three resistive loads R1, R2, and R3.
Each load is connected to the source with different configurations,
but the equivalent resistance between each load and the source is the same.
Since the equivalent resistances are the same, each load draws the same current.
Extends from Modelica.Icons.Example (Icon for runnable examples).
Modelica definition
model ACLine
"Test model for a three-phase unbalanced commercial cable without neutral"
extends Modelica.Icons.Example;
Sources.FixedVoltage E(
definiteReference=true,
f=60,
V=480)
"Voltage source";
Loads.Impedance R1(R=10)
"Resistive load 1";
Loads.Impedance R2(R=10)
"Resistive load 2";
Loads.Impedance R3(R=10)
"Resistive load 3";
Line line_1(
l=1000,
P_nominal=2000,
V_nominal=480,
mode=Buildings.Electrical.Types.CableMode.commercial,
redeclare Buildings.Electrical.Transmission.LowVoltageCables.Cu35
commercialCable)
"Cable that connects to load 1";
Line line_2a(
l=500,
P_nominal=2000,
V_nominal=480,
mode=Buildings.Electrical.Types.CableMode.commercial,
redeclare Buildings.Electrical.Transmission.LowVoltageCables.Cu35
commercialCable)
"Cable that connects to load 2";
Line line_2b(
l=500,
P_nominal=2000,
V_nominal=480,
mode=Buildings.Electrical.Types.CableMode.commercial,
redeclare Buildings.Electrical.Transmission.LowVoltageCables.Cu35
commercialCable)
"Cable that connects to load 2";
Line line_3a(
l=2000,
P_nominal=1000,
V_nominal=480,
mode=Buildings.Electrical.Types.CableMode.commercial,
redeclare Buildings.Electrical.Transmission.LowVoltageCables.Cu35
commercialCable)
"Cable that connects to load 3";
Line line_3b(
l=2000,
P_nominal=1000,
V_nominal=480,
mode=Buildings.Electrical.Types.CableMode.commercial,
redeclare Buildings.Electrical.Transmission.LowVoltageCables.Cu35
commercialCable)
"Cable that connects to load 3";
equation
connect(E.terminal, line_1.terminal_n);
connect(line_1.terminal_p, R1.terminal);
connect(E.terminal, line_2a.terminal_n);
connect(line_2a.terminal_p, line_2b.terminal_n);
connect(line_2b.terminal_p, R2.terminal);
connect(E.terminal, line_3a.terminal_n);
connect(E.terminal, line_3b.terminal_n);
connect(line_3a.terminal_p, R3.terminal);
connect(line_3b.terminal_p, R3.terminal);
end ACLine;
Test model for a three-phase unbalanced inductive-resistive line specified by a Z matrix
Information
This example demonstrates how to use an inductive resistive line model to connect
a source to a load. The model is parameterized using the impedance matrix Z.
The model has three loads. The loads represent a short circuit R=0.
The current that flows through the load depends on the resistance of the line.
Extends from Modelica.Icons.Example (Icon for runnable examples).
Modelica definition
model ACLineMatrix_RL
"Test model for a three-phase unbalanced inductive-resistive line specified by a Z matrix"
extends Modelica.Icons.Example;
Sources.FixedVoltage E(
definiteReference=true,
f=60,
V=100*
sqrt(3))
"Voltage source";
Loads.Impedance sc_load1(R=0, L=0)
"Short circuit load";
Loads.Impedance sc_load2(R=0, L=0)
"Short circuit load";
Loads.Impedance sc_load3(R=0, L=0)
"Short circuit load";
Lines.TwoPortMatrixRL Rline_1(
Z11={10,10},
Z12={0,0},
Z13={0,0},
Z22={10,10},
Z23={0,0},
Z33={10,10},
V_nominal=100*
sqrt(3))
"RL line that connects to load 1";
Lines.TwoPortMatrixRL Rline_2a(
Z12={0,0},
Z13={0,0},
Z23={0,0},
Z11=0.5*{10,10},
Z22=0.5*{10,10},
Z33=0.5*{10,10},
V_nominal=100*
sqrt(3))
"RL line that connects to load 2";
Lines.TwoPortMatrixRL Rline_2b(
Z12={0,0},
Z13={0,0},
Z23={0,0},
Z11=0.5*{10,10},
Z22=0.5*{10,10},
Z33=0.5*{10,10},
V_nominal=100*
sqrt(3))
"RL line that connects to load 2";
Lines.TwoPortMatrixRL Rline_3a(
Z12={0,0},
Z13={0,0},
Z23={0,0},
Z11=2*{10,10},
Z22=2*{10,10},
Z33=2*{10,10},
V_nominal=100*
sqrt(3))
"RL line that connects to load 3";
Lines.TwoPortMatrixRL Rline_3b(
Z12={0,0},
Z13={0,0},
Z23={0,0},
Z11=2*{10,10},
Z22=2*{10,10},
Z33=2*{10,10},
V_nominal=100*
sqrt(3))
"RL line that connects to load 3";
equation
connect(E.terminal, Rline_1.terminal_n);
connect(Rline_1.terminal_p, sc_load1.terminal);
connect(E.terminal, Rline_2a.terminal_n);
connect(Rline_2a.terminal_p, Rline_2b.terminal_n);
connect(Rline_2b.terminal_p, sc_load2.terminal);
connect(E.terminal, Rline_3a.terminal_n);
connect(E.terminal, Rline_3b.terminal_n);
connect(Rline_3a.terminal_p, sc_load3.terminal);
connect(Rline_3b.terminal_p, sc_load3.terminal);
end ACLineMatrix_RL;
Test model for a three-phase unbalanced RLC line specified by Z and B matrices
Information
This example demonstrates how to use a RLC line model to connect
a source to a load. The model is parameterized using the impedance matrix Z
and the admittance matrix B.
The example shows two configurations to test a zero and non-zero matrix B.
In the second case the impedance matrix Z has been set to zero.
Therefore, the line model does not have a load connected to it.
Extends from Modelica.Icons.Example (Icon for runnable examples).
Modelica definition
model ACLineMatrix_RLC
"Test model for a three-phase unbalanced RLC line specified by Z and B matrices"
extends Modelica.Icons.Example;
Sources.FixedVoltage E(
definiteReference=true,
f=60,
V=100*
sqrt(3))
"Voltage source";
Loads.Impedance sc_load1(R=0, L=0)
"Short circuit load";
Lines.TwoPortMatrixRLC Rline_1(
Z11={10,10},
Z12={0,0},
Z13={0,0},
Z22={10,10},
Z23={0,0},
Z33={10,10},
V_nominal=100*
sqrt(3),
B12=0,
B13=0,
B23=0,
B11=10,
B22=10,
B33=10)
"RL line that connects to load 1";
Lines.TwoPortMatrixRLC Rline_2(
Z12={0,0},
Z13={0,0},
Z23={0,0},
V_nominal=100*
sqrt(3),
B12=0,
B13=0,
B23=0,
Z11={0,0},
Z22={0,0},
Z33={0,0},
B11=0.1,
B22=0.1,
B33=0.1)
"RL line that connects to load 2";
equation
connect(E.terminal, Rline_1.terminal_n);
connect(Rline_1.terminal_p, sc_load1.terminal);
connect(E.terminal, Rline_2.terminal_n);
end ACLineMatrix_RLC;
Test model for a three-phase unbalanced RLC line with neutral cable specified by Z and B matrices
Information
This example demonstrates how to use a RLC line model with neutral line to connect
a source to a load. The model is parameterized using the impedance matrix Z
and the admittance matrix B.
The example shows two configurations to test a zero and non-zero matrix B.
In the second case the impedance matrix Z has been set to zero.
Therefore, the line model does not have a load connected to it.
Extends from Modelica.Icons.Example (Icon for runnable examples).
Modelica definition
model ACLineMatrix_RLC_N
"Test model for a three-phase unbalanced RLC line with neutral cable specified by Z and B matrices"
extends Modelica.Icons.Example;
Sources.FixedVoltage_N E(
definiteReference=true,
f=60,
V=100*
sqrt(3))
"Voltage source";
Loads.Impedance_N sc_load1(R=0, L=0)
"Short circuit load";
Lines.TwoPortMatrixRLC_N Rline_1(
Z11={10,10},
Z12={0,0},
Z13={0,0},
Z22={10,10},
Z23={0,0},
Z33={10,10},
V_nominal=100*
sqrt(3),
B12=0,
B13=0,
B23=0,
B11=10,
B22=10,
B33=10,
Z14={0,0},
Z24={0,0},
Z34={0,0},
Z44={10,10},
B14=0,
B24=0,
B34=0,
B44=10)
"RL line that connects to load 1";
Lines.TwoPortMatrixRLC_N Rline_2(
Z12={0,0},
Z13={0,0},
Z23={0,0},
V_nominal=100*
sqrt(3),
B12=0,
B13=0,
B23=0,
Z11={0,0},
Z22={0,0},
Z33={0,0},
B11=0.1,
B22=0.1,
B33=0.1,
Z14={0,0},
Z24={0,0},
B14=0,
B24=0,
B34=0,
B44=0.1,
Z34={0,0},
Z44={0,0})
"RL line that connects to load 2";
equation
connect(E.terminal, Rline_1.terminal_n);
connect(E.terminal, Rline_2.terminal_n);
connect(Rline_1.terminal_p, sc_load1.terminal);
end ACLineMatrix_RLC_N;
Test model for a three-phase unbalanced inductive-resistive line with neutral cable specified by a Z matrix
Information
This example demonstrates how to use an inductive resistive line model with neutral line to connect
a source to a load. The model is parameterized using the impedance matrix Z.
The model has three loads. The loads represent a short circuit R=0.
The current that flows through the load depends on the resistance of the line.
Extends from Modelica.Icons.Example (Icon for runnable examples).
Modelica definition
model ACLineMatrix_RL_N
"Test model for a three-phase unbalanced inductive-resistive line with neutral cable specified by a Z matrix"
extends Modelica.Icons.Example;
Sources.FixedVoltage_N E(
definiteReference=true,
f=60,
V=100*
sqrt(3))
"Voltage source";
Loads.Impedance_N sc_load1(R=0, L=0)
"Short circuit load";
Loads.Impedance_N sc_load2(R=0, L=0)
"Short circuit load";
Loads.Impedance_N sc_load3(R=0, L=0)
"Short circuit load";
Lines.TwoPortMatrixRL_N Rline_1(
Z11={10,10},
Z12={0,0},
Z13={0,0},
Z22={10,10},
Z23={0,0},
Z33={10,10},
V_nominal=100*
sqrt(3),
Z14={0,0},
Z24={0,0},
Z34={0,0},
Z44={10,10})
"RL line that connects to load 1";
Lines.TwoPortMatrixRL_N Rline_2a(
Z12={0,0},
Z13={0,0},
Z23={0,0},
Z11=0.5*{10,10},
Z22=0.5*{10,10},
Z33=0.5*{10,10},
V_nominal=100*
sqrt(3),
Z14={0,0},
Z24={0,0},
Z34={0,0},
Z44=0.5*{10,10})
"RL line that connects to load 2";
Lines.TwoPortMatrixRL_N Rline_2b(
Z12={0,0},
Z13={0,0},
Z23={0,0},
Z11=0.5*{10,10},
Z22=0.5*{10,10},
Z33=0.5*{10,10},
V_nominal=100*
sqrt(3),
Z14={0,0},
Z24={0,0},
Z34={0,0},
Z44=0.5*{10,10})
"RL line that connects to load 2";
Lines.TwoPortMatrixRL_N Rline_3a(
Z12={0,0},
Z13={0,0},
Z23={0,0},
Z11=2*{10,10},
Z22=2*{10,10},
Z33=2*{10,10},
V_nominal=100*
sqrt(3),
Z14={0,0},
Z24={0,0},
Z34={0,0},
Z44=2*{10,10})
"RL line that connects to load 3";
Lines.TwoPortMatrixRL_N Rline_3b(
Z12={0,0},
Z13={0,0},
Z23={0,0},
Z11=2*{10,10},
Z22=2*{10,10},
Z33=2*{10,10},
V_nominal=100*
sqrt(3),
Z14={0,0},
Z24={0,0},
Z34={0,0},
Z44=2*{10,10})
"RL line that connects to load 3";
equation
connect(E.terminal, Rline_1.terminal_n);
connect(E.terminal, Rline_2a.terminal_n);
connect(E.terminal, Rline_3a.terminal_n);
connect(E.terminal, Rline_3b.terminal_n);
connect(Rline_3b.terminal_p, sc_load3.terminal);
connect(Rline_3a.terminal_p, sc_load3.terminal);
connect(Rline_2b.terminal_p, sc_load2.terminal);
connect(Rline_1.terminal_p, sc_load1.terminal);
connect(Rline_2a.terminal_p, Rline_2b.terminal_n);
end ACLineMatrix_RL_N;
Test model for a three-phase unbalanced inductive line
Information
This example demonstrates how to use a purely inductive line model to connect
a source to a load.
The model has four different loads. The load sc_load represents
a short circuit R=0. The current that flows through the load depends
on the resistance of the line.
The remaining three loads L1, L2, and L3
are inductive loads. Each load is connected to the source with different configurations,
but the equivalent impedance between each load and the source is the same.
Since the equivalent impedances are the same, each load draws the same current.
Extends from Modelica.Icons.Example (Icon for runnable examples).
Parameters
| Type | Name | Default | Description |
|---|
| Inductance | Lbase | 10/2/Modelica.Constants.pi/60 | Base value for the line inductances [H] |
Modelica definition
model ACLine_L
"Test model for a three-phase unbalanced inductive line"
extends Modelica.Icons.Example;
parameter Modelica.SIunits.Inductance Lbase = 10/2/Modelica.Constants.pi/60
"Base value for the line inductances";
Sources.FixedVoltage E(
definiteReference=true,
f=60,
V=480)
"Voltage source";
Loads.Impedance L1(R=0, L=Lbase)
"Inductive load 1";
Loads.Impedance L2(R=0, L=Lbase)
"Inductive load 2";
Loads.Impedance L3(R=0, L=Lbase)
"Inductive load 3";
Loads.Impedance sc_load(R=0)
"Short circuit load";
Lines.TwoPortInductance Lline_sc(L=6*Lbase)
"Inductive line that connects to the short circuit";
Lines.TwoPortInductance Rline_1(L=3*Lbase)
"Inductive line that connects to load 1";
Lines.TwoPortInductance Rline_2a(L=3*Lbase/2)
"Inductive line that connects to load 2";
Lines.TwoPortInductance Rline_2b(L=3*Lbase/2)
"Inductive line that connects to load 2";
Lines.TwoPortInductance Rline_3a(L=6*Lbase)
"Inductive line that connects to load 3";
Lines.TwoPortInductance Rline_3b(L=6*Lbase)
"Inductive line that connects to load 3";
equation
connect(E.terminal,Lline_sc. terminal_n);
connect(Lline_sc.terminal_p, sc_load.terminal);
connect(E.terminal, Rline_1.terminal_n);
connect(Rline_1.terminal_p,L1. terminal);
connect(E.terminal, Rline_2a.terminal_n);
connect(Rline_2a.terminal_p, Rline_2b.terminal_n);
connect(Rline_2b.terminal_p,L2. terminal);
connect(E.terminal, Rline_3a.terminal_n);
connect(E.terminal, Rline_3b.terminal_n);
connect(Rline_3a.terminal_p,L3. terminal);
connect(Rline_3b.terminal_p,L3. terminal);
end ACLine_L;
Test model for a three-phase unbalanced inductive line with neutral cable
Information
This example demonstrates how to use a purely inductive line model with neutral cable to connect
a source to a load.
The model has four different loads. The load sc_load represents
a short circuit R=0. The current that flows through the load depends
on the resistance of the line.
The remaining three loads L1, L2, and L3
are inductive loads. Each load is connected to the source with different configurations,
but the equivalent impedance between each load and the source is the same.
Since the equivalent impedances are the same, each load draws the same current.
Extends from Modelica.Icons.Example (Icon for runnable examples).
Parameters
| Type | Name | Default | Description |
|---|
| Inductance | Lbase | 10/2/Modelica.Constants.pi/60 | Base value for the line inductances [H] |
Modelica definition
model ACLine_L_N
"Test model for a three-phase unbalanced inductive line with neutral cable"
extends Modelica.Icons.Example;
parameter Modelica.SIunits.Inductance Lbase = 10/2/Modelica.Constants.pi/60
"Base value for the line inductances";
Sources.FixedVoltage_N E(
definiteReference=true,
f=60,
V=480)
"Voltage source";
Loads.Impedance_N L1(R=0, L=Lbase)
"Inductive load 1";
Loads.Impedance_N L2(R=0, L=Lbase)
"Inductive load 2";
Loads.Impedance_N L3(R=0, L=Lbase)
"Inductive load 3";
Loads.Impedance_N sc_load(R=0)
"Short circuit load";
Lines.TwoPortInductance_N Lline_sc(L=6*Lbase, Ln=Lbase)
"Inductive line that connects to the short circuit";
Lines.TwoPortInductance_N Rline_1(L=3*Lbase, Ln=0.5*Lbase)
"Inductive line that connects to load 1";
Lines.TwoPortInductance_N Rline_2a(L=3*Lbase/2, Ln=0.5*Lbase/2)
"Inductive line that connects to load 2";
Lines.TwoPortInductance_N Rline_2b(L=3*Lbase/2, Ln=0.5*Lbase/2)
"Inductive line that connects to load 2";
Lines.TwoPortInductance_N Rline_3a(L=6*Lbase, Ln=Lbase)
"Inductive line that connects to load 3";
Lines.TwoPortInductance_N Rline_3b(L=6*Lbase, Ln=Lbase)
"Inductive line that connects to load 3";
equation
connect(E.terminal, Lline_sc.terminal_n);
connect(E.terminal, Rline_1.terminal_n);
connect(E.terminal, Rline_2a.terminal_n);
connect(E.terminal, Rline_3a.terminal_n);
connect(E.terminal, Rline_3b.terminal_n);
connect(Rline_3b.terminal_p, L3.terminal);
connect(Rline_3a.terminal_p, L3.terminal);
connect(Rline_2b.terminal_p, L2.terminal);
connect(Rline_2a.terminal_p, Rline_2b.terminal_n);
connect(Rline_1.terminal_p, L1.terminal);
connect(Lline_sc.terminal_p, sc_load.terminal);
end ACLine_L_N;
Test model for a three-phase unbalanced commercial cable with neutral
Information
This example demonstrates how to use a cable line model with
neutral to connect a source to a load.
The model has three resistive loads R1, R2, and R3.
Each load is connected to the source with different configurations,
but the equivalent resistance between each load and the source is the same.
Since the equivalent resistances are the same, each load draws the same current.
Extends from Modelica.Icons.Example (Icon for runnable examples).
Modelica definition
model ACLine_N
"Test model for a three-phase unbalanced commercial cable with neutral"
extends Modelica.Icons.Example;
Sources.FixedVoltage_N E(
definiteReference=true,
f=60,
V=480)
"Voltage source";
Loads.Impedance_N R1(R=10)
"Resistive load 1";
Loads.Impedance_N R2(R=10)
"Resistive load 2";
Loads.Impedance_N R3(R=10)
"Resistive load 3";
Line_N line_1(
l=1000,
P_nominal=2000,
V_nominal=480,
mode=Buildings.Electrical.Types.CableMode.commercial,
redeclare Buildings.Electrical.Transmission.LowVoltageCables.Cu35
commercialCable)
"Cable that connects to load 1";
Line_N line_2a(
l=500,
P_nominal=2000,
V_nominal=480,
mode=Buildings.Electrical.Types.CableMode.commercial,
redeclare Buildings.Electrical.Transmission.LowVoltageCables.Cu35
commercialCable)
"Cable that connects to load 2";
Line_N line_2b(
l=500,
P_nominal=2000,
V_nominal=480,
mode=Buildings.Electrical.Types.CableMode.commercial,
redeclare Buildings.Electrical.Transmission.LowVoltageCables.Cu35
commercialCable)
"Cable that connects to load 2";
Line_N line_3a(
l=2000,
P_nominal=1000,
V_nominal=480,
mode=Buildings.Electrical.Types.CableMode.commercial,
redeclare Buildings.Electrical.Transmission.LowVoltageCables.Cu35
commercialCable)
"Cable that connects to load 3";
Line_N line_3b(
l=2000,
P_nominal=1000,
V_nominal=480,
mode=Buildings.Electrical.Types.CableMode.commercial,
redeclare Buildings.Electrical.Transmission.LowVoltageCables.Cu35
commercialCable)
"Cable that connects to load 3";
equation
connect(E.terminal, line_2a.terminal_n);
connect(E.terminal, line_1.terminal_n);
connect(line_1.terminal_p, R1.terminal);
connect(E.terminal, line_3a.terminal_n);
connect(E.terminal, line_3b.terminal_n);
connect(line_2a.terminal_p, line_2b.terminal_n);
connect(line_3a.terminal_p, R3.terminal);
connect(line_3b.terminal_p, R3.terminal);
connect(line_2b.terminal_p, R2.terminal);
end ACLine_N;
Test model for a three-phase unbalanced resistive line
Information
This example demonstrates how to use a resistive line model to connect
a source to a load.
The model has four different loads. The load sc_load represents
a short circuit R=0. The current that flows through the load depends
on the resistance of the line.
The remaining three loads R1, R2, and R3
are resistive loads. Each load is connected to the source with different configurations,
but the equivalent resistance between each load and the source is the same.
Since the equivalent resistances are the same, each load draws the same current.
Extends from Modelica.Icons.Example (Icon for runnable examples).
Modelica definition
model ACLine_R
"Test model for a three-phase unbalanced resistive line"
extends Modelica.Icons.Example;
Sources.FixedVoltage E(
definiteReference=true,
f=60,
V=480)
"Voltage source";
Loads.Impedance R1(R=10)
"Resistive load 1";
Loads.Impedance R2(R=10)
"Resistive load 2";
Loads.Impedance R3(R=10)
"Resistive load 3";
Loads.Impedance sc_load(R=0)
"Short circuit load";
Lines.TwoPortResistance Rline_sc( useHeatPort=false, R=60)
"Resistive line that connects to the short circuit";
Lines.TwoPortResistance Rline_1(R=30)
"Resistive line that connects to load 1";
Lines.TwoPortResistance Rline_2a(R=15)
"Resistive line that connects to load 2";
Lines.TwoPortResistance Rline_2b(R=15)
"Resistive line that connects to load 2";
Lines.TwoPortResistance Rline_3a(R=60)
"Resistive line that connects to load 3";
Lines.TwoPortResistance Rline_3b(R=60)
"Resistive line that connects to load 3";
equation
connect(E.terminal, Rline_sc.terminal_n);
connect(Rline_sc.terminal_p, sc_load.terminal);
connect(E.terminal, Rline_1.terminal_n);
connect(Rline_1.terminal_p, R1.terminal);
connect(E.terminal, Rline_2a.terminal_n);
connect(Rline_2a.terminal_p, Rline_2b.terminal_n);
connect(Rline_2b.terminal_p, R2.terminal);
connect(E.terminal, Rline_3a.terminal_n);
connect(E.terminal, Rline_3b.terminal_n);
connect(Rline_3a.terminal_p, R3.terminal);
connect(Rline_3b.terminal_p, R3.terminal);
end ACLine_R;
Test model for a three-phase unbalanced inductive-resistive line
Information
This example demonstrates how to use a resistive-inductive line model to connect
a source to a load.
The model has three loads load_sc_1, load_sc_2,
and load_sc_3 representing short circuits R=0.
The current that flows through the load depends on the impedance of the line.
Each load is connected to the source with different configurations,
but the equivalent impedance between each load and the source is the same.
Since the equivalent impedances are the same, each load draw the same current.
Note:
The line model RL_3 is the same as RL_2 but it uses
dynamic phasors.
Extends from Modelica.Icons.Example (Icon for runnable examples).
Parameters
| Type | Name | Default | Description |
|---|
| Resistance | Rbase | 3*10 | Base value for the line resistance [Ohm] |
| Inductance | Lbase | Rbase/2/Modelica.Constants.p... | Base value for the line inductance [H] |
Modelica definition
model ACLine_RL
"Test model for a three-phase unbalanced inductive-resistive line"
extends Modelica.Icons.Example;
parameter Modelica.SIunits.Resistance Rbase = 3*10
"Base value for the line resistance";
parameter Modelica.SIunits.Inductance Lbase = Rbase/2/Modelica.Constants.pi/60
"Base value for the line inductance";
Sources.FixedVoltage E(
definiteReference=true,
f=60,
V=100*
sqrt(3))
"Voltage source";
Loads.Impedance load_sc_1(R=0)
"Short circuit 1";
Loads.Impedance load_sc_2(R=0)
"Short circuit 2";
Lines.TwoPortRL RL_2(
R=Rbase,
L=Lbase)
"Resistive-Inductive line connected to short circuit 2";
Lines.TwoPortResistance R_1(R=Rbase)
"Resistance line connected to short circuit 1";
Lines.TwoPortInductance L_1(L=Lbase)
"Inductance line connected to short circuit 1";
Lines.TwoPortRL RL_3(
R=Rbase,
L=Lbase,
mode=Buildings.Electrical.Types.Load.FixedZ_dynamic)
"Dynamic resistive-inductive line connected to short circuit 3";
Loads.Impedance load_sc_3(R=0)
"Short circuit 3";
equation
connect(E.terminal, R_1.terminal_n);
connect(R_1.terminal_p, L_1.terminal_n);
connect(L_1.terminal_p, load_sc_1.terminal);
connect(E.terminal, RL_2.terminal_n);
connect(RL_2.terminal_p, load_sc_2.terminal);
connect(E.terminal, RL_3.terminal_n);
connect(RL_3.terminal_p, load_sc_3.terminal);
end ACLine_RL;
Test model for a three-phase unbalanced RLC line
Information
This example demonstrates how to use an RLC line model to connect
a source to a load.
The model has four different loads. The loads sc_load,
sc_load1, sc_load2, sc_load3 represent
short circuits R=0. The current that flows through the load depends
on the resistance, inductance and capacitance of the line.
The parameter R, L and C are such that at the nominal
frequency fnom = 60 Hz the respective resistance and
reactances are all equal to 10 Ω.
The lines used in this example have a T model (see
Buildings.Electrical.AC.ThreePhasesUnbalanced.Lines.TwoPortRLC).
The equivalent impedance of the line on each phase is equal to
ZEQ = R/2 +jXL/2 + (R/2 +jXL/2)(-jXC)/
(R/2 +jXL/2 -jXC)
that in this case is equal to ZEQ = 15 + j5 Ω.
Given the equivalent impedance of each phase, and a voltage
with an RMS value of 100 V produces a current equal to
I = 6 - j2 A flowing through phase 1.
Notes
(1) Note:
The line model RLCLine_sc is the same as RLCLine_1 but it uses
dynamic phasors.
(2) Note:
The line model RLCLine_2a has a current that is different
from the one passing in RLCLine_1 because the series of two T
line models is different from the sum of the two separate line models.
(3) Note:
The line models RLCLine_3a and RLCLine_3b have currents that are
50% of the other lines because they are in parallel.
Extends from Modelica.Icons.Example (Icon for runnable examples).
Parameters
| Type | Name | Default | Description |
|---|
| Resistance | RBase | 3*10 | Base value for the line resistance [Ohm] |
| Inductance | LBase | RBase/(2*Modelica.Constants.... | Base value for the line inductances [H] |
| Capacitance | CBase | 3*0.1/(2*Modelica.Constants.... | Base value for the line inductances [F] |
Modelica definition
model ACLine_RLC
"Test model for a three-phase unbalanced RLC line"
extends Modelica.Icons.Example;
parameter Modelica.SIunits.Resistance RBase = 3*10
"Base value for the line resistance";
parameter Modelica.SIunits.Inductance LBase = RBase/(2*Modelica.Constants.pi*60)
"Base value for the line inductances";
parameter Modelica.SIunits.Capacitance CBase = 3*0.1/(2*Modelica.Constants.pi*60)
"Base value for the line inductances";
Sources.FixedVoltage E(
definiteReference=true,
f=60,
V=100*
sqrt(3))
"Voltage source";
Loads.Impedance sc_load1(R=0, L=0)
"Short circuit load";
Loads.Impedance sc_load2(R=0, L=0)
"Short circuit load";
Loads.Impedance sc_load3(R=0, L=0)
"Short circuit load";
Loads.Impedance sc_load(R=0, L=0)
"Short circuit load";
Lines.TwoPortRLC RLCLine_sc(
R=RBase,
C=CBase,
L=LBase,
mode=Buildings.Electrical.Types.Load.FixedZ_dynamic,
V_nominal=480)
"RLC line that connects to the short circuit";
Lines.TwoPortRLC RLCLine_1(
R=RBase,
C=CBase,
L=LBase,
V_nominal=480)
"RLC line that connects to load 1";
Lines.TwoPortRLC RLCLine_2a(
V_nominal=480,
R=RBase/2,
L=LBase/2,
C=CBase/2)
"RLC line that connects to load 2";
Lines.TwoPortRLC RLCLine_2b(
V_nominal=480,
R=RBase/2,
L=LBase/2,
C=CBase/2)
"RLC line that connects to load 2";
Lines.TwoPortRLC RLCLine_3a(
R=2*RBase,
L=2*LBase,
V_nominal=480,
C=CBase/2)
"RLC line that connects to load 3";
Lines.TwoPortRLC RLCLine_3b(
R=2*RBase,
L=2*LBase,
V_nominal=480,
C=CBase/2)
"RLC line that connects to load 3";
equation
connect(E.terminal, RLCLine_sc.terminal_n);
connect(RLCLine_sc.terminal_p, sc_load.terminal);
connect(E.terminal, RLCLine_1.terminal_n);
connect(RLCLine_1.terminal_p, sc_load1.terminal);
connect(E.terminal, RLCLine_2a.terminal_n);
connect(RLCLine_2a.terminal_p, RLCLine_2b.terminal_n);
connect(RLCLine_2b.terminal_p, sc_load2.terminal);
connect(E.terminal, RLCLine_3a.terminal_n);
connect(E.terminal, RLCLine_3b.terminal_n);
connect(RLCLine_3a.terminal_p, sc_load3.terminal);
connect(RLCLine_3b.terminal_p, sc_load3.terminal);
end ACLine_RLC;
Test model for a three-phase unbalanced RLC line with neutral cable
Information
This example demonstrates how to use an RLC line model with neutral cable to connect
a source to a load.
The model has four different loads. The loads sc_load,
sc_load1, sc_load2, sc_load3 represent
short circuits R=0. The current that flows through the load depends
on the resistance, inductance and capacitance of the line.
The parameter R, L and C are such that at the nominal
frequency fnom = 60 Hz the respective resistance and
reactances are all equal to 10 Ω.
The lines used in this example have a T model (see
Buildings.Electrical.AC.ThreePhasesUnbalanced.Lines.TwoPortRLC).
The equivalent impedance of the line on each phase is equal to
ZEQ = R/2 +jXL/2 + (R/2 +jXL/2)(-jXC)/
(R/2 +jXL/2 -jXC)
that in this case is equal to ZEQ = 15 + j5 Ω.
Given the equivalent impedance of each phase, and a voltage
with an RMS value of 100 V produces a current equal to
I = 6 - j2 A flowing through phase 1.
Notes
(1) Note:
The line model RLCLine_sc is the same as RLCLine_1 but it uses
dynamic phasors.
(2) Note:
The line model RLCLine_2a has a current that is different
from the one passing in RLCLine_1 because the series of two T
line models is different from the sum of the two separate line models.
(3) Note:
The line models RLCLine_3a and RLCLine_3b have currents that are
50% of the other lines because they are in parallel.
Extends from Modelica.Icons.Example (Icon for runnable examples).
Parameters
| Type | Name | Default | Description |
|---|
| Resistance | RBase | 3*10 | Base value for the line resistance [Ohm] |
| Inductance | LBase | RBase/(2*Modelica.Constants.... | Base value for the line inductances [H] |
| Capacitance | CBase | 3*0.1/(2*Modelica.Constants.... | Base value for the line inductances [F] |
Modelica definition
model ACLine_RLC_N
"Test model for a three-phase unbalanced RLC line with neutral cable"
extends Modelica.Icons.Example;
parameter Modelica.SIunits.Resistance RBase = 3*10
"Base value for the line resistance";
parameter Modelica.SIunits.Inductance LBase = RBase/(2*Modelica.Constants.pi*60)
"Base value for the line inductances";
parameter Modelica.SIunits.Capacitance CBase = 3*0.1/(2*Modelica.Constants.pi*60)
"Base value for the line inductances";
Sources.FixedVoltage_N E(
definiteReference=true,
f=60,
V=100*
sqrt(3))
"Voltage source";
Loads.Impedance_N sc_load1(R=0, L=0)
"Short circuit load";
Loads.Impedance_N sc_load2(R=0, L=0)
"Short circuit load";
Loads.Impedance_N sc_load3(R=0, L=0)
"Short circuit load";
Loads.Impedance_N sc_load(R=0, L=0)
"Short circuit load";
Lines.TwoPortRLC_N RLCLine_sc(
R=RBase,
C=CBase,
L=LBase,
mode=Buildings.Electrical.Types.Load.FixedZ_dynamic,
V_nominal=480,
Rn=RBase,
Cn=CBase,
Ln=LBase)
"RLC line that connects to the short circuit";
Lines.TwoPortRLC_N RLCLine_1(
R=RBase,
C=CBase,
L=LBase,
V_nominal=480,
Rn=RBase,
Cn=CBase,
Ln=LBase)
"RLC line that connects to load 1";
Lines.TwoPortRLC_N RLCLine_2a(
V_nominal=480,
R=RBase/2,
L=LBase/2,
C=CBase/2,
Rn=RBase/2,
Cn=CBase/2,
Ln=LBase/2)
"RLC line that connects to load 2";
Lines.TwoPortRLC_N RLCLine_2b(
V_nominal=480,
R=RBase/2,
L=LBase/2,
C=CBase/2,
Rn=RBase/2,
Cn=CBase/2,
Ln=LBase/2)
"RLC line that connects to load 2";
Lines.TwoPortRLC_N RLCLine_3a(
R=2*RBase,
L=2*LBase,
V_nominal=480,
C=CBase/2,
Rn=2*RBase,
Cn=CBase/2,
Ln=2*LBase)
"RLC line that connects to load 3";
Lines.TwoPortRLC_N RLCLine_3b(
R=2*RBase,
L=2*LBase,
V_nominal=480,
C=CBase/2,
Rn=2*RBase,
Cn=CBase/2,
Ln=2*LBase)
"RLC line that connects to load 3";
equation
connect(RLCLine_2a.terminal_p, RLCLine_2b.terminal_n);
connect(RLCLine_2b.terminal_p, sc_load2.terminal);
connect(RLCLine_3a.terminal_p, sc_load3.terminal);
connect(RLCLine_3b.terminal_p, sc_load3.terminal);
connect(RLCLine_1.terminal_p, sc_load1.terminal);
connect(RLCLine_sc.terminal_p, sc_load.terminal);
connect(E.terminal, RLCLine_sc.terminal_n);
connect(E.terminal, RLCLine_1.terminal_n);
connect(E.terminal, RLCLine_2a.terminal_n);
connect(E.terminal, RLCLine_3a.terminal_n);
connect(E.terminal, RLCLine_3b.terminal_n);
end ACLine_RLC_N;
Test model for a three-phase unbalanced inductive-resistive line with neutral cable
Information
This example demonstrates how to use a resistive-inductive line model with neutral cable to connect
a source to a load.
The model has two loads load_sc_1 and load_sc_2
representing short circuits R=0.
The current that flows through the load depends on the impedance of the line.
Each load is connected to the source with different configurations,
but the equivalent impedance between each load and the source is the same.
Since the equivalent impedances are the same, each load draw the same current.
Extends from Modelica.Icons.Example (Icon for runnable examples).
Parameters
| Type | Name | Default | Description |
|---|
| Resistance | Rbase | 3*10 | Base value for the line resistance [Ohm] |
| Inductance | Lbase | Rbase/2/Modelica.Constants.p... | Base value for the line inductance [H] |
Modelica definition
model ACLine_RL_N
"Test model for a three-phase unbalanced inductive-resistive line with neutral cable"
extends Modelica.Icons.Example;
parameter Modelica.SIunits.Resistance Rbase = 3*10
"Base value for the line resistance";
parameter Modelica.SIunits.Inductance Lbase = Rbase/2/Modelica.Constants.pi/60
"Base value for the line inductance";
Sources.FixedVoltage_N E(
definiteReference=true,
f=60,
V=100*
sqrt(3))
"Voltage source";
Loads.Impedance_N load_sc_1(R=0)
"Short circuit 1";
Loads.Impedance_N load_sc_2(R=0)
"Short circuit 2";
Lines.TwoPortRL_N RL_2(
R=Rbase,
L=Lbase,
Rn=0.5*Rbase,
Ln=0.5*Lbase)
"Resistive-Inductive line connected to short circuit 2";
Lines.TwoPortResistance_N R_1(R=Rbase, Rn=0.5*Rbase)
"Resistance line connected to short circuit 1";
Lines.TwoPortInductance_N L_1(L=Lbase, Ln=0.5*Lbase)
"Inductance line connected to short circuit 1";
equation
connect(RL_2.terminal_p, load_sc_2.terminal);
connect(L_1.terminal_p, load_sc_1.terminal);
connect(L_1.terminal_n, R_1.terminal_p);
connect(R_1.terminal_n, E.terminal);
connect(E.terminal, RL_2.terminal_n);
end ACLine_RL_N;
Test model for a three-phase unbalanced resistive line with neutral cable
Information
This example demonstrates how to use a resistive line model with neutral cable to connect
a source to a load.
The model has four different loads. The load sc_load represents
a short circuit R=0. The current that flows through the load depends
on the resistance of the line.
The remaining three loads R1, R2, and R3
are resistive loads. Each load is connected to the source with different configurations,
but the equivalent resistance between each load and the source is the same.
Since the equivalent resistances are the same, each load draws the same current.
Extends from Modelica.Icons.Example (Icon for runnable examples).
Modelica definition
model ACLine_R_N
"Test model for a three-phase unbalanced resistive line with neutral cable"
extends Modelica.Icons.Example;
Sources.FixedVoltage_N E(
definiteReference=true,
f=60,
V=480)
"Voltage source";
Loads.Impedance_N R1(R=10)
"Resistive load 1";
Loads.Impedance_N R2(R=10)
"Resistive load 2";
Loads.Impedance_N R3(R=10)
"Resistive load 3";
Loads.Impedance_N sc_load(R=0)
"Short circuit load";
Lines.TwoPortResistance_N Rline_sc( useHeatPort=false, R=60,
Rn=20)
"Resistive line that connects to the short circuit";
Lines.TwoPortResistance_N Rline_1(R=30, Rn=10)
"Resistive line that connects to load 1";
Lines.TwoPortResistance_N Rline_2a(R=15, Rn=5)
"Resistive line that connects to load 2";
Lines.TwoPortResistance_N Rline_2b(R=15, Rn=5)
"Resistive line that connects to load 2";
Lines.TwoPortResistance_N Rline_3a(R=60, Rn=20)
"Resistive line that connects to load 3";
Lines.TwoPortResistance_N Rline_3b(R=60, Rn=20)
"Resistive line that connects to load 3";
equation
connect(Rline_sc.terminal_p, sc_load.terminal);
connect(Rline_1.terminal_p, R1.terminal);
connect(Rline_2b.terminal_p, R2.terminal);
connect(Rline_2a.terminal_p, Rline_2b.terminal_n);
connect(Rline_3b.terminal_p, R3.terminal);
connect(Rline_3a.terminal_p, R3.terminal);
connect(E.terminal, Rline_sc.terminal_n);
connect(E.terminal, Rline_1.terminal_n);
connect(E.terminal, Rline_2a.terminal_n);
connect(E.terminal, Rline_3a.terminal_n);
connect(E.terminal, Rline_3b.terminal_n);
end ACLine_R_N;
Test model for a network model for three-phase unbalanced systems without neutral cable
Information
This example demonstrates how to use a network model to connect
a source to a load. In this simple case the network has two nodes
that are connected by a commercial cable without a neutral line.
At the beginning of the simulation, the load consumes power while at the
and it produces power. The voltage at the load at the beginning is lower
than the nominal RMS voltage (480 V), while at the end of the simulation it is higher.
The voltage drop and increase are due to the presence of the cable between
the source and the load.
The network uses cables of the type LowVoltageCable.Cu35 with
a length of 200 m.
The picture below describes the grid topology.
Extends from Modelica.Icons.Example (Icon for runnable examples).
Modelica definition
model ACSimpleGrid
"Test model for a network model for three-phase unbalanced systems without neutral cable"
extends Modelica.Icons.Example;
Network network(
redeclare Buildings.Electrical.Transmission.Grids.TestGrid2Nodes grid,
V_nominal=480)
"Network model that represents the connection between the source and the load";
Loads.Inductive load(
V_nominal=480,
mode=Buildings.Electrical.Types.Load.VariableZ_P_input,
plugPhase3=false)
"Load connected to the network";
Sources.FixedVoltage E(f=60, V=480,
definiteReference=true)
"Voltage source";
Modelica.Blocks.Sources.Ramp load_inputs(
height=5000,
offset=-2000,
duration=0.5,
startTime=0.25)
"Input signal for the power consumption of the loads";
equation
connect(E.terminal, network.terminal[1]);
connect(load.terminal, network.terminal[2]);
connect(load_inputs.y, load.Pow1);
connect(load_inputs.y, load.Pow2);
end ACSimpleGrid;
Test model for a network model for three-phase unbalanced systems with neutral cable
Information
This example demonstrates how to use a network model to connect
a source to a load. In this simple case the network has two nodes
that are connected by a commercial cable with neutral line.
At the beginning of the simulation the load consumes power while at the
and it produces power. The voltage at the load at the beginning is lower
than the nominal RMS voltage (480 V) while at the end of the simulation it is higher.
The voltage drop and increase are due to the presence of the cable between
the source and the load.
The network uses cables of the type LowVoltageCable.Cu35 with
a length of 200 m.
The picture below describes the grid topology.
Extends from Modelica.Icons.Example (Icon for runnable examples).
Modelica definition
model ACSimpleGrid_N
"Test model for a network model for three-phase unbalanced systems with neutral cable"
extends Modelica.Icons.Example;
Network_N network(
redeclare Buildings.Electrical.Transmission.Grids.TestGrid2Nodes grid,
V_nominal=480)
"Network model that represents the connection between the source and the load";
Loads.Inductive_N load(
V_nominal=480,
mode=Buildings.Electrical.Types.Load.VariableZ_P_input,
plugPhase3=false)
"Load connected to the network";
Sources.FixedVoltage_N E(
f=60,
V=480,
definiteReference=true)
"Voltage source";
Modelica.Blocks.Sources.Ramp load_inputs(
height=5000,
offset=-2000,
duration=0.5,
startTime=0.25)
"Input signal for the power consumption of the loads";
equation
connect(E.terminal, network.terminal[1]);
connect(load.terminal, network.terminal[2]);
connect(load_inputs.y, load.Pow1);
connect(load_inputs.y, load.Pow2);
end ACSimpleGrid_N;
Automatically generated Mon Jul 13 14:23:05 2015.
Buildings.Electrical.AC.ThreePhasesUnbalanced.Lines.Examples.ACLine