Buildings.Fluid.SolarCollectors.BaseClasses

Information

This package contains base classes that are used to construct the models in Buildings.Fluid.SolarCollectors.

Package Content

Name	Description
ASHRAEHeatLoss	Calculate the heat loss of a solar collector per ASHRAE standard 93
ASHRAESolarGain	Calculate the solar heat gain of a solar collector per ASHRAE Standard 93
EN12975HeatLoss	Calculate the heat loss of a solar collector per EN12975
EN12975SolarGain	Model calculating solar gains per the EN12975 standard
PartialHeatLoss	Partial heat loss model on which ASHRAEHeatLoss and EN12975HeatLoss are based
PartialParameters	Partial model for parameters
PartialSolarCollector	Partial model for solar collectors
IAM	Function for incident angle modifer
Examples	Collection of models that illustrate model use and test models

Buildings.Fluid.SolarCollectors.BaseClasses.ASHRAEHeatLoss

Information

This component computes the heat loss from the solar thermal collector to the environment. It is designed for use with ratings data collected in accordance with ASHRAE Standard 93. A negative QLos[i] indicates that heat is being lost to the environment.

This model calculates the heat lost from a multiple-segment model using ratings data based solely on the inlet temperature. As a result, the slope from the ratings data is converted to a UA value which, for a given number of segments, yields the same heat loss as the ratings data would at nominal conditions. The first three equations, which perform calculations at nominal conditions without a UA value, are based on equations 6.17.1 through 6.17.3 in Duffie and Beckman (2006). The UA value is identified using the system of equations below:

Q_Use,nom = G_nom A_c F_R(τα) + F_RU_L A_c (T_In,nom - T_Env,nom )
T_Fluid,nom[nSeg]=T_In,nom+Q_Use,nom/(m _Flow,nomC_p)
Q_Los,nom=-F_RU_L A_c (T_In,nom -T_Env,nom)
T_Fluid,nom[i] = T_Fluid,nom[i-1] + (G_nom F _R(τα) A_c/nSeg - UA/nSeg (T_Fluid,nom[i-1] -T_Env,nom))/(m_Flow,nom c_p)
Q_Loss,UA=UA/nSeg (T_Fluid,nom[i]-T_Env,nom)
sum(Q_Loss,UA[1:nSeg])=Q_Loss,nom

where Q_Use,nom is the useful heat gain at nominal conditions, G_nom is the nominal solar irradiance, A_c is the area of the collector, F_R(τα) is the collector maximum efficiency, F_R U_L is the collector heat loss coefficient,T_In,nom is the nominal inlet temperature, T _Env,nom is the ambient temperature at nominal conditions, T _Fluid,nom[i] is the temperature of fluid in a given segment of the collector, m_Flow,nom is the fluid flow at nominal conditions, C_p is the specific heat of the heated fluid, Q _Loss,nom is the heat loss identified using the default value UA is the identified heat loss coefficient for a multiple-segment equivalent solar collector, nSeg is the number of segments in the simulation, and Q _Loss,UA is the heat loss identified using the UA value.

The effective UA value is calculated at the beginning of the simulation and used as a constant through the rest of the simulation. The actual heat loss from the collector is calculated using

-Q_Loss[i] = UA/nSeg (T_Fluid[i] - T_Env)

where Q_Loss[i] is the heat loss from a given segment, UA is the heat loss coefficient for a multiple segments model, nSeg is the number of segments in the simulation, T_Fluid[i] is the temperature of the fluid in a given segment, and T_Env is the temperature of the surrounding air.

This model reduces the heat loss rate to 0 W when the fluid temperature is within 1 degree C of the minimum temperature of the medium model. The calucation is performed using the Buildings.Utilities.Math.Functions.smoothHeaviside function.

References

J.A. Duffie and W.A. Beckman 2006, Solar Engineering of Thermal Processes (3rd Edition), John Wiley & Sons, Inc.
ASHRAE 93-2010 -- Methods of Testing to Determine the Thermal Performance of Solar Collectors (ANSI approved)

Parameters

Type	Name	Default	Description
Area	A_c		Area of the collector [m2]
Integer	nSeg	3	Number of segments
Real	y_intercept		Y intercept (Maximum efficiency)
replaceable package Medium		PartialMedium	Medium in the component
CoefficientOfHeatTransfer	slope		Slope from ratings data [W/(m2.K)]
Nominal condition
Irradiance	G_nominal		Irradiance at nominal conditions [W/m2]
TemperatureDifference	dT_nominal		Ambient temperature at nomincal conditions [K]
MassFlowRate	m_flow_nominal		Fluid flow rate at nominal conditions [kg/s]

Connectors

Type	Name	Description
input RealInput	TEnv	Temperature of surrounding environment [K]
input RealInput	TFlu[nSeg]	Temperature of the heat transfer fluid [K]
output RealOutput	QLos[nSeg]	Limited heat loss rate at current conditions [W]

Modelica definition

block ASHRAEHeatLoss 
  "Calculate the heat loss of a solar collector per ASHRAE standard 93"

  extends Buildings.Fluid.SolarCollectors.BaseClasses.PartialHeatLoss;

  parameter Modelica.SIunits.CoefficientOfHeatTransfer slope 
    "Slope from ratings data";

protected 
  final parameter Modelica.SIunits.ThermalConductance UA(start = -slope*A_c, fixed = false) 
    "Coefficient describing heat loss to ambient conditions";
initial equation 
   //Identifies useful heat gain at nominal conditions
   QUse_nominal = G_nominal * A_c * y_intercept + slope * A_c * (dT_nominal);
   //Identifies TFlu[nSeg] at nominal conditions
   m_flow_nominal * Cp_default * (dT_nominal_fluid[nSeg]) = QUse_nominal;
   //Identifies heat lost to environment at nominal conditions
   QLos_nominal = -slope * A_c * (dT_nominal);
   //Governing equation for the first segment (i=1)
   G_nominal * y_intercept * A_c/nSeg - UA/nSeg * (dT_nominal) = m_flow_nominal * Cp_default
   * (dT_nominal_fluid[1]);
   //Loop with the governing equations for segments 2:nSeg-1
   for i in 2:nSeg-1 loop
     G_nominal * y_intercept * A_c/nSeg - UA/nSeg * (dT_nominal_fluid[i-1]+dT_nominal) =
     m_flow_nominal * Cp_default * (dT_nominal_fluid[i]-dT_nominal_fluid[i-1]);
   end for;
   for i in 1:nSeg loop
     nSeg * QLosUA[i] = UA * (dT_nominal_fluid[i]+dT_nominal);
   end for;
   sum(QLosUA[1:nSeg]) = QLos_nominal;
equation 
   for i in 1:nSeg loop
     -QLosInt[i] * nSeg = UA * (TFlu[i] - TEnv);
   end for;
end ASHRAEHeatLoss;

Buildings.Fluid.SolarCollectors.BaseClasses.ASHRAESolarGain

Information

This component computes the solar heat gain of the solar thermal collector. It only calculates the solar heat gain without considering the heat loss to the environment. This model uses ratings data according to ASHRAE93. The solar heat gain is calculated using Equations 555 - 559 in the referenced EnergyPlus documentation.

The solar radiation absorbed by the panel is identified using Eq 559 from the EnergyPlus documentation. It is

Q_Flow[i]=A_c/nSeg (F_R(τα) K_(τα)net (G_Dir (1-shaCoe)+G_Dif,Sky+G_Dif,Gnd))

where Q_Flow[i] is the heat gain in each segment, A _c is the area of the collector, nSeg is the user-specified number of segments in the simulation, F_R(τα) is the maximum collector efficiency, K_(τα)net> is the incidence angle modifier, G_Dir is the direct solar radiation, shaCoe is the user-specified shading coefficient, G_Dif,Sky is the diffuse solar radiation from the sky, and G_Dif,Gnd is the diffuse radiation from the ground.

The solar radiation equation indicates that the collector is divided into multiple segments. The number of segments used in the simulation is specified by the user (parameter: nSeg). The area of an individual segment is identified by dividing the collector area by the total number of segments. The term shaCoe is used to define the percentage of the collector that is shaded.

The incidence angle modifier used in the solar radiation equation is found using Eq 556 from the EnergyPlus documentation. It is

K_(τα),net=(G_Beam K_{(τα), Beam}+G_Dif,Sky K_(τα),Sky+G_Dif,Gnd K_(τα),Gnd) / (G_beam+G_Dif,Sky+G _Dif,Gnd)

where K_(τα),net is the net incidence angle modified, G_Beam is the beam radiation, K_(τα),Beam is the incidence angle modifier for beam radiation, G_Dif,Sky is the diffuse radiation from the sky, K_(τα),Sky is the incidence angle modifier for radiation from the sky, G_{Dif, Gnd} is the diffuse radiation from the ground, and K_(τα),Gnd is the incidence angle modifier for diffuse radiation from the ground.

Each incidence angle modifier is calculated using Eq 555 from the EnergyPlus documentation. It is

K_(τα),x=1+b₀ (1/cos(θ)-1)+b₁ (1/cos(θ)-1)²

where x can refer to beam, sky or ground. θ is the incidence angle. For beam radiation θ is found via standard geometry. The incidence angle for sky and ground diffuse radiation are found using, respectively, Eq 557 and 558 from the EnergyPlus documentation. They are

θ_sky=59.68-0.1388 til+0.001497 til²
θ_gnd=90.0-0.5788 til+0.002693 til²

where θ_sky is the incidence angle for diffuse radiation from the sky, til is the tilt of the solar thermal collector, and θ_gnd is the incidence angle for diffuse radiation from the ground.

These two equations must be evaluated in degrees. The necessary unit conversions are made internally.

This model reduces the heat gain rate to 0 W when the fluid temperature is within 1 degree C of the maximum temperature of the medium model. The calucation is performed using the Buildings.Utilities.Math.Functions.smoothHeaviside function.

References

EnergyPlus 7.0.0 Engineering Reference, October 13, 2011.
ASHRAE 93-2010 -- Methods of Testing to Determine the Thermal Performance of Solar Collectors (ANSI approved)

Parameters

Type	Name	Default	Description
Area	A_c		Area of the collector [m2]
Integer	nSeg	3	Number of segments
Real	y_intercept		Y intercept (Maximum efficiency)
Real	B0		1st incident angle modifer coefficient
Real	B1		2nd incident angle modifer coefficient
Angle	til		Surface tilt [rad]
replaceable package Medium		Modelica.Media.Interfaces.Pa...	Medium in the system
Shading
Boolean	use_shaCoe_in	false	Enable input connector for shaCoe
Real	shaCoe	0	Shading coefficient 0.0: no shading, 1.0: full shading

Connectors

Type	Name	Description
replaceable package Medium		Medium in the system
input RealInput	shaCoe_in	Shading coefficient
input RealInput	TFlu[nSeg]	[K]
input RealInput	HSkyDifTil	Diffuse solar irradiation on a tilted surfce from the sky [W/m2]
input RealInput	HGroDifTil	Diffuse solar irradiation on a tilted surfce from the ground [W/m2]
input RealInput	incAng	Incidence angle of the sun beam on a tilted surface [rad]
input RealInput	HDirTil	Direct solar irradiation on a tilted surfce [W/m2]
output RealOutput	QSol_flow[nSeg]	Solar heat gain [W]

Modelica definition

block ASHRAESolarGain 
  "Calculate the solar heat gain of a solar collector per ASHRAE Standard 93"
  extends Modelica.Blocks.Interfaces.BlockIcon;
  extends SolarCollectors.BaseClasses.PartialParameters;

  parameter Real B0 "1st incident angle modifer coefficient";
  parameter Real B1 "2nd incident angle modifer coefficient";
  parameter Boolean use_shaCoe_in = false "Enable input connector for shaCoe";

  parameter Real shaCoe(
    min=0.0,
    max=1.0) = 0 "Shading coefficient 0.0: no shading, 1.0: full shading";

  parameter Modelica.SIunits.Angle til "Surface tilt";

  replaceable package Medium = Modelica.Media.Interfaces.PartialMedium 
    "Medium in the system";

  Modelica.Blocks.Interfaces.RealInput shaCoe_in if use_shaCoe_in 
    "Shading coefficient";
   Modelica.Blocks.Interfaces.RealInput TFlu[nSeg](
   unit = "K",
   displayUnit="degC",
   quantity="Temperature");
   Modelica.Blocks.Interfaces.RealInput HSkyDifTil(
     unit="W/m2", quantity="RadiantEnergyFluenceRate") 
    "Diffuse solar irradiation on a tilted surfce from the sky";
  Modelica.Blocks.Interfaces.RealInput HGroDifTil(
    unit="W/m2", quantity="RadiantEnergyFluenceRate") 
    "Diffuse solar irradiation on a tilted surfce from the ground";
  Modelica.Blocks.Interfaces.RealInput incAng(
    quantity="Angle",
    unit="rad",
    displayUnit="degree") "Incidence angle of the sun beam on a tilted surface";
  Modelica.Blocks.Interfaces.RealInput HDirTil(
    unit="W/m2", quantity="RadiantEnergyFluenceRate") 
    "Direct solar irradiation on a tilted surfce";
  Modelica.Blocks.Interfaces.RealOutput QSol_flow[nSeg](final unit="W") 
    "Solar heat gain";

protected 
  final parameter Real iamSky( fixed = false) 
    "Incident angle modifier for diffuse solar radiation from the sky";
  final parameter Real iamGro( fixed = false) 
    "Incident angle modifier for diffuse solar radiation from the ground";
  final parameter Modelica.SIunits.Angle incAngSky( fixed = false) 
    "Incident angle of diffuse radiation from the sky";
  final parameter Modelica.SIunits.Angle incAngGro( fixed = false) 
    "Incident angle of diffuse radiation from the ground";
  final parameter Real tilDeg(
    unit = "deg") = Modelica.SIunits.Conversions.to_deg(til) 
    "Surface tilt angle in degrees";
  final parameter Modelica.SIunits.HeatFlux HTotMin = 1 
    "Minimum HTot to avoid div/0";
  final parameter Real HMinDel = 0.001 
    "Delta of the smoothing function for HTot";

  Real iamBea "Incident angle modifier for director solar radiation";
  Real iam "Weighted incident angle modifier";

  Modelica.Blocks.Interfaces.RealInput shaCoe_internal 
    "Internally used shading coefficient";

initial equation 
  // E+ Equ (557)
  incAngSky = Modelica.SIunits.Conversions.from_deg(59.68 - 0.1388*(tilDeg) +
  0.001497*(tilDeg)^2);
  // Diffuse radiation from the sky
  // E+ Equ (555)
  iamSky = SolarCollectors.BaseClasses.IAM(incAngSky, B0, B1);
  // E+ Equ (558)
  incAngGro = Modelica.SIunits.Conversions.from_deg(90 - 0.5788*(tilDeg)+
  0.002693*(tilDeg)^2);
  // Diffuse radiation from the ground
  // E+ Equ (555)
  iamGro = SolarCollectors.BaseClasses.IAM(
    incAngGro,
    B0,
    B1);

equation 

  connect(shaCoe_internal, shaCoe_in);

  if not use_shaCoe_in then
    shaCoe_internal = shaCoe;
  end if;

  // E+ Equ (555)
  iamBea = Buildings.Utilities.Math.Functions.smoothHeaviside(1/3*
  Modelica.Constants.pi- incAng, Modelica.Constants.pi/60)*
  SolarCollectors.BaseClasses.IAM(
    incAng,
    B0,
    B1);
  // E+ Equ (556)
  iam = Buildings.Utilities.Math.Functions.smoothHeaviside(
      1/3*Modelica.Constants.pi-incAng,Modelica.Constants.pi/60)*
      ((HDirTil*iamBea + HSkyDifTil*iamSky + HGroDifTil*iamGro)/
      Buildings.Utilities.Math.Functions.smoothMax((HDirTil +
      HSkyDifTil + HGroDifTil), HTotMin, HMinDel));
  // Modified from EnergyPlus Equ (559) by applying shade effect for
  //direct solar radiation
  // Only solar heat gain is considered here
  for i in 1 : nSeg loop
    QSol_flow[i] = A_c/nSeg*(y_intercept*iam*(HDirTil*(1.0 -
    shaCoe_internal) + HSkyDifTil + HGroDifTil))*
    Buildings.Utilities.Math.Functions.smoothHeaviside(
     (Medium.T_max+1)-TFlu[i],1);
  end for;

end ASHRAESolarGain;

Buildings.Fluid.SolarCollectors.BaseClasses.EN12975HeatLoss

Information

This component computes the heat loss from the solar thermal collector to the environment. It is designed anticipating ratings data collected in accordance with EN12975. A negative QLos[i] indicates that heat is being lost to the environment.

This model calculates the heat lost from a multiple-segment model using ratings data based on the mean collector temperature. As a result, the slope from the ratings data must be converted to a UA value which, for a given number of segments, returns the same heat loss as the ratings data would at nominal conditions. The UA value is identified using the system of equations below:

Q_Use,nom = G_nom A_c F_R (τα) - C₁ A_c (T_Mean,nom- T_Env,nom)-C₂ A_c (T_Mean,nom -T_Env,nom)²
T_Fluid,nom[nSeg]=T_Mean,nom+Q_Use,nom/ (m_Flow,nom C_p)
Q_Los,nom=-C₁ A_c (T_Mean,nom-T _Env,nom)-C₂ A_c (T_Mean,nom- T_Env,nom)²
T_Fluid,nom[i] = T_Fluid,nom[i-1] + (G_nom F_R(τα) A_c/nSeg - UA/nSeg (T_{Fluid, nom}[i-1]-T_Env,nom))/(m_Flow,nom c_p )
Q_Loss,UA=UA/nSeg (T_Fluid,nom[i]-T_Env,nom )
sum(Q_Loss,UA[1:nSeg])=Q_Loss,nom

where Q_Use,nom is the useful heat gain at nominal conditions,G_nom is the nominal solar irradiance, A_c is the area of the collector, F_R (τα) is the collector maximum efficiency, C₁ is the collector heat loss coefficient, C₂ is the temperature dependance of the heat loss coefficient, T_{Mean, nom} is the nominal mean temperature of the solar collector, T _Env,nom is the ambient temperature at nominal conditions, T_Fluid,nom[i] is the temperature of fluid in a given segment of the collector, m_Flow,nom is the fluid flow at nominal conditions, C_p is the specific heat of the heated fluid, Q_Loss,nom is the heat loss identified using the default value UA is the identified heat loss coefficient for a multiple-segment equivalent solar collector, nSeg is the number of segments in the simulation, and Q_Loss,UA is the heat loss identified using the UA value.

The effective UA value is calculated at the beginning of the simulation and used as a constant through the rest of the simulation. The actual heat loss from the collector is calculated using

Q_Loss[i] = UA/nSeg (T_Fluid[i] - T_Env).

where Q_Loss[i] is the heat loss from a given segment, UA is the heat loss coefficient for a multiple segments model, nSeg is the number of segments in the simulation,T_Fluid [i] is the temperature of the fluid in a given segment, and T_Env is the temperature of the surrounding air.

This model reduces the heat loss rate to 0 W when the fluid temperature is within 1 degree C of the minimum temperature of the medium model. The calucation is performed using the Buildings.Utilities.Math.Functions.smoothHeaviside function.

References

CEN 2006, European Standard 12975-1:2006, European Committee for Standardization

Parameters

Type	Name	Default	Description
Area	A_c		Area of the collector [m2]
Integer	nSeg	3	Number of segments
Real	y_intercept		Y intercept (Maximum efficiency)
replaceable package Medium		PartialMedium	Medium in the component
CoefficientOfHeatTransfer	C1		C1 from ratings data [W/(m2.K)]
Real	C2		C2 from ratings data [W/(m2.K2)]
Nominal condition
Irradiance	G_nominal		Irradiance at nominal conditions [W/m2]
TemperatureDifference	dT_nominal		Ambient temperature at nomincal conditions [K]
MassFlowRate	m_flow_nominal		Fluid flow rate at nominal conditions [kg/s]

Connectors

Type	Name	Description
input RealInput	TEnv	Temperature of surrounding environment [K]
input RealInput	TFlu[nSeg]	Temperature of the heat transfer fluid [K]
output RealOutput	QLos[nSeg]	Limited heat loss rate at current conditions [W]

Modelica definition

block EN12975HeatLoss 
  "Calculate the heat loss of a solar collector per EN12975"

  extends Buildings.Fluid.SolarCollectors.BaseClasses.PartialHeatLoss;

  parameter Modelica.SIunits.CoefficientOfHeatTransfer C1 
    "C1 from ratings data";
  parameter Real C2(
  final unit = "W/(m2.K2)") "C2 from ratings data";

protected 
  final parameter Modelica.SIunits.ThermalConductance UA(
     fixed = false,
     start=QLos_nominal/(dT_nominal)) 
    "Coefficient describing heat loss to ambient conditions";
initial equation 
   //Identifies useful heat gain at nominal conditions
   QUse_nominal = G_nominal * A_c * y_intercept -C1 * A_c *
      (dT_nominal) - C2 * A_c * (dT_nominal)^2;
   //Identifies TFlu[nSeg] at nominal conditions
   m_flow_nominal * Cp_default * (dT_nominal_fluid[nSeg]) = QUse_nominal;
   //Identifies heat lost to environment at nominal conditions
   QLos_nominal = -C1 * A_c * (dT_nominal)-C2 * A_c * (dT_nominal)^2;
   //Governing equation for the first segment (i=1)
   G_nominal * y_intercept * A_c/nSeg - UA/nSeg * (dT_nominal)
     = m_flow_nominal * Cp_default * (dT_nominal_fluid[1]);
   //Loop with the governing equations for segments 2:nSeg-1
   for i in 2:nSeg-1 loop
     G_nominal * y_intercept * A_c/nSeg - UA/nSeg * (dT_nominal_fluid[i-1]
     +dT_nominal)= m_flow_nominal * Cp_default * (dT_nominal_fluid[i]-
     dT_nominal_fluid[i-1]);
   end for;
   for i in 1:nSeg loop
     nSeg * QLosUA[i] = UA * (dT_nominal_fluid[i]+dT_nominal);
   end for;
   sum(QLosUA) = QLos_nominal;
equation 
   for i in 1:nSeg loop
     QLosInt[i] * nSeg = UA * (TFlu[i] - TEnv);
   end for;
end EN12975HeatLoss;

Buildings.Fluid.SolarCollectors.BaseClasses.EN12975SolarGain

Information

This component computes the solar heat gain of the solar thermal collector. It only calculates the solar heat gain without considering the heat loss to the environment. This model performs calculations using ratings data from EN12975. The solar heat gain is calculated using Equation 559 in the referenced EnergyPlus documentation. The calculation is modified somewhat to use coefficients from EN12975.

The equation used to calculate solar gain is a modified version of Eq 559 from the EnergyPlus documentation. It is

Q_Flow[i] = A_c/nSeg F_R(τα) (K _(τα),Beam G_Beam (1-shaCoe)+K_Diff G _Diff),

where Q_Flow[i] is the heat gained in each segment, A _c is the area of the collector, nSeg is the number of segments in the collector, F_R(τα) is the maximum efficiency of the collector, K_(τα),Beam is the incidence angle modifier for beam radiation, G_Beam is the current beam radiation on the collector, shaCoe is the shading coefficient, K_Diff is the incidence angle modifier for diffuse radiation and G_Diff is the diffuse radiation striking the surface.

The solar radiation equation indicates that the collector is divided into multiple segments. The number of segments used in the simulation is specified using the parameter nSeg. The area of an individual segment is identified by dividing the collector area by the total number of segments. The parameter shaCoe is used to define the percentage of the collector which is shaded. The main difference between this model and the ASHRAE model is the handling of diffuse radiation. The ASHRAE model contains calculated incidence angle modifiers for both sky and ground diffuse radiation while this model uses a coefficient from test data for diffuse radiation.

The incidence angle modifier for beam radiation is calculated using Eq 555 from the EnergyPlus documentation, as

K_(τα),Beam=1+b₀ (1/cos(θ)-1)+b₁ (1/cos(θ)-1)²,

where K_(τα),Beam is the incidence angle modifier for beam radiation, b₀ is the first incidence angle modifier coefficient, θ is the incidence angle and b₁ is the second incidence angle modifier coefficient.

This model reduces the heat gain rate to 0 W when the fluid temperature is within 1 degree C of the maximum temperature of the medium model. The calucation is performed using the Buildings.Utilities.Math.Functions.smoothHeaviside function.

References

EnergyPlus 7.0.0 Engineering Reference, October 13, 2011.
CEN 2006, European Standard 12975-1:2006, European Committee for Standardization

Parameters

Type	Name	Default	Description
Area	A_c		Area of the collector [m2]
Integer	nSeg	3	Number of segments
Real	y_intercept		Y intercept (Maximum efficiency)
Real	B0		1st incident angle modifer coefficient
Real	B1		2nd incident angle modifer coefficient
Real	iamDiff		Incidence angle modifier for diffuse radiation
replaceable package Medium		Modelica.Media.Interfaces.Pa...	Medium in the system
Shading
Boolean	use_shaCoe_in	false	Enables an input connector for shaCoe
Real	shaCoe	0	Shading coefficient 0.0: no shading, 1.0: full shading

Connectors

Type	Name	Description
replaceable package Medium		Medium in the system
input RealInput	shaCoe_in	Time varying input for the shading coefficient
input RealInput	HSkyDifTil	Diffuse solar irradiation on a tilted surfce from the sky [W/m2]
input RealInput	incAng	Incidence angle of the sun beam on a tilted surface [rad]
input RealInput	HDirTil	Direct solar irradiation on a tilted surfce [W/m2]
output RealOutput	QSol_flow[nSeg]	Solar heat gain [W]
input RealInput	TFlu[nSeg]	[K]

Modelica definition

model EN12975SolarGain 
  "Model calculating solar gains per the EN12975 standard"
  extends Modelica.Blocks.Interfaces.BlockIcon;
  extends SolarCollectors.BaseClasses.PartialParameters;

  parameter Real B0 "1st incident angle modifer coefficient";
  parameter Real B1 "2nd incident angle modifer coefficient";
  parameter Boolean use_shaCoe_in = false 
    "Enables an input connector for shaCoe";
  parameter Real shaCoe(
    min=0.0,
    max=1.0) = 0 "Shading coefficient 0.0: no shading, 1.0: full shading";
  parameter Real iamDiff "Incidence angle modifier for diffuse radiation";

  replaceable package Medium = Modelica.Media.Interfaces.PartialMedium 
    "Medium in the system";
  Modelica.Blocks.Interfaces.RealInput shaCoe_in if use_shaCoe_in 
    "Time varying input for the shading coefficient";

  Modelica.Blocks.Interfaces.RealInput HSkyDifTil(
    unit="W/m2", quantity="RadiantEnergyFluenceRate") 
    "Diffuse solar irradiation on a tilted surfce from the sky";
  Modelica.Blocks.Interfaces.RealInput incAng(
    quantity="Angle",
    unit="rad",
    displayUnit="degree") "Incidence angle of the sun beam on a tilted surface";
  Modelica.Blocks.Interfaces.RealInput HDirTil(
    unit="W/m2", quantity="RadiantEnergyFluenceRate") 
    "Direct solar irradiation on a tilted surfce";
  Modelica.Blocks.Interfaces.RealOutput QSol_flow[nSeg](final unit="W") 
    "Solar heat gain";
  Modelica.Blocks.Interfaces.RealInput TFlu[nSeg](
     unit="K",
     displayUnit="degC",
     quantity="Temperature");

protected 
  Real iamBea "Incidence angle modifier for director solar radiation";
  Modelica.Blocks.Interfaces.RealInput shaCoe_internal "Internally used shaCoe";

equation 
  connect(shaCoe_internal, shaCoe_in);

  // E+ Equ (555)
  iamBea = Buildings.Utilities.Math.Functions.smoothHeaviside(x=Modelica.Constants.pi
    /3 - incAng, delta=Modelica.Constants.pi/60)*
    SolarCollectors.BaseClasses.IAM(
    incAng,
    B0,
    B1);
  // Modified from EnergyPlus Equ (559) by applying shade effect for direct solar radiation
  // Only solar heat gain is considered here

  if not use_shaCoe_in then
    shaCoe_internal = shaCoe;
  end if;

  for i in 1 : nSeg loop
  QSol_flow[i] = A_c/nSeg*(y_intercept*(iamBea*HDirTil*(1.0 - shaCoe_internal) + iamDiff *
  HSkyDifTil))*Buildings.Utilities.Math.Functions.smoothHeaviside((Medium.T_max+1)-TFlu[i],1);
  end for;
end EN12975SolarGain;

Buildings.Fluid.SolarCollectors.BaseClasses.PartialHeatLoss

Information

This component is a partial model used as the base for Buildings.Fluid.SolarCollectors.BaseClasses.ASHRAEHeatLoss and Buildings.Fluid.SolarCollectors.BaseClasses.EN12975HeatLoss. It contains the input, output and parameter declarations which are common to both models. More detailed information is available in the documentation for the extending classes.

Parameters

Type	Name	Default	Description
Area	A_c		Area of the collector [m2]
Integer	nSeg	3	Number of segments
Real	y_intercept		Y intercept (Maximum efficiency)
replaceable package Medium		Modelica.Media.Interfaces.Pa...	Medium in the component
Nominal condition
Irradiance	G_nominal		Irradiance at nominal conditions [W/m2]
TemperatureDifference	dT_nominal		Ambient temperature at nomincal conditions [K]
MassFlowRate	m_flow_nominal		Fluid flow rate at nominal conditions [kg/s]

Connectors

Type	Name	Description
replaceable package Medium		Medium in the component
input RealInput	TEnv	Temperature of surrounding environment [K]
input RealInput	TFlu[nSeg]	Temperature of the heat transfer fluid [K]
output RealOutput	QLos[nSeg]	Limited heat loss rate at current conditions [W]

Modelica definition

block PartialHeatLoss 
  "Partial heat loss model on which ASHRAEHeatLoss and EN12975HeatLoss are based"
  extends Modelica.Blocks.Interfaces.BlockIcon;
  extends SolarCollectors.BaseClasses.PartialParameters;

  replaceable package Medium = Modelica.Media.Interfaces.PartialMedium 
    "Medium in the component";

  parameter Modelica.SIunits.Irradiance G_nominal 
    "Irradiance at nominal conditions";
  parameter Modelica.SIunits.TemperatureDifference dT_nominal 
    "Ambient temperature at nomincal conditions";
  parameter Modelica.SIunits.MassFlowRate m_flow_nominal 
    "Fluid flow rate at nominal conditions";

  Modelica.Blocks.Interfaces.RealInput TEnv(
    quantity="ThermodynamicTemperature",
    unit="K",
    displayUnit="degC") "Temperature of surrounding environment";

public 
  Modelica.Blocks.Interfaces.RealInput TFlu[nSeg](
    quantity="ThermodynamicTemperature",
    unit = "K",
    displayUnit="degC") "Temperature of the heat transfer fluid";
  Modelica.Blocks.Interfaces.RealOutput QLos[nSeg](
    quantity="HeatFlowRate",
    unit="W",
    displayUnit="W") "Limited heat loss rate at current conditions";

protected 
  final parameter Modelica.SIunits.HeatFlowRate QUse_nominal(fixed = false) 
    "Useful heat gain at nominal conditions";
  final parameter Modelica.SIunits.HeatFlowRate QLos_nominal(fixed = false) 
    "Heat loss at nominal conditions";
  final parameter Modelica.SIunits.HeatFlowRate QLosUA[nSeg](fixed = false) 
    "Heat loss at current conditions";
  final parameter Modelica.SIunits.Temperature dT_nominal_fluid[nSeg](each 
  start = 293.15, fixed = false) 
    "Temperature of each semgent in the collector at nominal conditions";
  Medium.ThermodynamicState sta_default=Medium.setState_pTX(
      T=Medium.T_default,
      p=Medium.p_default,
      X=Medium.X_default);
  Modelica.SIunits.SpecificHeatCapacity Cp_default = Medium.specificHeatCapacityCp(sta_default) 
    "Specific heat capacity of the fluid";
  Modelica.SIunits.HeatFlowRate QLosInt[nSeg] 
    "Heat loss rate at current conditions";

equation 
  for i in 1:nSeg loop
    QLos[i] = QLosInt[i] * Buildings.Utilities.Math.Functions.smoothHeaviside(
     TFlu[i]-(Medium.T_min+1), 1);
  end for;

end PartialHeatLoss;

Buildings.Fluid.SolarCollectors.BaseClasses.PartialParameters

Information

Partial parameters used in all solar collector models

Parameters

Type	Name	Default	Description
Area	A_c		Area of the collector [m2]
Integer	nSeg	3	Number of segments
Real	y_intercept		Y intercept (Maximum efficiency)

Modelica definition

block PartialParameters "Partial model for parameters"

  parameter Modelica.SIunits.Area A_c "Area of the collector";
  parameter Integer nSeg(min=3)=3 "Number of segments";
  parameter Real y_intercept "Y intercept (Maximum efficiency)";

end PartialParameters;

Buildings.Fluid.SolarCollectors.BaseClasses.PartialSolarCollector

Information

This component is a partial model of a solar thermal collector. It can be expanded to create solar collector models based on either ASHRAE93 or EN12975 ratings data.

Notice

1. As mentioned in the reference, the SRCC incident angle modifier equation coefficients are only valid for incident angles of 60 degrees or less. Because these curves behave poorly for angles greater than 60 degrees the model does not calculatue either direct or diffuse solar radiation gains when the incidence angle is greater than 60 degrees.
2. By default, the estimated heat capacity of the collector without fluid is calculated based on the dry mass and the specific heat capacity of copper.

References

EnergyPlus 7.0.0 Engineering Reference, October 13, 2011.
CEN 2006, European Standard 12975-1:2006, European Committee for Standardization

Parameters

Type	Name	Default	Description
replaceable package Medium		PartialMedium	Medium in the component
Integer	nSeg	3	Number of segments used to discretize the collector model
Angle	lat		Latitude [rad]
Angle	azi		Surface azimuth [rad]
Angle	til		Surface tilt [rad]
Real	rho		Ground reflectance
HeatCapacity	C	385*perPar.mDry	Heat capacity of solar collector without fluid (default: cp_copper*mDry*nPanels) [J/K]
Nominal condition
Pressure	dp_nominal	dp_nominal_final	Pressure [Pa]
MassFlowRate	m_flow_nominal	perPar.mperA_flow_nominal*pe...	Nominal mass flow rate [kg/s]
Initialization
MassFlowRate	m_flow.start	0	Mass flow rate from port_a to port_b (m_flow > 0 is design flow direction) [kg/s]
Pressure	dp.start	0	Pressure difference between port_a and port_b [Pa]
Shading
Boolean	use_shaCoe_in	false	Enables an input connector for shaCoe
Real	shaCoe	0	Shading coefficient. 0.0: no shading, 1.0: full shading
Area declarations
NumberSelection	nColType	Buildings.Fluid.SolarCollect...	Selection of area specification format
Integer	nPanels	0	Desired number of panels in the simulation
Area	totalArea	0	Total area of panels in the simulation [m2]
Configuration declarations
SystemConfiguration	sysConfig	Buildings.Fluid.SolarCollect...	Selection of system configuration
Dynamics
Equations
Dynamics	energyDynamics	Modelica.Fluid.Types.Dynamic...	Formulation of energy balance
Dynamics	massDynamics	energyDynamics	Formulation of mass balance
Initialization
AbsolutePressure	p_start	Medium.p_default	Start value of pressure [Pa]
Temperature	T_start	Medium.T_default	Start value of temperature [K]
MassFraction	X_start[Medium.nX]	Medium.X_default	Start value of mass fractions m_i/m [kg/kg]
ExtraProperty	C_start[Medium.nC]	fill(0, Medium.nC)	Start value of trace substances
ExtraProperty	C_nominal[Medium.nC]	fill(1E-2, Medium.nC)	Nominal value of trace substances. (Set to typical order of magnitude.)
Flow resistance
Boolean	computeFlowResistance	true	=true, compute flow resistance. Set to false to assume no friction
Boolean	from_dp	false	= true, use m_flow = f(dp) else dp = f(m_flow)
Boolean	linearizeFlowResistance	false	= true, use linear relation between m_flow and dp for any flow rate
Real	deltaM	0.1	Fraction of nominal flow rate where flow transitions to laminar
Assumptions
Boolean	allowFlowReversal	system.allowFlowReversal	= true to allow flow reversal, false restricts to design direction (port_a -> port_b)
Advanced
MassFlowRate	m_flow_small	1E-4*abs(m_flow_nominal)	Small mass flow rate for regularization of zero flow [kg/s]
Boolean	homotopyInitialization	true	= true, use homotopy method
Diagnostics
Boolean	show_T	false	= true, if actual temperature at port is computed

Connectors

Type	Name	Description
FluidPort_a	port_a	Fluid connector a (positive design flow direction is from port_a to port_b)
FluidPort_b	port_b	Fluid connector b (positive design flow direction is from port_a to port_b)
input RealInput	shaCoe_in	Shading coefficient
Bus	weaBus	Weather data bus

Modelica definition

model PartialSolarCollector "Partial model for solar collectors"
 extends Buildings.Fluid.Interfaces.LumpedVolumeDeclarations;
  extends Buildings.Fluid.Interfaces.TwoPortFlowResistanceParameters(final dp_nominal = dp_nominal_final);
  extends Buildings.Fluid.Interfaces.PartialTwoPortInterface(
    showDesignFlowDirection=false,
    final m_flow_nominal=perPar.mperA_flow_nominal*perPar.A);
  parameter Integer nSeg(min=3) = 3 
    "Number of segments used to discretize the collector model";

  parameter Modelica.SIunits.Angle lat "Latitude";
  parameter Modelica.SIunits.Angle azi "Surface azimuth";
  parameter Modelica.SIunits.Angle til "Surface tilt";
  parameter Real rho "Ground reflectance";
  parameter Modelica.SIunits.HeatCapacity C=385*perPar.mDry 
    "Heat capacity of solar collector without fluid (default: cp_copper*mDry*nPanels)";

  parameter Boolean use_shaCoe_in = false 
    "Enables an input connector for shaCoe";
  parameter Real shaCoe(
    min=0.0,
    max=1.0) = 0 "Shading coefficient. 0.0: no shading, 1.0: full shading";

  parameter Buildings.Fluid.SolarCollectors.Types.NumberSelection nColType=
  Buildings.Fluid.SolarCollectors.Types.NumberSelection.Number 
    "Selection of area specification format";
  parameter Integer nPanels= 0 "Desired number of panels in the simulation";

  parameter Modelica.SIunits.Area totalArea=0 
    "Total area of panels in the simulation";

  parameter Buildings.Fluid.SolarCollectors.Types.SystemConfiguration sysConfig=
  Buildings.Fluid.SolarCollectors.Types.SystemConfiguration.Series 
    "Selection of system configuration";

  Modelica.Blocks.Interfaces.RealInput shaCoe_in if use_shaCoe_in 
    "Shading coefficient";

  Modelica.Thermal.HeatTransfer.Components.HeatCapacitor heaCap[nSeg](
    T(each start =   T_start), each C=(C*nPanels_internal)/nSeg) if 
       not (energyDynamics == Modelica.Fluid.Types.Dynamics.SteadyState) 
    "Heat capacity for one segment of the the solar collector";

  Buildings.BoundaryConditions.WeatherData.Bus weaBus "Weather data bus";
  Buildings.BoundaryConditions.SolarIrradiation.DiffusePerez HDifTilIso(
    final outSkyCon=true,
    final outGroCon=true,
    final til=til,
    final lat=lat,
    final azi=azi,
    final rho=rho) "Diffuse solar irradiation on a tilted surface";

  Buildings.BoundaryConditions.SolarIrradiation.DirectTiltedSurface HDirTil(
    final til=til,
    final lat=lat,
    final azi=azi) "Direct solar irradiation on a tilted surface";

  Buildings.Fluid.Sensors.MassFlowRate senMasFlo(redeclare package Medium =
    Medium, allowFlowReversal=allowFlowReversal) "Mass flow rate sensor";
  Buildings.Fluid.FixedResistances.FixedResistanceDpM res(
    redeclare final package Medium = Medium,
    final from_dp=from_dp,
    final show_T=show_T,
    final m_flow_nominal=m_flow_nominal,
    final allowFlowReversal=allowFlowReversal,
    final linearized=linearizeFlowResistance,
    final homotopyInitialization=homotopyInitialization,
    use_dh=false,
    deltaM=deltaM,
    final dp_nominal=dp_nominal_final) "Flow resistance";
  Buildings.Fluid.MixingVolumes.MixingVolume vol[nSeg](
    each nPorts=2,
    redeclare package Medium = Medium,
    each final m_flow_nominal=m_flow_nominal,
    each final energyDynamics=energyDynamics,
    each final p_start=p_start,
    each final T_start=T_start,
    each m_flow_small=m_flow_small,
    each homotopyInitialization=homotopyInitialization,
    each final V=(perPar.V*nPanels_internal)/nSeg) 
    "Volume of fluid in one segment of the solar collector";

  Modelica.Thermal.HeatTransfer.Sensors.TemperatureSensor temSen[nSeg] 
    "Temperature sensor";

  Buildings.HeatTransfer.Sources.PrescribedHeatFlow heaGai[nSeg] 
    "Rate of solar heat gain";
  Buildings.HeatTransfer.Sources.PrescribedHeatFlow QLos[nSeg] 
    "Rate of solar heat gain";

protected 
  parameter Buildings.Fluid.SolarCollectors.Data.GenericSolarCollector perPar 
    "Partial performance data";

    Modelica.Blocks.Interfaces.RealInput shaCoe_internal 
    "Internally used shading coefficient";

    final parameter Modelica.SIunits.Pressure dp_nominal_final=
    if sysConfig == Buildings.Fluid.SolarCollectors.Types.SystemConfiguration.Series then 
       nPanels_internal*perPar.dp_nominal
    else 
      perPar.dp_nominal "Nominal pressure loss across the system of collectors";

  parameter Modelica.SIunits.Area TotalArea_internal=
      nPanels_internal * perPar.A "Area used in the simulation";

  parameter Real nPanels_internal=
    if nColType == Buildings.Fluid.SolarCollectors.Types.NumberSelection.Number then 
      nPanels
    else 
      totalArea/perPar.A "Number of panels used in the simulation";

equation 
  connect(shaCoe_internal,shaCoe_in);

  if not use_shaCoe_in then
    shaCoe_internal=shaCoe;
  end if;

  connect(weaBus, HDifTilIso.weaBus);
  connect(weaBus, HDirTil.weaBus);
  connect(port_a, senMasFlo.port_a);
  connect(senMasFlo.port_b, res.port_a);
  connect(heaCap.port, vol.heatPort);
      connect(vol[nSeg].ports[2], port_b);
  connect(vol[1].ports[1], res.port_b);
      for i in 1:(nSeg - 1) loop
    connect(vol[i].ports[2], vol[i + 1].ports[1]);
  end for;
  connect(vol.heatPort, temSen.port);
  connect(heaGai.port, vol.heatPort);
  connect(QLos.port, vol.heatPort);
end PartialSolarCollector;

Buildings.Fluid.SolarCollectors.BaseClasses.IAM

Information

Overview

This function computes the incidence angle modifier for solar insolation striking the surface of the solar thermal collector. It is calculated using Eq 555 in the EnergyPlus 7.0.0 Engineering Reference.

Notice

As stated in EnergyPlus7.0.0 the incidence angle equation performs poorly at angles greater than 60 degrees. This model outputs 0 whenever the incidence angle is greater than 60 degrees.

References

EnergyPlus 7.0.0 Engineering Reference, October 13, 2011.

Inputs

Type	Name	Default	Description
Angle	incAng		Incident angle [rad]
Real	B0		1st incident angle modifer coefficient
Real	B1		2nd incident angle modifer coefficient

Outputs

Type	Name	Description
Real	incAngMod	Incident angle modifier coefficient

Modelica definition

function IAM "Function for incident angle modifer"

  input Modelica.SIunits.Angle incAng "Incident angle";
  input Real B0 "1st incident angle modifer coefficient";
  input Real B1 "2nd incident angle modifer coefficient";
  output Real incAngMod "Incident angle modifier coefficient";
  parameter Modelica.SIunits.Angle incAngMin = Modelica.Constants.pi / 2 -0.1 
    "Minimum incidence angle to avoid divison by zero";
  parameter Real cosIncAngMin(min=Modelica.Constants.eps)=
  Modelica.Math.cos(incAngMin) "Cosine of minimum incidence angle";
  parameter Real delta = 0.0001 "Width of the smoothing function";

algorithm 
  // E+ Equ (555)

  incAngMod :=
  Buildings.Utilities.Math.Functions.smoothHeaviside(
  Modelica.Constants.pi/3-incAng, delta)*
  (1 + B0*(1/Buildings.Utilities.Math.Functions.smoothMax(
  Modelica.Math.cos(incAng), Modelica.Math.cos(incAngMin), delta) - 1) +
  B1*(1/Buildings.Utilities.Math.Functions.smoothMax(Modelica.Math.cos(incAng),
  cosIncAngMin, delta) - 1)^2);

end IAM;