Buildings.Examples.ScalableBenchmarks.BuildingVAV.BaseClasses
Base classes
Information
Package with base classes for scalable building models implementation.
Extends from Modelica.Icons.BasesPackage (Icon for packages containing base classes).
Package Content
| Name | Description |
|---|---|
 ControlBus
|
Control bus that is adapted to the signals connected to it |
 CoolSetpoint
|
Schedule for cooling setpoint |
 FanOnOffWithDP
|
Controller for fan on/off and to provide prescribed dP |
 HeatSetpoint
|
Schedule for heating setpoint |
| IntLoad
|
Schedule for time varying internal loads |
 VAVBranch
|
Supply branch of a VAV system |
Buildings.Examples.ScalableBenchmarks.BuildingVAV.BaseClasses.ControlBus
Control bus that is adapted to the signals connected to it
Information
This connector defines the expandable connector ControlBus that
is used to connect control signals.
Note, this connector is empty. When using it, the actual content is
constructed by the signals connected to this bus.
Extends from Modelica.Icons.SignalBus (Icon for signal bus).
Contents
| Type | Name | Description |
|---|---|---|
| Temperature | TRooMin | Minimum temperature of multiple zones [K] |
| Temperature | TRooAve | Average temperature of multiple zones [K] |
| Temperature | TRooSetHea | Room heating setpoint temperature [K] |
| Temperature | TRooSetCoo | Room cooling setpoint temperature [K] |
| Temperature | TOut | Outdoor air temperature [K] |
| Time | dTNexOcc | Time to next occupancy period [s] |
| Boolean | occupied | Occupancy status |
| Integer | controlMode | System operation modes |
Modelica definition
expandable connector ControlBus
"Control bus that is adapted to the signals connected to it"
extends Modelica.Icons.SignalBus;
Modelica.SIunits.Temperature TRooMin "Minimum temperature of multiple zones";
Modelica.SIunits.Temperature TRooAve "Average temperature of multiple zones";
Modelica.SIunits.Temperature TRooSetHea "Room heating setpoint temperature";
Modelica.SIunits.Temperature TRooSetCoo "Room cooling setpoint temperature";
Modelica.SIunits.Temperature TOut "Outdoor air temperature";
Modelica.SIunits.Time dTNexOcc "Time to next occupancy period";
Boolean occupied "Occupancy status";
Integer controlMode "System operation modes";
end ControlBus;
Buildings.Examples.ScalableBenchmarks.BuildingVAV.BaseClasses.CoolSetpoint
Schedule for cooling setpoint
Information
This block defines room air cooling setpoints.
Extends from Modelica.Blocks.Sources.CombiTimeTable (Table look-up with respect to time and linear/periodic extrapolation methods (data from matrix/file)).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Table data definition | |||
| Boolean | tableOnFile | false | = true, if table is defined on file or in function usertab |
| Real | table[:, :] | [0, 273.15 + 32.0; 8*3600, 2... | Table matrix (time = first column; e.g., table=[0,2]) |
| String | tableName | "NoName" | Table name on file or in function usertab (see docu) |
| String | fileName | "NoName" | File where matrix is stored |
| Boolean | verboseRead | true | = true, if info message that file is loading is to be printed |
| Table data interpretation | |||
| Integer | columns[:] | {2} | Columns of table to be interpolated |
| Smoothness | smoothness | Modelica.Blocks.Types.Smooth... | Smoothness of table interpolation |
| Extrapolation | extrapolation | Modelica.Blocks.Types.Extrap... | Extrapolation of data outside the definition range |
| Real | offset[:] | {0} | Offsets of output signals |
| Time | startTime | 0 | Output = offset for time < startTime [s] |
| Time | timeScale | 1 | Time scale of first table column [s] |
Connectors
| Type | Name | Description |
|---|---|---|
| output RealOutput | y[nout] | Connector of Real output signals |
Modelica definition
model CoolSetpoint "Schedule for cooling setpoint"
extends Modelica.Blocks.Sources.CombiTimeTable(
smoothness=Modelica.Blocks.Types.Smoothness.ConstantSegments,
extrapolation=Modelica.Blocks.Types.Extrapolation.Periodic,
table=[
0, 273.15+32.0;
8*3600, 273.15+27.0;
18*3600, 273.15+32.0;
24*3600, 273.15+32.0],
columns={2});
end CoolSetpoint;
Buildings.Examples.ScalableBenchmarks.BuildingVAV.BaseClasses.FanOnOffWithDP
Controller for fan on/off and to provide prescribed dP
Information
This model outputs ON/OFF signal to control fan operation.
When the system is in mode like unoccupiedOff, safety, it outputs
false so that fan should be OFF and provide 0 pressure rise;
When the system is in mode like unoccupiedNightSetBack,occupied,unoccupiedWarmUp,
unoccupiedPreCool, it outputs true so that fan should be
ON and provide preRis pressure rise.
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| PressureDifference | preRis | 850 | Prescribed pressure difference [Pa] |
Connectors
| Type | Name | Description |
|---|---|---|
| output RealOutput | y | Supply fan requested pressure rise, or zero if fan should be off [Pa] |
| ControlBus | controlBus |
Modelica definition
block FanOnOffWithDP
"Controller for fan on/off and to provide prescribed dP"
import Buildings.Examples.VAVReheat.Controls.OperationModes;
parameter Modelica.SIunits.PressureDifference preRis=850
"Prescribed pressure difference";
Modelica.Blocks.Interfaces.RealOutput y(unit="Pa")
"Supply fan requested pressure rise, or zero if fan should be off";
Buildings.Examples.VAVReheat.Controls.ControlBus controlBus;
Modelica.Blocks.Routing.Extractor extractor(
nin=6,
index(start=1, fixed=true)) "Extractor for control signal";
Modelica.Blocks.Sources.Constant off(k=0) "Off signal";
Modelica.Blocks.Sources.Constant on(k=preRis) "On signal";
equation
connect(off.y, extractor.u[Integer(OperationModes.unoccupiedOff)]);
connect(off.y, extractor.u[Integer(OperationModes.safety)]);
connect(on.y, extractor.u[Integer(OperationModes.unoccupiedNightSetBack)]);
connect(on.y, extractor.u[Integer(OperationModes.occupied)]);
connect(on.y, extractor.u[Integer(OperationModes.unoccupiedWarmUp)]);
connect(on.y, extractor.u[Integer(OperationModes.unoccupiedPreCool)]);
connect(controlBus.controlMode, extractor.index);
connect(extractor.y, y);
end FanOnOffWithDP;
Buildings.Examples.ScalableBenchmarks.BuildingVAV.BaseClasses.HeatSetpoint
Schedule for heating setpoint
Information
This block defines room air heating setpoints.
Extends from Modelica.Blocks.Sources.CombiTimeTable (Table look-up with respect to time and linear/periodic extrapolation methods (data from matrix/file)).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Table data definition | |||
| Boolean | tableOnFile | false | = true, if table is defined on file or in function usertab |
| Real | table[:, :] | [0, 273.15 + 13.0; 8*3600, 2... | Table matrix (time = first column; e.g., table=[0,2]) |
| String | tableName | "NoName" | Table name on file or in function usertab (see docu) |
| String | fileName | "NoName" | File where matrix is stored |
| Boolean | verboseRead | true | = true, if info message that file is loading is to be printed |
| Table data interpretation | |||
| Integer | columns[:] | {2} | Columns of table to be interpolated |
| Smoothness | smoothness | Modelica.Blocks.Types.Smooth... | Smoothness of table interpolation |
| Extrapolation | extrapolation | Modelica.Blocks.Types.Extrap... | Extrapolation of data outside the definition range |
| Real | offset[:] | {0} | Offsets of output signals |
| Time | startTime | 0 | Output = offset for time < startTime [s] |
| Time | timeScale | 1 | Time scale of first table column [s] |
Connectors
| Type | Name | Description |
|---|---|---|
| output RealOutput | y[nout] | Connector of Real output signals |
Modelica definition
model HeatSetpoint "Schedule for heating setpoint"
extends Modelica.Blocks.Sources.CombiTimeTable(
smoothness=Modelica.Blocks.Types.Smoothness.ConstantSegments,
extrapolation=Modelica.Blocks.Types.Extrapolation.Periodic,
table=[
0, 273.15+13.0;
8*3600, 273.15+20.0;
18*3600, 273.15+13.0;
24*3600, 273.15+13.0],
columns={2});
end HeatSetpoint;
Buildings.Examples.ScalableBenchmarks.BuildingVAV.BaseClasses.IntLoad
Schedule for time varying internal loads
Information
This block defines schedule of internal load.
Extends from Modelica.Blocks.Sources.CombiTimeTable (Table look-up with respect to time and linear/periodic extrapolation methods (data from matrix/file)).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Table data definition | |||
| Boolean | tableOnFile | false | = true, if table is defined on file or in function usertab |
| Real | table[:, :] | [0, 0.1; 8*3600, 1.0; 18*360... | Table matrix (time = first column; e.g., table=[0,2]) |
| String | tableName | "NoName" | Table name on file or in function usertab (see docu) |
| String | fileName | "NoName" | File where matrix is stored |
| Boolean | verboseRead | true | = true, if info message that file is loading is to be printed |
| Table data interpretation | |||
| Integer | columns[:] | {2} | Columns of table to be interpolated |
| Smoothness | smoothness | Modelica.Blocks.Types.Smooth... | Smoothness of table interpolation |
| Extrapolation | extrapolation | Modelica.Blocks.Types.Extrap... | Extrapolation of data outside the definition range |
| Real | offset[:] | {0} | Offsets of output signals |
| Time | startTime | 0 | Output = offset for time < startTime [s] |
| Time | timeScale | 1 | Time scale of first table column [s] |
Connectors
| Type | Name | Description |
|---|---|---|
| output RealOutput | y[nout] | Connector of Real output signals |
Modelica definition
model IntLoad "Schedule for time varying internal loads"
extends Modelica.Blocks.Sources.CombiTimeTable(
smoothness=Modelica.Blocks.Types.Smoothness.ConstantSegments,
extrapolation=Modelica.Blocks.Types.Extrapolation.Periodic,
table=[
0, 0.1;
8*3600, 1.0;
18*3600, 0.1;
24*3600, 0.1],
columns={2});
end IntLoad;
Buildings.Examples.ScalableBenchmarks.BuildingVAV.BaseClasses.VAVBranch
Supply branch of a VAV system
Information
Model for a VAV branch.
The model has been developed based on Buildings.Examples.VAVReheat.ThermalZones.VAVBranch, but using different VAV box model Buildings.Fluid.Actuators.Dampers.PressureIndependent.
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| replaceable package MediumA | Modelica.Media.Interfaces.Pa... | Medium model for air | |
| replaceable package MediumW | Modelica.Media.Interfaces.Pa... | Medium model for water | |
| PressureDifference | dpFixed_nominal | 0 | Pressure drop of duct and other resistances that are in series [Pa] |
| MassFlowRate | m_flow_nominal | Mass flow rate of this thermal zone [kg/s] | |
| Volume | VRoo | Room volume [m3] | |
Connectors
| Type | Name | Description |
|---|---|---|
| replaceable package MediumA | Medium model for air | |
| replaceable package MediumW | Medium model for water | |
| input RealInput | TRooHeaSet | Setpoint temperature for room for heating [K] |
| input RealInput | TRooCooSet | Setpoint temperature for room for cooling [K] |
| input RealInput | TRoo | Measured room temperature [K] |
| FluidPort_a | port_a | Fluid connector a1 (positive design flow direction is from port_a1 to port_b1) |
| FluidPort_a | port_b | Fluid connector b (positive design flow direction is from port_a1 to port_b1) |
| output RealOutput | yDam | Signal for VAV damper |
Modelica definition
model VAVBranch "Supply branch of a VAV system"
replaceable package MediumA = Modelica.Media.Interfaces.PartialMedium
"Medium model for air";
replaceable package MediumW = Modelica.Media.Interfaces.PartialMedium
"Medium model for water";
parameter Modelica.SIunits.PressureDifference dpFixed_nominal(displayUnit="Pa")=0
"Pressure drop of duct and other resistances that are in series";
parameter Modelica.SIunits.MassFlowRate m_flow_nominal
"Mass flow rate of this thermal zone";
parameter Modelica.SIunits.Volume VRoo "Room volume";
Buildings.Controls.OBC.CDL.Interfaces.RealInput TRooHeaSet(
final quantity="ThermodynamicTemperature",
final unit = "K",
displayUnit = "degC",
min=0)
"Setpoint temperature for room for heating";
Buildings.Controls.OBC.CDL.Interfaces.RealInput TRooCooSet(
final quantity="ThermodynamicTemperature",
final unit = "K",
displayUnit = "degC",
min=0)
"Setpoint temperature for room for cooling";
Modelica.Blocks.Interfaces.RealInput TRoo(
final quantity="ThermodynamicTemperature",
final unit = "K",
displayUnit = "degC",
min=0)
"Measured room temperature";
Modelica.Fluid.Interfaces.FluidPort_a port_a(
redeclare package Medium = MediumA)
"Fluid connector a1 (positive design flow direction is from port_a1 to port_b1)";
Modelica.Fluid.Interfaces.FluidPort_a port_b(
redeclare package Medium = MediumA)
"Fluid connector b (positive design flow direction is from port_a1 to port_b1)";
Modelica.Blocks.Interfaces.RealOutput yDam "Signal for VAV damper";
Fluid.Actuators.Dampers.PressureIndependent vav(
redeclare package Medium = MediumA,
m_flow_nominal=m_flow_nominal,
dpFixed_nominal=dpFixed_nominal,
dp_nominal(displayUnit="Pa") = 20) "VAV box for room";
Buildings.Fluid.HeatExchangers.DryCoilEffectivenessNTU terHea(
redeclare package Medium1 = MediumA,
redeclare package Medium2 = MediumW,
m1_flow_nominal=m_flow_nominal,
m2_flow_nominal=m_flow_nominal*1000*(50 - 17)/4200/10,
Q_flow_nominal=m_flow_nominal*1006*(50 - 16.7),
configuration=Buildings.Fluid.Types.HeatExchangerConfiguration.CounterFlow,
dp1_nominal=0,
from_dp2=true,
dp2_nominal=0,
T_a1_nominal=289.85,
T_a2_nominal=355.35) "Heat exchanger of terminal box";
Buildings.Fluid.Sources.Boundary_pT sinTer(
redeclare package Medium = MediumW,
p(displayUnit="Pa") = 3E5,
nPorts=1) "Sink for terminal box ";
Buildings.Examples.VAVReheat.Controls.RoomVAV con "Room temperature controller";
Buildings.Fluid.Sensors.MassFlowRate senMasFlo(
redeclare package Medium = MediumA) "Sensor for mass flow rate";
Modelica.Blocks.Math.Gain fraMasFlo(
k=1/m_flow_nominal)
"Fraction of mass flow rate, relative to nominal flow";
Buildings.Fluid.Sensors.TemperatureTwoPort TSup(
redeclare package Medium = MediumA,
m_flow_nominal=m_flow_nominal,
initType=Modelica.Blocks.Types.Init.InitialState) "Supply air temperature";
Modelica.Blocks.Math.Gain ACH(k=1/VRoo/1.2*3600) "Air change per hour";
Buildings.Fluid.Actuators.Valves.TwoWayLinear valHea(
redeclare package Medium = MediumW,
m_flow_nominal=m_flow_nominal*1000*15/4200/10,
CvData=Buildings.Fluid.Types.CvTypes.OpPoint,
from_dp=true,
dpFixed_nominal=6000,
dpValve_nominal=6000) "Valve at reaheat coil";
Buildings.Fluid.Sources.Boundary_pT souTer(
redeclare package Medium = MediumW,
p(displayUnit="Pa") = 3E5 + 12000,
nPorts=1,
T=323.15) "Source for terminal box ";
equation
connect(fraMasFlo.u, senMasFlo.m_flow);
connect(TSup.T,con.TDis);
connect(con.yDam, vav.y);
connect(terHea.port_b1, TSup.port_a);
connect(TSup.port_b, vav.port_a);
connect(vav.port_b, senMasFlo.port_a);
connect(con.yDam, yDam);
connect(ACH.u, senMasFlo.m_flow);
connect(con.yVal, valHea.y);
connect(souTer.ports[1], terHea.port_a2);
connect(terHea.port_b2, valHea.port_a);
connect(valHea.port_b, sinTer.ports[1]);
connect(port_a, terHea.port_a1);
connect(senMasFlo.port_b, port_b);
connect(con.TRoo, TRoo);
connect(con.TRooHeaSet, TRooHeaSet);
connect(TRooCooSet, con.TRooCooSet);
end VAVBranch;