Buildings.Utilities.Psychrometrics.BaseClasses

Package Content

Name	Description
der_dewPointTemperature	Derivative of dewPointTemperature function
dewPointTemperature	Function to compute the dew point temperature of moist air
Examples	Collection of models that illustrate model use and test models
HumidityRatioVaporPressure	Humidity ratio for given water vapor pressure

Buildings.Utilities.Psychrometrics.BaseClasses.der_dewPointTemperature

Information

Derivative of dew point temperature calculation for moist air above freezing temperature.

Inputs

Type	Name	Default	Description
Temperature	T		Dew point temperature [K]
Temperature	dT		[K]

Outputs

Type	Name	Description
Real	dp_w	Differential of water vapor partial pressure (dp_w/dT) [Pa/K]

Modelica definition

function der_dewPointTemperature 
  "Derivative of dewPointTemperature function"


  input Modelica.SIunits.Temperature T "Dew point temperature";
  input Modelica.SIunits.Temperature dT;
  output Real dp_w(unit="Pa/K") 
    "Differential of water vapor partial pressure (dp_w/dT)";
protected 
  constant Real C8 = -5.800226E3;
  constant Real C9 =  1.3914993E0;
  constant Real C10= -4.8640239E-2;
  constant Real C11 = 4.1764768E-5;
  constant Real C12= -1.4452093E-8;
  constant Real C13 = 6.5459673E0;
algorithm 
 dp_w := Modelica.Math.exp(C8/T + C9 + T * ( C10
           + T * ( C11 + T * C12))  + C13 * Modelica.Math.log(T))
           * (-C8/T/T+C10+2*C11*T+3*C12*T*T+C13/T);
end der_dewPointTemperature;

Buildings.Utilities.Psychrometrics.BaseClasses.dewPointTemperature

Information

Dew point temperature calculation for moist air above freezing temperature.

The correlation used in this model is valid for dew point temperatures between 0 degC and 200 degC. It is the correlation from 2005 ASHRAE Handbook, p. 6.2. In an earlier version of this model, the equation from Peppers has been used, but this equation yielded about 15 Kelvin lower dew point temperatures.

Inputs

Type	Name	Default	Description
Temperature	T		Dew point temperature [K]

Outputs

Type	Name	Description
Pressure	p_w	Water vapor partial pressure [Pa]

Modelica definition

function dewPointTemperature 
  "Function to compute the dew point temperature of moist air"
  annotation(derivative=der_dewPointTemperature);


  input Modelica.SIunits.Temperature T "Dew point temperature";
  output Modelica.SIunits.Pressure p_w "Water vapor partial pressure";
protected 
  constant Real C8 = -5.800226E3;
  constant Real C9 =  1.3914993E0;
  constant Real C10= -4.8640239E-2;
  constant Real C11 = 4.1764768E-5;
  constant Real C12= -1.4452093E-8;
  constant Real C13 = 6.5459673E0;
algorithm 
 p_w := Modelica.Math.exp(C8/T + C9 + T * ( C10
           + T * ( C11 + T * C12))  + C13 * Modelica.Math.log(T));
end dewPointTemperature;

Buildings.Utilities.Psychrometrics.BaseClasses.HumidityRatioVaporPressure

Information

Partial Block to compute the relation between humidity ratio and water vapor partial pressure.

If use_p_in is false (default option), the p parameter is used as atmospheric pressure, and the p_in input connector is disabled; if use_p_in is true, then the p parameter is ignored, and the value provided by the input connector is used instead.

Parameters

Type	Name	Default	Description
Boolean	use_p_in	true	Get the pressure from the input connector
Pressure	p	101325	Fixed value of pressure [Pa]

Connectors

Type	Name	Description
input RealInput	p_in	Atmospheric Pressure [Pa]

Modelica definition

partial block HumidityRatioVaporPressure 
  "Humidity ratio for given water vapor pressure"
  extends Modelica.Blocks.Interfaces.BlockIcon;
  parameter Boolean use_p_in = true "Get the pressure from the input connector";

  parameter Modelica.SIunits.Pressure p = 101325 "Fixed value of pressure";
  Modelica.Blocks.Interfaces.RealInput p_in(final quantity="Pressure",
                                         final unit="Pa",
                                         min = 0) if  use_p_in 
    "Atmospheric Pressure";
  output Modelica.SIunits.MassFraction X_dryAir(min=0, max=1, nominal=0.01, start=0.001) 
    "Water mass fraction per mass of dry air";
protected 
  Modelica.Blocks.Interfaces.RealInput p_in_internal 
    "Needed to connect to conditional connector";
equation 
  connect(p_in, p_in_internal);
  if not use_p_in then
    p_in_internal = p;
  end if;
end HumidityRatioVaporPressure;