Buildings.Fluid.HeatExchangers.ThermalWheels.Sensible.BaseClasses
Package with base classes for sensible heat recovery devices
Information
This package contains base classes that are used to construct the models in Buildings.Fluid.HeatExchangers.ThermalWheels.Sensible.
Extends from Modelica.Icons.BasesPackage (Icon for packages containing base classes).
Package Content
| Name | Description |
|---|---|
 Effectiveness
|
Model for calculating the heat exchange effectiveness |
 HeatExchangerWithInputEffectiveness
|
Heat exchanger with varying effectiveness |
 PartialWheel
|
Partial model for sensible heat recovery wheel |
 Validation
|
Collection of models that validate the module in the base classes |
Buildings.Fluid.HeatExchangers.ThermalWheels.Sensible.BaseClasses.Effectiveness
Model for calculating the heat exchange effectiveness
Information
This block calculates the sensible effectiveness of the heat exchanger under heating and cooling modes at different flow rates of the supply air and the exhaust air.
It first calculates the ratio of the average operating flow rate to the nominal supply flow rate by:
rat = max(0.5, min(1.3, (mSup_flow + mExh_flow)/(2*mSup_flow_nominal))),
where mSup_flow is the flow rate of the supply air,
mExh_flow is the flow rate of the exhaust air,
mSup_flow_nominal is the nominal flow rate of the supply air and
rat is the flow ratio.
It then calculates the sensible heat exchanger effectiveness as
eps = (epsPL + (eps_nominal - epsPL) * (rat - 0.75)/0.25),
where eps is the effectiveness
for the sensible heat transfer, respectively,
eps_nominal and epsPL are the effectiveness
for the sensible heat transfer when rat is 1 and 0.75, respectively.
Note:
The value of the rat is suggested to be between 0.5 and 1.3
during normal operation to ensure reasonable extrapolation.
Likewise, an unbalanced air flow ratio less than 2, i.e., mSup_flow/mExh_flow > 0.5
and mSup_flow/mExh_flow < 2 is recommended.
References
U.S. Department of Energy 2016. "EnergyPlus Engineering Reference".
Extends from Modelica.Blocks.Icons.Block (Basic graphical layout of input/output block).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Efficiency | eps_nominal | Nominal sensible heat exchanger effectiveness [1] | |
| Efficiency | epsPL | Part load (75% of the nominal supply flow rate) sensible heat exchanger effectiveness [1] | |
| MassFlowRate | mSup_flow_nominal | Nominal supply air mass flow rate [kg/s] |
Connectors
| Type | Name | Description |
|---|---|---|
| input RealInput | mSup_flow | Supply air mass flow rate [kg/s] |
| input RealInput | mExh_flow | Exhaust air mass flow rate [kg/s] |
| output RealOutput | eps | Sensible heat exchanger effectiveness [1] |
Modelica definition
model Effectiveness
"Model for calculating the heat exchange effectiveness"
extends Modelica.Blocks.Icons.Block;
parameter Modelica.Units.SI.Efficiency eps_nominal(final max=1)
"Nominal sensible heat exchanger effectiveness";
parameter Modelica.Units.SI.Efficiency epsPL(final max=1)
"Part load (75% of the nominal supply flow rate) sensible heat exchanger effectiveness";
parameter Modelica.Units.SI.MassFlowRate mSup_flow_nominal
"Nominal supply air mass flow rate";
Buildings.Controls.OBC.CDL.Interfaces.RealInput mSup_flow(final unit="kg/s")
"Supply air mass flow rate";
Buildings.Controls.OBC.CDL.Interfaces.RealInput mExh_flow(final unit="kg/s")
"Exhaust air mass flow rate";
Buildings.Controls.OBC.CDL.Interfaces.RealOutput eps(final unit="1")
"Sensible heat exchanger effectiveness";
protected
Real rat
"Ratio of the average operating air flow rate to the nominal supply air flow rate";
equation
// Calculate the average volumetric air flow and flow rate ratio.
rat=(mSup_flow+mExh_flow)/2/mSup_flow_nominal;
// Check if the air flows are too unbalanced, unless rat < 0.05, in which case
// the system is likely off or transitioning to on or off.
assert(rat<0.05 or (mSup_flow-2*mExh_flow<1e-5 and mExh_flow-2*mSup_flow<1e-5),
"In " + getInstanceName() + ": The ratio of the supply flow rate to the exhaust flow rate should be in the range of [0.5, 2] when flow rates are non-zero.",
level=AssertionLevel.warning);
// Calculate effectiveness
eps=(epsPL+(eps_nominal-epsPL)*(
Buildings.Utilities.Math.Functions.smoothLimit(x=rat, l=0.5, u=1.3, deltaX=0.01)-0.75)/0.25);
assert(eps>=0 and eps<1,
"In " + getInstanceName() + ": The sensible heat exchange effectiveness eps = " + String(eps) + ". It should be in the range of [0, 1].
Check if the part load (75% of the nominal supply flow rate) or nominal sensible heat exchanger effectiveness is too high or too low.",
level=AssertionLevel.error);
end Effectiveness;
Buildings.Fluid.HeatExchangers.ThermalWheels.Sensible.BaseClasses.HeatExchangerWithInputEffectiveness
Heat exchanger with varying effectiveness
Information
This block is identical to Buildings.Fluid.HeatExchangers.ConstantEffectiveness, except that the sensible heat exchanger effectiveness is an input rather than a parameter.
Extends from Buildings.Fluid.HeatExchangers.BaseClasses.PartialEffectiveness (Partial model to implement heat exchangers based on effectiveness model).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| replaceable package Medium1 | PartialMedium | Medium 1 in the component | |
| replaceable package Medium2 | PartialMedium | Medium 2 in the component | |
| HeatFlowRate | Q1_flow | eps*QMax_flow | Heat transferred into the medium 1 [W] |
| MassFlowRate | mWat1_flow | 0 | Moisture mass flow rate added to the medium 1 [kg/s] |
| HeatFlowRate | Q2_flow | -Q1_flow | Heat transferred into the medium 2 [W] |
| MassFlowRate | mWat2_flow | 0 | Moisture mass flow rate added to the medium 2 [kg/s] |
| Boolean | sensibleOnly1 | true | Set to true if sensible exchange only for medium 1 |
| Boolean | sensibleOnly2 | true | Set to true if sensible exchange only for medium 2 |
| Nominal condition | |||
| MassFlowRate | m1_flow_nominal | Nominal mass flow rate [kg/s] | |
| MassFlowRate | m2_flow_nominal | Nominal mass flow rate [kg/s] | |
| PressureDifference | dp1_nominal | Pressure difference [Pa] | |
| PressureDifference | dp2_nominal | Pressure difference [Pa] | |
| Assumptions | |||
| Boolean | allowFlowReversal1 | true | = false to simplify equations, assuming, but not enforcing, no flow reversal for medium 1 |
| Boolean | allowFlowReversal2 | true | = false to simplify equations, assuming, but not enforcing, no flow reversal for medium 2 |
| Advanced | |||
| MassFlowRate | m1_flow_small | 1E-4*abs(m1_flow_nominal) | Small mass flow rate for regularization of zero flow [kg/s] |
| MassFlowRate | m2_flow_small | 1E-4*abs(m2_flow_nominal) | Small mass flow rate for regularization of zero flow [kg/s] |
| Diagnostics | |||
| Boolean | show_T | false | = true, if actual temperature at port is computed |
| Flow resistance | |||
| Medium 1 | |||
| Boolean | from_dp1 | false | = true, use m_flow = f(dp) else dp = f(m_flow) |
| Boolean | linearizeFlowResistance1 | false | = true, use linear relation between m_flow and dp for any flow rate |
| Real | deltaM1 | 0.1 | Fraction of nominal flow rate where flow transitions to laminar |
| Medium 2 | |||
| Boolean | from_dp2 | false | = true, use m_flow = f(dp) else dp = f(m_flow) |
| Boolean | linearizeFlowResistance2 | false | = true, use linear relation between m_flow and dp for any flow rate |
| Real | deltaM2 | 0.1 | Fraction of nominal flow rate where flow transitions to laminar |
Connectors
| Type | Name | Description |
|---|---|---|
| FluidPort_a | port_a1 | Fluid connector a1 (positive design flow direction is from port_a1 to port_b1) |
| FluidPort_b | port_b1 | Fluid connector b1 (positive design flow direction is from port_a1 to port_b1) |
| FluidPort_a | port_a2 | Fluid connector a2 (positive design flow direction is from port_a2 to port_b2) |
| FluidPort_b | port_b2 | Fluid connector b2 (positive design flow direction is from port_a2 to port_b2) |
| input RealInput | eps | Sensible heat exchanger effectiveness [1] |
Modelica definition
model HeatExchangerWithInputEffectiveness
"Heat exchanger with varying effectiveness"
extends Buildings.Fluid.HeatExchangers.BaseClasses.PartialEffectiveness(
sensibleOnly1 = true,
sensibleOnly2 = true,
final prescribedHeatFlowRate1=true,
final prescribedHeatFlowRate2=true,
Q1_flow = eps * QMax_flow,
Q2_flow = -Q1_flow,
mWat1_flow = 0,
mWat2_flow = 0);
Buildings.Controls.OBC.CDL.Interfaces.RealInput eps(
min=0,
max=1,
final unit="1")
"Sensible heat exchanger effectiveness";
end HeatExchangerWithInputEffectiveness;
Buildings.Fluid.HeatExchangers.ThermalWheels.Sensible.BaseClasses.PartialWheel
Partial model for sensible heat recovery wheel
Information
Partial model of a sensible heat recovery wheel.
Extends from Modelica.Blocks.Icons.Block (Basic graphical layout of input/output block).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| replaceable package Medium | Modelica.Media.Interfaces.Pa... | Air | |
| Generic | per | per(final have_latHEX=false) | Record with performance data |
| Assumptions | |||
| Boolean | allowFlowReversal1 | true | = false to simplify equations, assuming, but not enforcing, no flow reversal for medium 1 |
| Boolean | allowFlowReversal2 | true | = false to simplify equations, assuming, but not enforcing, no flow reversal for medium 2 |
| Flow resistance | |||
| Medium 1 | |||
| Boolean | from_dp1 | false | = true, use m_flow = f(dp) else dp = f(m_flow) |
| Boolean | linearizeFlowResistance1 | false | = true, use linear relation between m_flow and dp for any flow rate |
| Medium 2 | |||
| Boolean | from_dp2 | false | = true, use m_flow = f(dp) else dp = f(m_flow) |
| Boolean | linearizeFlowResistance2 | false | = true, use linear relation between m_flow and dp for any flow rate |
Connectors
| Type | Name | Description |
|---|---|---|
| replaceable package Medium | Air | |
| output RealOutput | P | Electric power consumption [W] |
| output RealOutput | eps | Sensible heat exchanger effectiveness [1] |
| FluidPort_a | port_a1 | Fluid connector a1 of the supply air (positive design flow direction is from port_a1 to port_b1) |
| FluidPort_b | port_b2 | Fluid connector b2 of the exhaust air (positive design flow direction is from port_a2 to port_b2) |
| FluidPort_b | port_b1 | Fluid connector b1 of the supply air (positive design flow direction is from port_a1 to port_b1) |
| FluidPort_a | port_a2 | Fluid connector a2 of the exhaust air (positive design flow direction is from port_a2 to port_b2) |
Modelica definition
partial model PartialWheel
"Partial model for sensible heat recovery wheel"
extends Modelica.Blocks.Icons.Block;
replaceable package Medium = Modelica.Media.Interfaces.PartialCondensingGases
"Air";
parameter Buildings.Fluid.HeatExchangers.ThermalWheels.Data.Generic per(
final have_latHEX=false)
"Record with performance data";
parameter Boolean allowFlowReversal1 = true
"= false to simplify equations, assuming, but not enforcing, no flow reversal for medium 1";
parameter Boolean allowFlowReversal2 = true
"= false to simplify equations, assuming, but not enforcing, no flow reversal for medium 2";
parameter Boolean from_dp1 = false
"= true, use m_flow = f(dp) else dp = f(m_flow)";
parameter Boolean linearizeFlowResistance1 = false
"= true, use linear relation between m_flow and dp for any flow rate";
parameter Boolean from_dp2 = false
"= true, use m_flow = f(dp) else dp = f(m_flow)";
parameter Boolean linearizeFlowResistance2 = false
"= true, use linear relation between m_flow and dp for any flow rate";
Buildings.Controls.OBC.CDL.Interfaces.RealOutput P(
final unit="W") "Electric power consumption";
Buildings.Controls.OBC.CDL.Interfaces.RealOutput eps(final unit="1")
"Sensible heat exchanger effectiveness";
Modelica.Fluid.Interfaces.FluidPort_a port_a1(
redeclare final package Medium = Medium)
"Fluid connector a1 of the supply air (positive design flow direction is from port_a1 to port_b1)";
Modelica.Fluid.Interfaces.FluidPort_b port_b2(
redeclare final package Medium = Medium)
"Fluid connector b2 of the exhaust air (positive design flow direction is from port_a2 to port_b2)";
Modelica.Fluid.Interfaces.FluidPort_b port_b1(
redeclare final package Medium = Medium)
"Fluid connector b1 of the supply air (positive design flow direction is from port_a1 to port_b1)";
Modelica.Fluid.Interfaces.FluidPort_a port_a2(
redeclare final package Medium = Medium)
"Fluid connector a2 of the exhaust air (positive design flow direction is from port_a2 to port_b2)";
Buildings.Fluid.Sensors.MassFlowRate senSupMasFlo(
redeclare package Medium = Medium)
"Supply air mass flow rate";
Buildings.Fluid.Sensors.MassFlowRate senExhMasFlo(
redeclare package Medium = Medium)
"Exhaust air mass flow rate";
protected
parameter Medium.ThermodynamicState sta_nominal=Medium.setState_pTX(
T=Buildings.Utilities.Psychrometrics.Constants.T_ref,
p=101325,
X=Medium.X_default)
"State of the supply air at the default properties";
Buildings.Fluid.HeatExchangers.ThermalWheels.Sensible.BaseClasses.HeatExchangerWithInputEffectiveness
hex(
redeclare package Medium1 = Medium,
redeclare package Medium2 = Medium,
final m1_flow_nominal=per.mSup_flow_nominal,
final m2_flow_nominal=per.mExh_flow_nominal,
final allowFlowReversal1=allowFlowReversal1,
final allowFlowReversal2=allowFlowReversal2,
final from_dp1=from_dp1,
final from_dp2=from_dp2,
final linearizeFlowResistance1=linearizeFlowResistance1,
final linearizeFlowResistance2=linearizeFlowResistance2)
"Heat exchanger";
Buildings.Fluid.HeatExchangers.ThermalWheels.Sensible.BaseClasses.Effectiveness
effCal(
final eps_nominal=per.epsSen_nominal,
final epsPL=per.epsSenPL,
final mSup_flow_nominal=per.mSup_flow_nominal)
"Calculate the effectiveness of heat exchanger";
equation
connect(senExhMasFlo.port_b, port_b2);
connect(senExhMasFlo.port_a, hex.port_b2);
connect(hex.port_b1, senSupMasFlo.port_a);
connect(senSupMasFlo.port_b, port_b1);
connect(senExhMasFlo.m_flow, effCal.mExh_flow);
connect(senSupMasFlo.m_flow, effCal.mSup_flow);
end PartialWheel;