Buildings.Fluid.HeatPumps.ModularReversible.BaseClasses
Package with base classes for Buildings.Fluid.HeatPumps.ModularReversible
Information
This package contains base classes that are used to construct the models in Buildings.Fluid.HeatPumps.ModularReversible.
Extends from Modelica.Icons.BasesPackage (Icon for packages containing base classes).
Package Content
| Name | Description |
|---|---|
 CalculateEfficiency
|
Calculate the COP or EER of a device |
 EvaporatorCondenserWithCapacity
|
Evaporaotr or condenser model with added capacity for heat losses to the ambient |
 LargeScaleWaterToWaterDeclarations
|
Model with parameters for large scale water-to-water heat pump |
 PartialModularRefrigerantCycle
|
Partial refrigerant cycle model |
 PartialReversibleRefrigerantMachine
|
Model for reversible heat pumps and chillers with a refrigerant cycle |
 RefrigerantCycle
|
Refrigerant cycle model of a heat pump |
 RefrigerantMachineControlBus
|
Bus connector for reversible heat pump and chiller model |
Buildings.Fluid.HeatPumps.ModularReversible.BaseClasses.CalculateEfficiency
Calculate the COP or EER of a device
Information
This model is used to calculate the COP or the EER of a device. As the electrical power can get zero, a lower boundary is used to avoid division by zero.
Extends from Modelica.Blocks.Icons.Block (Basic graphical layout of input/output block).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Power | PEleMin | If eletrical power consumption falls below this value, COP will be set to zero [W] |
Connectors
| Type | Name | Description |
|---|---|---|
| input RealInput | PEle | Electrical power consumed by the system [W] |
| input RealInput | QUse_flow | Useful heat flow [W] |
| output RealOutput | COP | Output for calculated COP value [1] |
| input BooleanInput | hea | =true for heating, false for cooling |
| output RealOutput | EER | Output for calculated EER value [1] |
Modelica definition
model CalculateEfficiency
"Calculate the COP or EER of a device"
extends Modelica.Blocks.Icons.Block;
parameter Modelica.Units.SI.Power PEleMin(min=Modelica.Constants.eps)
"If eletrical power consumption falls below this value, COP will be set to zero";
Modelica.Blocks.Interfaces.RealInput PEle(final unit="W", displayUnit="W")
"Electrical power consumed by the system";
Modelica.Blocks.Interfaces.RealInput QUse_flow(final unit="W", displayUnit="W")
"Useful heat flow";
Modelica.Blocks.Interfaces.RealOutput COP(min=0, final unit="1")
"Output for calculated COP value";
Modelica.Blocks.Logical.Hysteresis hys(
uLow=PEleMin,
uHigh=PEleMin*1.1)
"Hysteresis to switch between calculation and no calculation";
Modelica.Blocks.Interfaces.BooleanInput hea
"=true for heating, false for cooling";
Modelica.Blocks.Interfaces.RealOutput EER(min=0, final unit="1")
"Output for calculated EER value";
Buildings.Utilities.Math.InverseXRegularized invXReg(delta=PEleMin)
"Inverse of electrical power";
protected
Modelica.Blocks.Math.Product copCom "Computes COP";
Modelica.Blocks.Logical.Switch swi
"Outputs COP or zero depending on electricity use";
Modelica.Blocks.Sources.Constant zer(final k=0) "Outputs zero";
Modelica.Blocks.Logical.Switch swiCoo "Switch for cooling and EER calculation";
Modelica.Blocks.Logical.Switch swiHea "Switch for heating and COP calculation";
protected
Modelica.Blocks.Math.Abs absQEva_flow
"Negates possibly negative usefule flow rates";
initial equation
assert(PEleMin > 0,
"In " + getInstanceName() + ": PEleMin must be greater than zero. Disable efficiency calculation using
calEff=false to debug why PEle_nominal is lower than zero.",
AssertionLevel.error);
equation
connect(hys.u, PEle);
connect(hys.y, swi.u2);
connect(copCom.y, swi.u1);
connect(zer.y, swi.u3);
connect(swiCoo.y, EER);
connect(swiHea.y, COP);
connect(hea, swiHea.u2);
connect(swi.y, swiHea.u1);
connect(swiHea.u3, zer.y);
connect(hea, swiCoo.u2);
connect(swi.y, swiCoo.u3);
connect(zer.y, swiCoo.u1);
connect(QUse_flow, absQEva_flow.u);
connect(absQEva_flow.y, copCom.u1);
connect(copCom.u2, invXReg.y);
connect(invXReg.u, PEle);
end CalculateEfficiency;
Buildings.Fluid.HeatPumps.ModularReversible.BaseClasses.EvaporatorCondenserWithCapacity
Evaporaotr or condenser model with added capacity for heat losses to the ambient
Information
Model for an evaporator or condenser with the use of a capacity to simulate heat losses.
Used in Buildings.Fluid.HeatPumps.ModularReversible.Modular and Buildings.Fluid.Chillers.ModularReversible.Modular, the heat flow to or from the volume is calculated in a black-box. Thus the heat is directly added to the medium.
Transient heat losses are modelled by adding a capacity
and two convection components to
Buildings.Fluid.Interfaces.TwoPortHeatMassExchanger.
One of the convection component is between the capacity and the volume
(with thermal conductance GInn) and the other between
the capacity and the ambient heat port (with GOut).
Implementation
Both GInn and GOut are constants
but declared without a parameter keyword so that
the calculation can follow a temperature or flow-rate based approach.
Extends from Buildings.Fluid.Interfaces.TwoPortHeatMassExchanger (Partial model transporting one fluid stream with storing mass or energy).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| replaceable package Medium | PartialMedium | Medium in the component | |
| Boolean | isCon | =true for condenser, false for evaporator | |
| Nominal condition | |||
| MassFlowRate | m_flow_nominal | Nominal mass flow rate [kg/s] | |
| PressureDifference | dp_nominal | Pressure difference [Pa] | |
| Heat losses | |||
| Boolean | use_cap | true | False if capacity and heat losses are neglected |
| HeatCapacity | C | Capacity of heat exchanger, set to zero to ignore its dry mass [J/K] | |
| ThermalConductance | GOut | Exterior heat transfer coefficient, set to zero to ignore external heat loss but keep the dry mass [W/K] | |
| RealOutput | GInn | Interior heat transfer coefficient | |
| Assumptions | |||
| Boolean | allowFlowReversal | true | = false to simplify equations, assuming, but not enforcing, no flow reversal |
| Advanced | |||
| MassFlowRate | m_flow_small | 1E-4*abs(m_flow_nominal) | Small mass flow rate for regularization of zero flow [kg/s] |
| Diagnostics | |||
| Boolean | show_T | false | = true, if actual temperature at port is computed |
| Flow resistance | |||
| Boolean | from_dp | false | = true, use m_flow = f(dp) else dp = f(m_flow) |
| Boolean | linearizeFlowResistance | false | = true, use linear relation between m_flow and dp for any flow rate |
| Real | deltaM | 0.1 | Fraction of nominal flow rate where flow transitions to laminar |
| Dynamics | |||
| Nominal condition | |||
| Time | tau | 30 | Time constant at nominal flow (if energyDynamics <> SteadyState) [s] |
| Conservation equations | |||
| Dynamics | energyDynamics | Modelica.Fluid.Types.Dynamic... | Type of energy balance: dynamic (3 initialization options) or steady state |
| Initialization | |||
| AbsolutePressure | p_start | Medium.p_default | Start value of pressure [Pa] |
| Temperature | T_start | Medium.T_default | Start value of temperature [K] |
| MassFraction | X_start[Medium.nX] | Medium.X_default | Start value of mass fractions m_i/m [kg/kg] |
| ExtraProperty | C_start[Medium.nC] | fill(0, Medium.nC) | Start value of trace substances |
| Capacity | |||
| Temperature | TCap_start | Medium.T_default | Initial temperature of heat capacity [K] |
Connectors
| Type | Name | Description |
|---|---|---|
| FluidPort_a | port_a | Fluid connector a (positive design flow direction is from port_a to port_b) |
| FluidPort_b | port_b | Fluid connector b (positive design flow direction is from port_a to port_b) |
| HeatPort_a | port_out | Temperature and heat flow to the ambient |
| input RealInput | Q_flow | Heat flow rate from the refrigerant to the medium |
| output RealOutput | T | Temperature of the condenser volume [K] |
| Heat losses | ||
| output RealOutput | GInn | Interior heat transfer coefficient |
Modelica definition
model EvaporatorCondenserWithCapacity
"Evaporaotr or condenser model with added capacity for heat losses to the ambient"
extends Buildings.Fluid.Interfaces.TwoPortHeatMassExchanger(
redeclare final Buildings.Fluid.MixingVolumes.MixingVolume vol(final V=
m_flow_nominal*tau/rho_default,
final prescribedHeatFlowRate=true));
parameter Boolean isCon "=true for condenser, false for evaporator";
parameter Boolean use_cap=true
"False if capacity and heat losses are neglected";
parameter Modelica.Units.SI.HeatCapacity C
"Capacity of heat exchanger, set to zero to ignore its dry mass";
parameter Modelica.Units.SI.Temperature TCap_start=Medium.T_default
"Initial temperature of heat capacity";
Modelica.Units.SI.ThermalConductance GOut
"Exterior heat transfer coefficient,
set to zero to ignore external heat loss but keep the dry mass";
Modelica.Blocks.Interfaces.RealOutput GInn
"Interior heat transfer coefficient";
Modelica.Thermal.HeatTransfer.Components.Convection conIns if use_cap
"Convection between the wall and the working fluid";
Modelica.Thermal.HeatTransfer.Components.Convection conOut if use_cap
"Convection and conduction between the wall and ambient air";
Modelica.Thermal.HeatTransfer.Components.HeatCapacitor heaCap(
final C=C,
final T(final fixed=(energyDynamics == Modelica.Fluid.Types.Dynamics.FixedInitial),
final start=TCap_start),
final der_T(final fixed=(energyDynamics == Modelica.Fluid.Types.Dynamics.SteadyStateInitial),
start=0)) if use_cap "Heat Capacity";
Modelica.Blocks.Sources.RealExpression heaLosInt(final y=GInn) if use_cap
"Nominal heat loss coefficient to the interior";
Modelica.Thermal.HeatTransfer.Interfaces.HeatPort_a port_out if use_cap
"Temperature and heat flow to the ambient";
Modelica.Blocks.Sources.RealExpression heaLosExt(final y=GOut) if use_cap
"Nominal heat loss coefficient to the exterior";
Modelica.Thermal.HeatTransfer.Sources.PrescribedHeatFlow preHea(final alpha=0,
final T_ref=293.15) "Heat flow rate of the condenser";
Modelica.Blocks.Interfaces.RealInput Q_flow
"Heat flow rate from the refrigerant to the medium";
Modelica.Thermal.HeatTransfer.Sensors.TemperatureSensor senT
"Temperature sensor for the condenser volume";
Modelica.Blocks.Interfaces.RealOutput T(
final unit="K",
displayUnit="degC")
"Temperature of the condenser volume";
equation
connect(conIns.fluid, heaCap.port);
connect(heaCap.port, conOut.solid);
connect(conIns.Gc, heaLosInt.y);
connect(conOut.fluid, port_out);
connect(conOut.Gc, heaLosExt.y);
connect(vol.heatPort, conIns.solid);
connect(vol.heatPort, preHea.port);
connect(preHea.Q_flow, Q_flow);
connect(senT.port, vol.heatPort);
connect(senT.T, T);
end EvaporatorCondenserWithCapacity;
Buildings.Fluid.HeatPumps.ModularReversible.BaseClasses.LargeScaleWaterToWaterDeclarations
Model with parameters for large scale water-to-water heat pump
Information
This model provides declarations that auto-populate nominal mass flow rates and time constants (i.e. volumes) of the heat exchange based on the nominal electric power consumption of the chiller or heat pump. It is based on more than 20 datasets of water-to-water heat pumps from multiple manufacturers ranging from about 25 kW to 1 MW in nominal electric power consumption. The linear regressions with coefficients of determination above 91% give a good approximation of these parameters. Nevertheless, estimates for machines outside the given range should be checked for plausibility during simulation.
For more information, see Buildings/Resources/Data/Fluid/HeatPumps/BaseClasses/LargeScaleWaterToWaterParameters.xlsx.
Modelica definition
partial model LargeScaleWaterToWaterDeclarations
"Model with parameters for large scale water-to-water heat pump"
//Automatic calculation of mass flow rates and volumes of the evaporator
// and condenser using linear regressions from data sheets of
// heat pumps and chillers (water to water)
protected
parameter Modelica.Units.SI.MassFlowRate autCalMMin_flow=0.3
"Realistic mass flow minimum for simulation plausibility";
parameter Modelica.Units.SI.Volume autCalVMin=0.003
"Realistic volume minimum for simulation plausibility";
parameter Modelica.Units.SI.MassFlowRate autCalMasEva_flow
"Automatically calculated evaporator mass flow rate";
parameter Modelica.Units.SI.MassFlowRate autCalMasCon_flow
"Automatically calculated condenser mass flow rate";
parameter Modelica.Units.SI.Volume autCalVEva
"Automatically calculated evaporator volume";
parameter Modelica.Units.SI.Volume autCalVCon
"Automatically calculated condenser volume";
initial equation
//Control and feedback for the auto-calculation of condenser and evaporator data
assert(
autCalMasEva_flow > autCalMMin_flow and autCalMasEva_flow < 90,
"In " + getInstanceName() + ": Given nominal heat output for auto-calculation of
evaporator and condenser data is outside the range of data sheets
considered. Verify the auto-calculated mass flows.",
level=AssertionLevel.warning);
assert(
autCalVEva > autCalVMin and autCalVEva < 0.43,
"In " + getInstanceName() + ": Given nominal heat output for auto-calculation of evaporator
and condenser data is outside the range of data sheets considered.
Verify the auto-calculated volumes.",
level=AssertionLevel.warning);
end LargeScaleWaterToWaterDeclarations;
Buildings.Fluid.HeatPumps.ModularReversible.BaseClasses.PartialModularRefrigerantCycle
Partial refrigerant cycle model
Information
Partial modular refrigerant cycle models for data and equation based approaches used in the model Buildings.Fluid.HeatPumps.ModularReversible.BaseClasses.PartialReversibleRefrigerantMachine.
This partial container only adds outputs and switches both relevant for heat pump and chiller applications.
For more information on the approach, please read the UsersGuide.
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Boolean | use_rev | true | True if the refrigerant machine is reversible |
Connectors
| Type | Name | Description |
|---|---|---|
| RefrigerantMachineControlBus | sigBus | Signal bus with data for refrigerant models |
| output RealOutput | QCon_flow | Heat flow rate from the refrigerant to the condenser medium [W] |
| output RealOutput | QEva_flow | Heat flow rate from the evaporator medium to the refrigerant [W] |
| output RealOutput | PEle | Routing block that picks the component for electric power consumption [W] |
Modelica definition
partial model PartialModularRefrigerantCycle
"Partial refrigerant cycle model"
parameter Boolean use_rev=true
"True if the refrigerant machine is reversible";
Buildings.Fluid.HeatPumps.ModularReversible.BaseClasses.RefrigerantMachineControlBus
sigBus
"Signal bus with data for refrigerant models";
Modelica.Blocks.Interfaces.RealOutput QCon_flow(
final unit="W")
"Heat flow rate from the refrigerant to the condenser medium";
Modelica.Blocks.Interfaces.RealOutput QEva_flow(
final unit="W")
"Heat flow rate from the evaporator medium to the refrigerant";
Modelica.Blocks.Logical.Switch swiQEva(
u1(final unit="W"),
u3(final unit="W"),
y(final unit="W"))
"Routing block that picks the component acting as evaporator";
Modelica.Blocks.Logical.Switch swiQCon(
y(final unit="W"),
u1(final unit="W"),
u3(final unit="W"))
"Routing block that picks the component acting as condenser";
Modelica.Blocks.Interfaces.RealOutput PEle(final unit="W")
"Routing block that picks the component for electric power consumption";
Modelica.Blocks.Logical.Switch swiPEle(
u1(final unit="W"),
u3(final unit="W"),
y(final unit="W"))
"Whether to use cooling or heating power output";
protected
Modelica.Blocks.Routing.BooleanPassThrough pasTrhModSet
"Pass through to enable assertion for non-reversible device";
equation
assert(
use_rev or (use_rev == false and pasTrhModSet.y == true),
"In " + getInstanceName() + ": Can't turn to reversible operation mode on
irreversible refrigerant machine.",
level=AssertionLevel.error);
connect(swiQEva.y, QEva_flow);
connect(swiPEle.y, PEle);
connect(swiQCon.y, QCon_flow);
end PartialModularRefrigerantCycle;
Buildings.Fluid.HeatPumps.ModularReversible.BaseClasses.PartialReversibleRefrigerantMachine
Model for reversible heat pumps and chillers with a refrigerant cycle
Information
This partial model defines all components which are equally required for heat pump and chillers. This encompasses
- the heat exchangers (evaporator and condenser),
- sensors for temperature and mass flow rates,
- the replaceable model for refrigerant inertia,
- safety controls,
- connectors and parameters,
- and the replaceable refrigerant cycle model
refCyc
The model refCyc is replaced in the ModularReversible
model for heat pumps and chillers, e.g. by
Buildings.Fluid.HeatPumps.ModularReversible.BaseClasses.RefrigerantCycle
in
Buildings.Fluid.HeatPumps.ModularReversible.Modular.
For more information on the approach, please read the UsersGuide.
Extends from Buildings.Fluid.Interfaces.PartialFourPortInterface (Partial model with four ports and declaration of quantities that are used by many models).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| replaceable package Medium1 | PartialMedium | Medium 1 in the component | |
| replaceable package Medium2 | PartialMedium | Medium 2 in the component | |
| replaceable package MediumCon | Modelica.Media.Interfaces.Pa... | Medium on condenser side | |
| replaceable package MediumEva | Modelica.Media.Interfaces.Pa... | Medium on evaporator side | |
| PartialModularRefrigerantCycle | refCyc | redeclare PartialModularRefr... | Model of the refrigerant cycle |
| Boolean | use_rev | true | =true if the chiller or heat pump is reversible |
| Nominal condition | |||
| MassFlowRate | m1_flow_nominal | mCon_flow_nominal | Nominal mass flow rate [kg/s] |
| MassFlowRate | m2_flow_nominal | mEva_flow_nominal | Nominal mass flow rate [kg/s] |
| HeatFlowRate | PEle_nominal | Nominal electrical power consumption [W] | |
| Inertia | |||
| replaceable model RefrigerantCycleInertia | Buildings.Fluid.HeatPumps.Mo... | Inertia between the refrigerant cycle outputs and the heat exchangers. | |
| Safety control | |||
| Boolean | use_intSafCtr | true | =true to enable internal safety control |
| Wuellhorst2021 | safCtrPar | redeclare parameter Building... | Safety control parameters |
| Nominal condition - Pressure losses | |||
| TemperatureDifference | dTCon_nominal | Nominal temperature difference in condenser medium, used to calculate mass flow rate [K] | |
| MassFlowRate | mCon_flow_nominal | Nominal mass flow rate of the condenser medium [kg/s] | |
| PressureDifference | dpCon_nominal | Pressure drop at nominal mass flow rate [Pa] | |
| TemperatureDifference | dTEva_nominal | Nominal temperature difference in evaporator medium, used to calculate mass flow rate [K] | |
| MassFlowRate | mEva_flow_nominal | Nominal mass flow rate of the evaporator medium [kg/s] | |
| PressureDifference | dpEva_nominal | Pressure drop at nominal mass flow rate [Pa] | |
| Assumptions | |||
| Boolean | allowFlowReversal1 | allowFlowReversalCon | = false to simplify equations, assuming, but not enforcing, no flow reversal for medium 1 |
| Boolean | allowFlowReversal2 | allowFlowReversalEva | = false to simplify equations, assuming, but not enforcing, no flow reversal for medium 2 |
| Evaporator | |||
| Boolean | allowFlowReversalEva | true | = false to simplify equations, assuming, but not enforcing, no flow reversal |
| Condenser | |||
| Boolean | allowFlowReversalCon | true | = false to simplify equations, assuming, but not enforcing, no flow reversal |
| Advanced | |||
| MassFlowRate | m1_flow_small | 1E-4*abs(mCon_flow_nominal) | Small mass flow rate for regularization of zero flow [kg/s] |
| MassFlowRate | m2_flow_small | 1E-4*abs(mEva_flow_nominal) | Small mass flow rate for regularization of zero flow [kg/s] |
| Boolean | allowDifferentDeviceIdentifiers | false | if use_rev=true, device data for cooling and heating need to entered. Set allowDifferentDeviceIdentifiers=true to allow different device identifiers devIde |
| Boolean | calEff | true | =false to disable efficiency calculation, may speed up the simulation |
| Real | limWarSca | 0.05 | Allowed difference in scaling '|scaFacHea - scaFacCoo| / scaFacHea', if exceeded, a warning will be issued [1] |
| Diagnostics | |||
| Boolean | show_T | false | = true, if actual temperature at port is computed |
| Real | ySet_small | 0.01 | Threshold for relative speed for the device to be considered on |
| Flow resistance | |||
| Boolean | from_dp | false | = true, use m_flow = f(dp) else dp = f(m_flow) |
| Boolean | linearized | false | = true, use linear relation between m_flow and dp for any flow rate |
| Condenser | |||
| Dynamics | |||
| Time | tauCon | 30 | Condenser heat transfer time constant at nominal flow [s] |
| Flow resistance | |||
| Real | deltaMCon | 0.1 | Fraction of nominal mass flow rate where transition to turbulent occurs |
| Heat Losses | |||
| Boolean | use_conCap | true | =true if using capacitor model for condenser heat loss estimation |
| HeatCapacity | CCon | 0 | Heat capacity of the condenser [J/K] |
| ThermalConductance | GConOut | 0 | Outer thermal conductance for condenser heat loss calculations [W/K] |
| ThermalConductance | GConIns | 0 | Inner thermal conductance for condenser heat loss calculations [W/K] |
| Evaporator | |||
| Dynamics | |||
| Time | tauEva | 30 | Evaporator heat transfer time constant at nominal flow [s] |
| Flow resistance | |||
| Real | deltaMEva | 0.1 | Fraction of nominal mass flow rate where transition to turbulent occurs |
| Heat Losses | |||
| Boolean | use_evaCap | true | =true if using capacitor model for evaporator heat loss estimation |
| HeatCapacity | CEva | 0 | Heat capacity of the evaporator [J/K] |
| ThermalConductance | GEvaOut | 0 | Outer thermal conductance for evaporator heat loss calculations [W/K] |
| ThermalConductance | GEvaIns | 0 | Inner thermal conductance for evaporator heat loss calculations [W/K] |
| Initialization | |||
| Parameters | |||
| Init | initType | Modelica.Blocks.Types.Init.I... | Type of initialization for refrigerant cycle dynamics (InitialState and InitialOutput are identical) |
| Condenser | |||
| AbsolutePressure | pCon_start | MediumCon.p_default | Start value of pressure [Pa] |
| Temperature | TCon_start | MediumCon.T_default | Start value of temperature [K] |
| Temperature | TConCap_start | MediumCon.T_default | Initial temperature of heat capacity of condenser [K] |
| MassFraction | XCon_start[MediumCon.nX] | MediumCon.X_default | Start value of mass fractions m_i/m [kg/kg] |
| Evaporator | |||
| AbsolutePressure | pEva_start | MediumEva.p_default | Start value of pressure [Pa] |
| Temperature | TEva_start | MediumEva.T_default | Start value of temperature [K] |
| Temperature | TEvaCap_start | MediumEva.T_default | Initial temperature of heat capacity at evaporator [K] |
| MassFraction | XEva_start[MediumEva.nX] | MediumEva.X_default | Start value of mass fractions m_i/m [kg/kg] |
| Dynamics | |||
| Equation | |||
| Dynamics | energyDynamics | Modelica.Fluid.Types.Dynamic... | Type of energy balance: dynamic (3 initialization options) or steady state (only affects fluid-models) |
Connectors
| Type | Name | Description |
|---|---|---|
| replaceable package Medium1 | Medium 1 in the component | |
| replaceable package Medium2 | Medium 2 in the component | |
| FluidPort_a | port_a1 | Fluid connector a1 (positive design flow direction is from port_a1 to port_b1) |
| FluidPort_b | port_b1 | Fluid connector b1 (positive design flow direction is from port_a1 to port_b1) |
| FluidPort_a | port_a2 | Fluid connector a2 (positive design flow direction is from port_a2 to port_b2) |
| FluidPort_b | port_b2 | Fluid connector b2 (positive design flow direction is from port_a2 to port_b2) |
| replaceable package MediumCon | Medium on condenser side | |
| replaceable package MediumEva | Medium on evaporator side | |
| input RealInput | ySet | Relative compressor speed between 0 and 1 |
| input RealInput | TEvaAmb | Ambient temperature on the evaporator side [K] |
| input RealInput | TConAmb | Ambient temperature on the condenser side [K] |
| output RealOutput | QCon_flow | Actual heating heat flow rate added to fluid 1 [W] |
| output RealOutput | P | Electric power consumed by compressor [W] |
| output RealOutput | QEva_flow | Actual cooling heat flow rate removed from fluid 2 [W] |
| output RealOutput | EER | Energy efficieny ratio [1] |
| output RealOutput | COP | Coefficient of performance [1] |
| Inertia | ||
| replaceable model RefrigerantCycleInertia | Inertia between the refrigerant cycle outputs and the heat exchangers. | |
Modelica definition
partial model PartialReversibleRefrigerantMachine
"Model for reversible heat pumps and chillers with a refrigerant cycle"
extends Buildings.Fluid.Interfaces.PartialFourPortInterface(
redeclare final package Medium1 = MediumCon,
redeclare final package Medium2 = MediumEva,
final m1_flow_nominal=mCon_flow_nominal,
final m2_flow_nominal=mEva_flow_nominal,
final allowFlowReversal1=allowFlowReversalCon,
final allowFlowReversal2=allowFlowReversalEva,
final m1_flow_small=1E-4*abs(mCon_flow_nominal),
final m2_flow_small=1E-4*abs(mEva_flow_nominal));
//General
replaceable package MediumCon =
Modelica.Media.Interfaces.PartialMedium "Medium on condenser side";
replaceable package MediumEva =
Modelica.Media.Interfaces.PartialMedium "Medium on evaporator side";
replaceable PartialModularRefrigerantCycle refCyc constrainedby PartialModularRefrigerantCycle
(final use_rev=use_rev)
"Model of the refrigerant cycle";
parameter Modelica.Units.SI.HeatFlowRate PEle_nominal
"Nominal electrical power consumption";
replaceable model RefrigerantCycleInertia =
Buildings.Fluid.HeatPumps.ModularReversible.RefrigerantCycle.Inertias.NoInertia
constrainedby Buildings.Fluid.HeatPumps.ModularReversible.RefrigerantCycle.Inertias.BaseClasses.PartialInertia
"Inertia between the refrigerant cycle outputs and the heat exchangers.";
parameter Boolean use_rev=true
"=true if the chiller or heat pump is reversible";
parameter Boolean allowDifferentDeviceIdentifiers=false
"if use_rev=true, device data for cooling and heating need to entered. Set allowDifferentDeviceIdentifiers=true to allow different device identifiers devIde";
// Safety control
parameter Boolean use_intSafCtr=true
"=true to enable internal safety control";
replaceable parameter Buildings.Fluid.HeatPumps.ModularReversible.Controls.Safety.Data.Wuellhorst2021
safCtrPar
constrainedby Buildings.Fluid.HeatPumps.ModularReversible.Controls.Safety.Data.Generic
"Safety control parameters";
//Condenser
parameter Modelica.Units.SI.Time tauCon=30
"Condenser heat transfer time constant at nominal flow";
parameter Modelica.Units.SI.TemperatureDifference dTCon_nominal
"Nominal temperature difference in condenser medium, used to calculate mass flow rate";
parameter Modelica.Units.SI.MassFlowRate mCon_flow_nominal
"Nominal mass flow rate of the condenser medium";
parameter Modelica.Units.SI.PressureDifference dpCon_nominal(displayUnit="Pa")
"Pressure drop at nominal mass flow rate";
parameter Real deltaMCon=0.1
"Fraction of nominal mass flow rate where transition to turbulent occurs";
parameter Boolean use_conCap=true
"=true if using capacitor model for condenser heat loss estimation";
parameter Modelica.Units.SI.HeatCapacity CCon=0
"Heat capacity of the condenser";
parameter Modelica.Units.SI.ThermalConductance GConOut=0
"Outer thermal conductance for condenser heat loss calculations";
parameter Modelica.Units.SI.ThermalConductance GConIns=0
"Inner thermal conductance for condenser heat loss calculations";
final parameter Modelica.Units.SI.Density rhoCon=MediumCon.density(staCon_nominal)
"Condenser medium density";
final parameter Modelica.Units.SI.SpecificHeatCapacity cpCon=
MediumCon.specificHeatCapacityCp(staCon_nominal)
"Condenser medium specific heat capacity";
//Evaporator
parameter Modelica.Units.SI.Time tauEva=30
"Evaporator heat transfer time constant at nominal flow";
parameter Modelica.Units.SI.TemperatureDifference dTEva_nominal
"Nominal temperature difference in evaporator medium, used to calculate mass flow rate";
parameter Modelica.Units.SI.MassFlowRate mEva_flow_nominal
"Nominal mass flow rate of the evaporator medium";
parameter Modelica.Units.SI.PressureDifference dpEva_nominal(displayUnit="Pa")
"Pressure drop at nominal mass flow rate";
parameter Real deltaMEva=0.1
"Fraction of nominal mass flow rate where transition to turbulent occurs";
parameter Boolean use_evaCap=true
"=true if using capacitor model for evaporator heat loss estimation";
parameter Modelica.Units.SI.HeatCapacity CEva=0
"Heat capacity of the evaporator";
parameter Modelica.Units.SI.ThermalConductance GEvaOut=0
"Outer thermal conductance for evaporator heat loss calculations";
parameter Modelica.Units.SI.ThermalConductance GEvaIns=0
"Inner thermal conductance for evaporator heat loss calculations";
final parameter Modelica.Units.SI.Density rhoEva=MediumEva.density(staEva_nominal)
"Evaporator medium density";
final parameter Modelica.Units.SI.SpecificHeatCapacity cpEva=
MediumEva.specificHeatCapacityCp(staEva_nominal)
"Evaporator medium specific heat capacity";
//Assumptions
parameter Boolean allowFlowReversalEva=true
"= false to simplify equations, assuming, but not enforcing, no flow reversal";
parameter Boolean allowFlowReversalCon=true
"= false to simplify equations, assuming, but not enforcing, no flow reversal";
//Initialization
parameter Modelica.Blocks.Types.Init initType=
Modelica.Blocks.Types.Init.InitialState
"Type of initialization for refrigerant cycle dynamics (InitialState and InitialOutput are identical)";
parameter Modelica.Media.Interfaces.Types.AbsolutePressure pCon_start=
MediumCon.p_default "Start value of pressure";
parameter Modelica.Media.Interfaces.Types.Temperature TCon_start=
MediumCon.T_default
"Start value of temperature";
parameter Modelica.Units.SI.Temperature TConCap_start=MediumCon.T_default
"Initial temperature of heat capacity of condenser";
parameter Modelica.Media.Interfaces.Types.MassFraction XCon_start[MediumCon.nX]=
MediumCon.X_default "Start value of mass fractions m_i/m";
parameter Modelica.Media.Interfaces.Types.AbsolutePressure pEva_start=
MediumEva.p_default "Start value of pressure";
parameter Modelica.Media.Interfaces.Types.Temperature TEva_start=
MediumEva.T_default
"Start value of temperature";
parameter Modelica.Units.SI.Temperature TEvaCap_start=MediumEva.T_default
"Initial temperature of heat capacity at evaporator";
parameter Modelica.Media.Interfaces.Types.MassFraction XEva_start[MediumEva.nX]=
MediumEva.X_default "Start value of mass fractions m_i/m";
//Dynamics
parameter Modelica.Fluid.Types.Dynamics energyDynamics=
Modelica.Fluid.Types.Dynamics.DynamicFreeInitial
"Type of energy balance: dynamic (3 initialization options)
or steady state (only affects fluid-models)";
//Advanced
parameter Boolean from_dp=false
"= true, use m_flow = f(dp) else dp = f(m_flow)";
parameter Boolean linearized=false
"= true, use linear relation between m_flow and dp for any flow rate";
parameter Real ySet_small(min=0.002)=0.01
"Threshold for relative speed for the device to be considered on";
parameter Boolean calEff=true
"=false to disable efficiency calculation, may speed up the simulation";
parameter Real limWarSca(final unit="1") = 0.05
"Allowed difference in scaling '|scaFacHea - scaFacCoo| / scaFacHea', if exceeded, a warning will be issued";
Modelica.Units.SI.HeatFlowRate Q1_flow = QCon_flow
"Heat transferred into the medium 1";
Modelica.Units.SI.HeatFlowRate Q2_flow = QEva_flow
"Heat transferred into the medium 2";
Buildings.Fluid.HeatPumps.ModularReversible.BaseClasses.EvaporatorCondenserWithCapacity
con(
redeclare final package Medium = MediumCon,
final allowFlowReversal=allowFlowReversalCon,
final m_flow_small=1E-4*abs(mCon_flow_nominal),
final show_T=show_T,
final deltaM=deltaMCon,
final tau=tauCon,
final T_start=TCon_start,
final p_start=pCon_start,
final use_cap=use_conCap,
final X_start=XCon_start,
final from_dp=from_dp,
final energyDynamics=energyDynamics,
final isCon=true,
final C=CCon,
final TCap_start=TConCap_start,
final GOut=GConOut,
final m_flow_nominal=mCon_flow_nominal,
final dp_nominal=dpCon_nominal,
final GInn=GConIns) "Heat exchanger model for the condenser";
Buildings.Fluid.HeatPumps.ModularReversible.BaseClasses.EvaporatorCondenserWithCapacity
eva(
redeclare final package Medium = MediumEva,
final deltaM=deltaMEva,
final tau=tauEva,
final use_cap=use_evaCap,
final allowFlowReversal=allowFlowReversalEva,
final m_flow_small=1E-4*abs(mEva_flow_nominal),
final show_T=show_T,
final T_start=TEva_start,
final p_start=pEva_start,
final X_start=XEva_start,
final from_dp=from_dp,
final energyDynamics=energyDynamics,
final isCon=false,
final C=CEva,
final m_flow_nominal=mEva_flow_nominal,
final dp_nominal=dpEva_nominal,
final TCap_start=TEvaCap_start,
final GOut=GEvaOut,
final GInn=GEvaIns) "Heat exchanger model for the evaporator";
Buildings.HeatTransfer.Sources.PrescribedTemperature varTOutEva
if use_evaCap "Forces heat losses according to ambient temperature";
Buildings.HeatTransfer.Sources.PrescribedTemperature varTOutCon
if use_conCap "Forces heat losses according to ambient temperature";
Buildings.Fluid.HeatPumps.ModularReversible.Controls.Safety.Safety safCtr(
final mEva_flow_nominal=mEva_flow_nominal,
final mCon_flow_nominal=mCon_flow_nominal,
safCtrPar=safCtrPar,
final ySet_small=ySet_small) if use_intSafCtr "Safety control models";
Modelica.Blocks.Interfaces.RealInput ySet if not use_busConOnl
"Relative compressor speed between 0 and 1";
Modelica.Blocks.Interfaces.RealInput TEvaAmb(final unit="K", displayUnit="degC")
if use_evaCap and not use_busConOnl
"Ambient temperature on the evaporator side";
Modelica.Blocks.Interfaces.RealInput TConAmb(final unit="K", displayUnit="degC")
if use_conCap and not use_busConOnl
"Ambient temperature on the condenser side";
Buildings.Fluid.Sensors.MassFlowRate mEva_flow(redeclare final package Medium =
MediumEva, final allowFlowReversal=allowFlowReversalEva)
"Mass flow sensor at the evaporator";
Buildings.Fluid.Sensors.MassFlowRate mCon_flow(final allowFlowReversal=
allowFlowReversalEva, redeclare final package Medium = MediumCon)
"Mass flow sensor at the evaporator";
RefrigerantCycleInertia refCycIneCon "Inertia model for condenser side";
RefrigerantCycleInertia refCycIneEva "Inertia model for evaporator side";
Modelica.Blocks.Sources.RealExpression senTConIn(
final y(
final unit="K",
displayUnit="degC")=MediumCon.temperature(MediumCon.setState_phX(
port_a1.p,
inStream(port_a1.h_outflow),
inStream(port_a1.Xi_outflow))))
"Real expression for condenser inlet temperature";
Modelica.Blocks.Sources.RealExpression senTEvaIn(
final y(
final unit="K",
displayUnit="degC")=MediumEva.temperature(MediumEva.setState_phX(
port_a2.p,
inStream(port_a2.h_outflow),
inStream(port_a2.Xi_outflow))))
"Real expression for evaporator inlet temperature";
Modelica.Blocks.Interfaces.RealOutput QCon_flow(final quantity="HeatFlowRate",
final unit="W") "Actual heating heat flow rate added to fluid 1";
Modelica.Blocks.Interfaces.RealOutput P(final quantity="Power", final unit="W")
"Electric power consumed by compressor";
Modelica.Blocks.Interfaces.RealOutput QEva_flow(final quantity="HeatFlowRate",
final unit="W") "Actual cooling heat flow rate removed from fluid 2";
Modelica.Blocks.Interfaces.RealOutput EER(unit="1") if use_EER and calEff
"Energy efficieny ratio";
Modelica.Blocks.Interfaces.RealOutput COP(unit="1") if use_COP and calEff
"Coefficient of performance";
Buildings.Fluid.HeatPumps.ModularReversible.BaseClasses.CalculateEfficiency
eff(PEleMin=PEle_nominal*0.1) if calEff "Calculate efficiencies of device";
// To avoid using the bus, set the section below to protected
//@modelica_select_start @remove_AixLib
protected
//@modelica_select_end
RefrigerantMachineControlBus sigBus
"Bus with model outputs and possibly inputs";
parameter Boolean use_busConOnl=false
"=true to allow input to bus connector,
not applicable with internal safety control";
//@modelica_select_start @remove_Buildings @remove_BuildingSystems @remove_IDEAS
// removed: protected
//@modelica_select_end
parameter Boolean use_COP "=true to enable COP output";
parameter Boolean use_EER "=true to enable EER output";
parameter MediumCon.ThermodynamicState staCon_nominal=MediumCon.setState_pTX(
T=MediumCon.T_default, p=MediumCon.p_default, X=MediumCon.X_default)
"Nominal state of condenser medium";
parameter MediumEva.ThermodynamicState staEva_nominal=MediumEva.setState_pTX(
T=MediumEva.T_default, p=MediumEva.p_default, X=MediumEva.X_default)
"Nominal state of evaporator medium";
equation
// Non bus connections
connect(safCtr.sigBus, sigBus);
connect(safCtr.yOut, sigBus.yMea);
connect(ySet, safCtr.ySet);
connect(TConAmb, varTOutCon.T);
connect(varTOutCon.port, con.port_out);
connect(TEvaAmb, varTOutEva.T);
connect(eva.port_out, varTOutEva.port);
connect(mEva_flow.port_a, port_a2);
connect(port_a1,mCon_flow. port_a);
connect(mEva_flow.port_b, eva.port_a);
connect(eva.port_b, port_b2);
connect(refCyc.QEva_flow, refCycIneEva.u);
connect(eva.Q_flow,refCycIneEva. y);
connect(refCycIneCon.y, con.Q_flow);
connect(refCycIneCon.u, refCyc.QCon_flow);
connect(mCon_flow.port_b, con.port_a);
connect(con.port_b, port_b1);
// External bus connections
connect(mEva_flow.m_flow, sigBus.mEvaMea_flow);
connect(mCon_flow.m_flow, sigBus.mConMea_flow);
connect(refCyc.sigBus, sigBus);
connect(refCyc.PEle, sigBus.PEleMea);
connect(TConAmb, sigBus.TConAmbMea);
connect(TEvaAmb, sigBus.TEvaAmbMea);
connect(con.T, sigBus.TConOutMea);
connect(senTConIn.y, sigBus.TConInMea);
connect(eva.T, sigBus.TEvaOutMea);
connect(senTEvaIn.y, sigBus.TEvaInMea);
if not use_intSafCtr then
connect(ySet, sigBus.yMea);
end if;
connect(ySet, sigBus.ySet);
connect(refCyc.PEle, P);
connect(refCycIneEva.y, QEva_flow);
connect(refCycIneCon.y, QCon_flow);
connect(eff.PEle, refCyc.PEle);
connect(eff.COP, COP);
connect(eff.EER, EER);
end PartialReversibleRefrigerantMachine;
Buildings.Fluid.HeatPumps.ModularReversible.BaseClasses.RefrigerantCycle
Refrigerant cycle model of a heat pump
Information
Modular refrigerant cycle model for heat pump applications used in the model Buildings.Fluid.HeatPumps.ModularReversible.Modular and extending models of the modular approach.
This model adds the replaceable model approaches for cooling and heating data to the partial refrigerant cylce.
Further, an asseration warning is raised if the model approaches or sources for performance data differ. This indicates that they are not for the same device.
For more information on the approach, please read the UsersGuide.
Extends from Buildings.Fluid.HeatPumps.ModularReversible.BaseClasses.PartialModularRefrigerantCycle (Partial refrigerant cycle model).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Boolean | use_rev | true | True if the refrigerant machine is reversible |
| Boolean | allowDifferentDeviceIdentifiers | false | if use_rev=true, device data for cooling and heating need to entered. Set allowDifferentDeviceIdentifiers=true to allow different device identifiers devIde |
| replaceable model RefrigerantCycleHeatPumpHeating | Buildings.Fluid.HeatPumps.Mo... | Replaceable model for refrigerant cycle of a heat pump in main operation mode | |
| replaceable model RefrigerantCycleHeatPumpCooling | Buildings.Fluid.Chillers.Mod... | Replaceable model for refrigerant cycle of a heat pump in reversed operation mode | |
Connectors
| Type | Name | Description |
|---|---|---|
| RefrigerantMachineControlBus | sigBus | Signal bus with data for refrigerant models |
| output RealOutput | QCon_flow | Heat flow rate from the refrigerant to the condenser medium [W] |
| output RealOutput | QEva_flow | Heat flow rate from the evaporator medium to the refrigerant [W] |
| output RealOutput | PEle | Routing block that picks the component for electric power consumption [W] |
| replaceable model RefrigerantCycleHeatPumpHeating | Replaceable model for refrigerant cycle of a heat pump in main operation mode | |
| replaceable model RefrigerantCycleHeatPumpCooling | Replaceable model for refrigerant cycle of a heat pump in reversed operation mode | |
Modelica definition
model RefrigerantCycle
"Refrigerant cycle model of a heat pump"
extends Buildings.Fluid.HeatPumps.ModularReversible.BaseClasses.PartialModularRefrigerantCycle;
parameter Boolean allowDifferentDeviceIdentifiers=false
"if use_rev=true, device data for cooling and heating need to entered. Set allowDifferentDeviceIdentifiers=true to allow different device identifiers devIde";
replaceable model RefrigerantCycleHeatPumpHeating =
Buildings.Fluid.HeatPumps.ModularReversible.RefrigerantCycle.BaseClasses.NoHeating(
useInHeaPum=true)
constrainedby Buildings.Fluid.HeatPumps.ModularReversible.RefrigerantCycle.BaseClasses.PartialHeatPumpCycle
"Replaceable model for refrigerant cycle of a heat pump in main operation mode";
replaceable model RefrigerantCycleHeatPumpCooling =
Buildings.Fluid.Chillers.ModularReversible.RefrigerantCycle.BaseClasses.NoCooling(
useInChi=true)
constrainedby Buildings.Fluid.Chillers.ModularReversible.RefrigerantCycle.BaseClasses.PartialChillerCycle
"Replaceable model for refrigerant cycle of a heat pump in reversed operation mode";
RefrigerantCycleHeatPumpHeating refCycHeaPumHea
"Refrigerant cycle instance for heating";
RefrigerantCycleHeatPumpCooling refCycHeaPumCoo
"Refrigerant cycle instance for cooling";
protected
parameter String devIde =
if use_rev then refCycHeaPumCoo.devIde else refCycHeaPumHea.devIde
"Data source for refrigerant cycle";
initial algorithm
if not allowDifferentDeviceIdentifiers then
assert(
devIde == refCycHeaPumHea.devIde,
"In " + getInstanceName() + ": Device identifiers devIde for reversible operation are not equal.
Heating device identifier is '" + refCycHeaPumHea.devIde + "' but cooling is '"
+ devIde + "'. To allow this, set 'allowDifferentDeviceIdentifiers=true'.",
AssertionLevel.error);
end if;
equation
connect(pasTrhModSet.u, sigBus.hea);
connect(sigBus,refCycHeaPumCoo.sigBus);
connect(sigBus,refCycHeaPumHea.sigBus);
connect(swiQCon.u2, sigBus.hea);
connect(swiPEle.u2, sigBus.hea);
connect(swiQEva.u2, sigBus.hea);
connect(refCycHeaPumHea.QCon_flow, swiQCon.u1);
connect(refCycHeaPumHea.QEva_flow, swiQEva.u1);
connect(refCycHeaPumCoo.QEva_flow, swiQCon.u3);
connect(refCycHeaPumCoo.QCon_flow, swiQEva.u3);
connect(refCycHeaPumCoo.PEle, swiPEle.u3);
connect(refCycHeaPumHea.PEle, swiPEle.u1);
end RefrigerantCycle;
Buildings.Fluid.HeatPumps.ModularReversible.BaseClasses.RefrigerantMachineControlBus
Bus connector for reversible heat pump and chiller model
Information
Bus connector for a refrigerant machine.
Used in the reversbile modular approaches for chiller and heat pump in the models Buildings.Fluid.Chillers.ModularReversible.Modular and Buildings.Fluid.HeatPumps.ModularReversible.Modular.
Extends from Modelica.Icons.SignalBus (Icon for signal bus).
Modelica definition
expandable connector RefrigerantMachineControlBus
"Bus connector for reversible heat pump and chiller model"
extends Modelica.Icons.SignalBus;
end RefrigerantMachineControlBus;
Buildings.Fluid.HeatPumps.ModularReversible.BaseClasses.PartialReversibleRefrigerantMachine.RefrigerantCycleInertia
Inertia between the refrigerant cycle outputs and the heat exchangers.
Connectors
| Type | Name | Description |
|---|---|---|
| input RealInput | u | Connector of Real input signal |
| output RealOutput | y | Connector of Real output signal |
Modelica definition
replaceable model RefrigerantCycleInertia =
Buildings.Fluid.HeatPumps.ModularReversible.RefrigerantCycle.Inertias.NoInertia
constrainedby Buildings.Fluid.HeatPumps.ModularReversible.RefrigerantCycle.Inertias.BaseClasses.PartialInertia
"Inertia between the refrigerant cycle outputs and the heat exchangers.";
Buildings.Fluid.HeatPumps.ModularReversible.BaseClasses.RefrigerantCycle.RefrigerantCycleHeatPumpHeating
Replaceable model for refrigerant cycle of a heat pump in main operation mode
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| String | devIde | "NoHeating" | Indicates the data source, used to warn users about different vapor compression devices in reversible models |
| Boolean | useInHeaPum | true | =false to indicate that this model is used in a chiller |
| Nominal condition | |||
| Power | PEle_nominal | 0 | Nominal electrical power consumption [W] |
| Temperature | TCon_nominal | 273.15 | Nominal temperature at secondary condenser side [K] |
| Temperature | TEva_nominal | 273.15 | Nominal temperature at secondary evaporator side [K] |
| HeatFlowRate | QHea_flow_nominal | 0 | Nominal heating capacity [W] |
| Advanced | |||
| Medium properties | |||
| SpecificHeatCapacity | cpCon | 4184 | Evaporator medium specific heat capacity [J/(kg.K)] |
| SpecificHeatCapacity | cpEva | 4184 | Evaporator medium specific heat capacity [J/(kg.K)] |
Connectors
| Type | Name | Description |
|---|---|---|
| output RealOutput | PEle | Electrical Power consumed by the device [W] |
| output RealOutput | QCon_flow | Heat flow rate through condenser [W] |
| RefrigerantMachineControlBus | sigBus | Bus-connector |
| output RealOutput | QEva_flow | Heat flow rate through evaporator [W] |
Modelica definition
replaceable model RefrigerantCycleHeatPumpHeating =
Buildings.Fluid.HeatPumps.ModularReversible.RefrigerantCycle.BaseClasses.NoHeating(
useInHeaPum=true)
constrainedby Buildings.Fluid.HeatPumps.ModularReversible.RefrigerantCycle.BaseClasses.PartialHeatPumpCycle
"Replaceable model for refrigerant cycle of a heat pump in main operation mode";
Buildings.Fluid.HeatPumps.ModularReversible.BaseClasses.RefrigerantCycle.RefrigerantCycleHeatPumpCooling
Replaceable model for refrigerant cycle of a heat pump in reversed operation mode
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| String | devIde | "NoCooling" | Indicates the data source, used to warn users about different vapor compression devices in reversible models |
| Boolean | useInChi | true | =false to indicate that this model is used as a heat pump |
| Nominal condition | |||
| Power | PEle_nominal | 0 | Nominal electrical power consumption [W] |
| Temperature | TCon_nominal | 273.15 | Nominal temperature at secondary condenser side [K] |
| Temperature | TEva_nominal | 273.15 | Nominal temperature at secondary evaporator side [K] |
| HeatFlowRate | QCoo_flow_nominal | 0 | Nominal cooling capacity [W] |
| Advanced | |||
| Medium properties | |||
| SpecificHeatCapacity | cpCon | 4184 | Evaporator medium specific heat capacity [J/(kg.K)] |
| SpecificHeatCapacity | cpEva | 4184 | Evaporator medium specific heat capacity [J/(kg.K)] |
Connectors
| Type | Name | Description |
|---|---|---|
| output RealOutput | PEle | Electrical Power consumed by the device [W] |
| output RealOutput | QCon_flow | Heat flow rate through condenser [W] |
| RefrigerantMachineControlBus | sigBus | Bus-connector |
| output RealOutput | QEva_flow | Heat flow rate through evaporator [W] |
Modelica definition
replaceable model RefrigerantCycleHeatPumpCooling =
Buildings.Fluid.Chillers.ModularReversible.RefrigerantCycle.BaseClasses.NoCooling(
useInChi=true)
constrainedby Buildings.Fluid.Chillers.ModularReversible.RefrigerantCycle.BaseClasses.PartialChillerCycle
"Replaceable model for refrigerant cycle of a heat pump in reversed operation mode";