Buildings.Fluid.Geothermal.Borefields.BaseClasses
Base classes used in Buildings.Fluid.HeatExchangers.Ground
Information
This package contains base classes that are used to construct the models in Buildings.Fluid.Geothermal.Borefields.
Extends from Modelica.Icons.BasesPackage (Icon for packages containing base classes).
Package Content
| Name | Description |
|---|---|
 PartialBorefield
|
Borefield model using single U-tube borehole heat exchanger configuration.Calculates the average fluid temperature T_fts of the borefield for a given (time dependent) load Q_flow |
 Boreholes
|
Package with borehole heat exchangers |
| HeatTransfer
|
Package with ground heat transfer models |
Buildings.Fluid.Geothermal.Borefields.BaseClasses.PartialBorefield
Borefield model using single U-tube borehole heat exchanger configuration.Calculates the average fluid temperature T_fts of the borefield for a given (time dependent) load Q_flow
Information
This model simulates a borefield containing one or multiple boreholes
using the parameters in the borFieDat record.
Heat transfer to the soil is modeled using only one borehole heat exchanger (To be added in an extended model). The fluid mass flow rate into the borehole is divided to reflect the per-borehole fluid mass flow rate. The borehole model calculates the dynamics within the borehole itself using an axial discretization and a resistance-capacitance network for the internal thermal resistances between the individual pipes and between each pipe and the borehole wall.
The thermal interaction between the borehole wall and the surrounding soil is modeled using Buildings.Fluid.Geothermal.Borefields.BaseClasses.HeatTransfer.GroundTemperatureResponse, which uses a cell-shifting load aggregation technique to calculate the borehole wall temperature after calculating and/or read (from a previous calculation) the borefield's thermal response factor.
Extends from Buildings.Fluid.Interfaces.PartialTwoPortInterface (Partial model transporting fluid between two ports without storing mass or energy), Buildings.Fluid.Interfaces.TwoPortFlowResistanceParameters (Parameters for flow resistance for models with two ports).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| replaceable package Medium | PartialMedium | Medium in the component | |
| Time | tLoaAgg | 300 | Time resolution of load aggregation [s] |
| Integer | nCel | 5 | Number of cells per aggregation level |
| Integer | nSeg | 10 | Number of segments to use in vertical discretization of the boreholes |
| Template | borFieDat | Borefield data | |
| PartialBorehole | borHol | redeclare Buildings.Fluid.Ge... | Borehole |
| Nominal condition | |||
| MassFlowRate | m_flow_nominal | borFieDat.conDat.mBorFie_flo... | Nominal mass flow rate [kg/s] |
| PressureDifference | dp_nominal | borFieDat.conDat.dp_nominal | Pressure difference [Pa] |
| Assumptions | |||
| Boolean | allowFlowReversal | true | = false to simplify equations, assuming, but not enforcing, no flow reversal |
| Advanced | |||
| MassFlowRate | m_flow_small | 1E-4*abs(m_flow_nominal) | Small mass flow rate for regularization of zero flow [kg/s] |
| Boolean | forceGFunCalc | false | Set to true to force the thermal response to be calculated at the start instead of checking whether this has been pre-computed |
| Diagnostics | |||
| Boolean | show_T | false | = true, if actual temperature at port is computed |
| Flow resistance | |||
| Boolean | computeFlowResistance | (borFieDat.conDat.dp_nominal... | =true, compute flow resistance. Set to false to assume no friction |
| Boolean | from_dp | false | = true, use m_flow = f(dp) else dp = f(m_flow) |
| Boolean | linearizeFlowResistance | false | = true, use linear relation between m_flow and dp for any flow rate |
| Real | deltaM | 0.1 | Fraction of nominal flow rate where flow transitions to laminar |
| Dynamics | |||
| Conservation equations | |||
| Dynamics | energyDynamics | Modelica.Fluid.Types.Dynamic... | Type of energy balance: dynamic (3 initialization options) or steady state |
| Boolean | dynFil | true | Set to false to remove the dynamics of the filling material. |
| Initialization | |||
| AbsolutePressure | p_start | Medium.p_default | Start value of pressure [Pa] |
| Temperature | TFlu_start[nSeg] | TGro_start | Start value of fluid temperature [K] |
| Soil | |||
| Temperature | TExt0_start | 283.15 | Initial far field temperature [K] |
| Temperature | TExt_start[nSeg] | {if z[i] >= z0 then TExt0_st... | Temperature of the undisturbed ground [K] |
| Filling material | |||
| Temperature | TGro_start[nSeg] | TExt_start | Start value of grout temperature [K] |
| Temperature profile | |||
| Height | z0 | 10 | Depth below which the temperature gradient starts [m] |
| Real | dT_dz | 0.01 | Vertical temperature gradient of the undisturbed soil for h below z0 [K/m] |
Connectors
| Type | Name | Description |
|---|---|---|
| FluidPort_a | port_a | Fluid connector a (positive design flow direction is from port_a to port_b) |
| FluidPort_b | port_b | Fluid connector b (positive design flow direction is from port_a to port_b) |
| replaceable package Medium | Medium in the component | |
| output RealOutput | TBorAve | Average borehole wall temperature in the borefield [K] |
Modelica definition
partial model PartialBorefield
"Borefield model using single U-tube borehole heat exchanger configuration.Calculates the average fluid temperature T_fts of the borefield for a given (time dependent) load Q_flow"
extends Buildings.Fluid.Interfaces.PartialTwoPortInterface(
final m_flow_nominal=borFieDat.conDat.mBorFie_flow_nominal);
extends Buildings.Fluid.Interfaces.TwoPortFlowResistanceParameters(
final dp_nominal=borFieDat.conDat.dp_nominal,
final computeFlowResistance=(borFieDat.conDat.dp_nominal > Modelica.Constants.eps));
replaceable package Medium = Modelica.Media.Interfaces.PartialMedium "Medium in the component";
constant Real mSenFac(min=1)=1
"Factor for scaling the sensible thermal mass of the volume";
// Assumptions
parameter Modelica.Fluid.Types.Dynamics energyDynamics=Modelica.Fluid.Types.Dynamics.DynamicFreeInitial
"Type of energy balance: dynamic (3 initialization options) or steady state";
// Initialization
parameter Medium.AbsolutePressure p_start = Medium.p_default
"Start value of pressure";
// Simulation parameters
parameter Modelica.Units.SI.Time tLoaAgg=300
"Time resolution of load aggregation";
parameter Integer nCel(min=1)=5 "Number of cells per aggregation level";
parameter Integer nSeg(min=1)=10
"Number of segments to use in vertical discretization of the boreholes";
parameter Boolean forceGFunCalc = false
"Set to true to force the thermal response to be calculated at the start instead of checking whether this has been pre-computed";
// General parameters of borefield
parameter Buildings.Fluid.Geothermal.Borefields.Data.Borefield.Template borFieDat "Borefield data";
// Temperature gradient in undisturbed soil
parameter Modelica.Units.SI.Temperature TExt0_start=283.15
"Initial far field temperature";
parameter Modelica.Units.SI.Temperature TExt_start[nSeg]={if z[i] >= z0 then
TExt0_start + (z[i] - z0)*dT_dz else TExt0_start for i in 1:nSeg}
"Temperature of the undisturbed ground";
parameter Modelica.Units.SI.Temperature TGro_start[nSeg]=TExt_start
"Start value of grout temperature";
parameter Modelica.Units.SI.Temperature TFlu_start[nSeg]=TGro_start
"Start value of fluid temperature";
parameter Modelica.Units.SI.Height z0=10
"Depth below which the temperature gradient starts";
parameter Real dT_dz(final unit="K/m", min=0) = 0.01
"Vertical temperature gradient of the undisturbed soil for h below z0";
// Dynamics of filling material
parameter Boolean dynFil=true
"Set to false to remove the dynamics of the filling material.";
Modelica.Blocks.Interfaces.RealOutput TBorAve(final quantity="ThermodynamicTemperature",
final unit="K",
displayUnit = "degC",
start=TExt0_start)
"Average borehole wall temperature in the borefield";
Buildings.Fluid.Geothermal.Borefields.BaseClasses.HeatTransfer.GroundTemperatureResponse
groTemRes(
final tLoaAgg=tLoaAgg,
final nCel=nCel,
final borFieDat=borFieDat,
final forceGFunCalc=forceGFunCalc)
"Ground temperature response";
replaceable Buildings.Fluid.Geothermal.Borefields.BaseClasses.Boreholes.BaseClasses.PartialBorehole
borHol constrainedby Buildings.Fluid.Geothermal.Borefields.BaseClasses.Boreholes.BaseClasses.PartialBorehole
(
redeclare final package Medium = Medium,
final borFieDat=borFieDat,
final nSeg=nSeg,
final m_flow_nominal=m_flow_nominal/borFieDat.conDat.nBor,
final dp_nominal=dp_nominal,
final allowFlowReversal=allowFlowReversal,
final m_flow_small=m_flow_small,
final show_T=show_T,
final computeFlowResistance=computeFlowResistance,
final from_dp=from_dp,
final linearizeFlowResistance=linearizeFlowResistance,
final deltaM=deltaM,
final energyDynamics=energyDynamics,
final p_start=p_start,
final mSenFac=mSenFac,
final dynFil=dynFil,
final TFlu_start=TFlu_start,
final TGro_start=TGro_start) "Borehole";
protected
parameter Modelica.Units.SI.Height z[nSeg]={borFieDat.conDat.hBor/nSeg*(i -
0.5) for i in 1:nSeg}
"Distance from the surface to the considered segment";
Buildings.Fluid.BaseClasses.MassFlowRateMultiplier masFloDiv(
redeclare final package Medium = Medium,
allowFlowReversal=allowFlowReversal,
final k=1/borFieDat.conDat.nBor)
"Division of flow rate";
Buildings.Fluid.BaseClasses.MassFlowRateMultiplier masFloMul(
redeclare final package Medium = Medium,
allowFlowReversal=allowFlowReversal,
final k=borFieDat.conDat.nBor) "Mass flow multiplier";
Modelica.Blocks.Math.Gain gaiQ_flow(k=borFieDat.conDat.nBor)
"Gain to multiply the heat extracted by one borehole by the number of boreholes";
Buildings.Utilities.Math.Average AveTBor(nin=nSeg)
"Average temperature of all the borehole segments";
Modelica.Blocks.Sources.Constant TSoiUnd[nSeg](
k = TExt_start,
each y(unit="K",
displayUnit="degC"))
"Undisturbed soil temperature";
Modelica.Thermal.HeatTransfer.Sensors.HeatFlowSensor QBorHol[nSeg]
"Heat flow rate of all segments of the borehole";
Buildings.HeatTransfer.Sources.PrescribedTemperature TemBorWal[nSeg]
"Borewall temperature";
Modelica.Blocks.Math.Add TSoiDis[nSeg](each final k1=1, each final k2=1)
"Addition of undisturbed soil temperature and change of soil temperature";
Modelica.Blocks.Math.Sum QTotSeg_flow(
final nin=nSeg,
final k = ones(nSeg))
"Total heat flow rate for all segments of this borehole";
Modelica.Blocks.Routing.Replicator repDelTBor(final nout=nSeg)
"Signal replicator for temperature difference of the borehole";
equation
connect(masFloMul.port_b, port_b);
connect(masFloDiv.port_a, port_a);
connect(masFloDiv.port_b, borHol.port_a);
connect(borHol.port_b, masFloMul.port_a);
connect(QBorHol.port_a, borHol.port_wall);
connect(QBorHol.Q_flow, QTotSeg_flow.u);
connect(groTemRes.delTBor, repDelTBor.u);
connect(TSoiDis.u1, repDelTBor.y);
connect(TSoiDis.u2, TSoiUnd.y);
connect(QTotSeg_flow.y, gaiQ_flow.u);
connect(gaiQ_flow.y, groTemRes.QBor_flow);
connect(TSoiDis.y, TemBorWal.T);
connect(QBorHol.port_b, TemBorWal.port);
connect(TSoiDis.y, AveTBor.u);
connect(AveTBor.y, TBorAve);
end PartialBorefield;