Buildings.Templates.AirHandlersFans.Validation
Package with validation models
Information
This package contains models validating the templates within Buildings.Templates.AirHandlersFans.
The models also illustrate parameter propagation from a top-level HVAC system record.
Extends from Modelica.Icons.ExamplesPackage (Icon for packages containing runnable examples).
Package Content
| Name | Description |
|---|---|
 VAVMultiZone
|
Validation model for multiple-zone VAV |
 UserProject
|
Package with configured models |
Buildings.Templates.AirHandlersFans.Validation.VAVMultiZone
Validation model for multiple-zone VAV
Information
This is a validation model for the template Buildings.Templates.AirHandlersFans.VAVMultiZone.
All supported system configurations can be generated by the Python script
Buildings/Resources/Scripts/travis/templates/VAVMultiZone.py.
Extends from Modelica.Icons.Example (Icon for runnable examples).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| replaceable package MediumAir | Buildings.Media.Air | Air medium | |
| replaceable package MediumChiWat | Buildings.Media.Water | Cooling medium (such as CHW) | |
| replaceable package MediumHeaWat | Buildings.Media.Water | Heating medium (such as HHW) | |
| AllSystems | datAll | datAll(final VAV_1(cfg=VAV_1... | Design and operating parameters |
| Dynamics | |||
| Conservation equations | |||
| Dynamics | energyDynamics | Modelica.Fluid.Types.Dynamic... | Type of energy balance: dynamic (3 initialization options) or steady state |
Connectors
| Type | Name | Description |
|---|---|---|
| replaceable package MediumAir | Air medium | |
| replaceable package MediumChiWat | Cooling medium (such as CHW) | |
| replaceable package MediumHeaWat | Heating medium (such as HHW) | |
Modelica definition
model VAVMultiZone "Validation model for multiple-zone VAV"
extends Modelica.Icons.Example;
replaceable package MediumAir=Buildings.Media.Air
constrainedby Modelica.Media.Interfaces.PartialMedium
"Air medium";
replaceable package MediumChiWat=Buildings.Media.Water
constrainedby Modelica.Media.Interfaces.PartialMedium
"Cooling medium (such as CHW)";
replaceable package MediumHeaWat=Buildings.Media.Water
constrainedby Modelica.Media.Interfaces.PartialMedium
"Heating medium (such as HHW)";
inner parameter UserProject.Data.AllSystems datAll(
final VAV_1(cfg=VAV_1.cfg))
"Design and operating parameters";
parameter Modelica.Fluid.Types.Dynamics energyDynamics=
Modelica.Fluid.Types.Dynamics.FixedInitial
"Type of energy balance: dynamic (3 initialization options) or steady state";
Buildings.Templates.AirHandlersFans.VAVMultiZone VAV_1(
nZon=2,
ctl(
idZon={"Box_1","Box_1"},
namGro={"Floor_1"},
namGroZon={"Floor_1","Floor_1"}),
final dat=datAll.VAV_1,
redeclare final package MediumAir = MediumAir,
redeclare final package MediumChiWat = MediumChiWat,
final energyDynamics=energyDynamics)
"Air handling unit";
Buildings.Fluid.Sources.Boundary_pT bouOut(
redeclare final package Medium =MediumAir,
nPorts=2)
"Boundary conditions for outdoor environment";
Buildings.Fluid.Sources.Boundary_pT bouBui(
redeclare final package Medium =MediumAir,
nPorts=3)
"Boundary conditions for indoor environment";
Fluid.FixedResistances.PressureDrop res(
redeclare final package Medium=MediumAir,
m_flow_nominal=1, dp_nominal=100);
Fluid.FixedResistances.PressureDrop res1(
redeclare final package Medium = MediumAir,
m_flow_nominal=1,
dp_nominal=100);
Fluid.Sensors.Pressure pBui(redeclare final package Medium = MediumAir)
"Building absolute pressure in representative space";
BoundaryConditions.WeatherData.ReaderTMY3 weaDat(filNam=
Modelica.Utilities.Files.loadResource(
"modelica://Buildings/Resources/weatherdata/USA_IL_Chicago-OHare.Intl.AP.725300_TMY3.mos"));
Fluid.FixedResistances.PressureDrop res2(
redeclare final package Medium = MediumAir,
m_flow_nominal=1,
dp_nominal=100);
Fluid.FixedResistances.PressureDrop res3(
redeclare final package Medium = MediumAir,
m_flow_nominal=1,
dp_nominal=100);
Fluid.Sources.Boundary_pT bouHeaWat(
redeclare final package Medium = MediumHeaWat,
nPorts=2) if VAV_1.have_souHeaWat
"Boundary conditions for HHW distribution system";
Fluid.Sources.Boundary_pT bouChiWat(
redeclare final package Medium = MediumChiWat,
nPorts=2) if VAV_1.have_souChiWat
"Boundary conditions for CHW distribution system";
UserProject.VAVBoxControlPoints sigVAVBox[VAV_1.nZon](each final stdVen=
datAll.stdVen) if VAV_1.ctl.typ == Buildings.Templates.AirHandlersFans.Types.Controller.G36VAVMultiZone
"Control signals from VAV box";
ZoneEquipment.Validation.UserProject.BASControlPoints sigBAS(
final nZon=VAV_1.nZon)
"BAS control points";
ZoneEquipment.Validation.UserProject.ZoneControlPoints sigZon[VAV_1.nZon]
"Zone control points";
protected
Interfaces.Bus busAHU
"Gateway bus";
equation
connect(bouHeaWat.ports[1], VAV_1.port_aHeaWat);
connect(bouChiWat.ports[2], VAV_1.port_bChiWat);
connect(VAV_1.port_bHeaWat, bouHeaWat.ports[2]);
connect(VAV_1.port_aChiWat, bouChiWat.ports[1]);
connect(bouOut.ports[1], res.port_a);
connect(res.port_b, VAV_1.port_Out);
connect(VAV_1.port_Sup, res1.port_a);
connect(res1.port_b, bouBui.ports[1]);
connect(bouBui.ports[2], pBui.port);
connect(weaDat.weaBus, VAV_1.busWea);
connect(busAHU, VAV_1.bus);
connect(VAV_1.port_Rel, res2.port_a);
connect(res2.port_b, bouOut.ports[2]);
connect(VAV_1.port_Ret, res3.port_b);
connect(res3.port_a, bouBui.ports[3]);
connect(pBui.p, busAHU.pBui);
connect(sigVAVBox.bus, VAV_1.busTer);
connect(sigBAS.busTer, VAV_1.busTer);
connect(sigZon.bus, VAV_1.busTer);
end VAVMultiZone;