Buildings.Air.Systems.SingleZone.VAV.Examples
Collection of models that illustrate model use and test models
Information
This package contains examples for the use of models that can be found in Buildings.Air.Systems.SingleZone.VAV.
Extends from Modelica.Icons.ExamplesPackage (Icon for packages containing runnable examples).
Package Content
| Name | Description |
|---|---|
 ChillerDXHeatingEconomizer
|
Example for SingleZoneVAV with a dry cooling coil, air-cooled chiller, electric heating coil, variable speed fan, and mixing box with economizer. |
 BaseClasses
|
Package with base classes for Buildings.Air.Systems.SingleZone.VAV.Examples |
Buildings.Air.Systems.SingleZone.VAV.Examples.ChillerDXHeatingEconomizer
Example for SingleZoneVAV with a dry cooling coil, air-cooled chiller, electric heating coil, variable speed fan, and mixing box with economizer.
Information
The thermal zone is based on the BESTEST Case 600 envelope, while the HVAC system is based on a conventional VAV system with air cooled chiller and economizer. See documentation for the specific models for more information.
Extends from Modelica.Icons.Example (Icon for runnable examples).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Temperature | TSupChi_nominal | 279.15 | Design value for chiller leaving water temperature [K] |
Connectors
| Type | Name | Description |
|---|---|---|
| Bus | weaBus | Weather data bus |
Modelica definition
model ChillerDXHeatingEconomizer
"Example for SingleZoneVAV with a dry cooling coil, air-cooled chiller, electric heating coil, variable speed fan, and mixing box with economizer."
extends Modelica.Icons.Example;
package MediumA = Buildings.Media.Air "Buildings library air media package";
package MediumW = Buildings.Media.Water "Buildings library air media package";
parameter Modelica.SIunits.Temperature TSupChi_nominal=279.15
"Design value for chiller leaving water temperature";
ChillerDXHeatingEconomizerController con(
minOAFra=0.2,
kFan=4,
kEco=4,
kHea=4,
TSupChi_nominal=TSupChi_nominal,
TSetSupAir=286.15)
"Controller";
Buildings.Air.Systems.SingleZone.VAV.ChillerDXHeatingEconomizer hvac(
redeclare package MediumA = MediumA,
redeclare package MediumW = MediumW,
mAir_flow_nominal=0.75,
etaHea_nominal=0.99,
QHea_flow_nominal=7000,
QCoo_flow_nominal=-7000,
TSupChi_nominal=TSupChi_nominal) "Single zone VAV system";
Buildings.Air.Systems.SingleZone.VAV.Examples.BaseClasses.Room zon(
mAir_flow_nominal=0.75,
lat=weaDat.lat) "Thermal envelope of single zone";
Buildings.BoundaryConditions.WeatherData.ReaderTMY3 weaDat(
computeWetBulbTemperature=false,
filNam=Modelica.Utilities.Files.loadResource("modelica://Buildings/Resources/weatherdata/DRYCOLD.mos"));
Modelica.Blocks.Continuous.Integrator EFan "Total fan energy";
Modelica.Blocks.Continuous.Integrator EHea "Total heating energy";
Modelica.Blocks.Continuous.Integrator ECoo "Total cooling energy";
Modelica.Blocks.Math.MultiSum EHVAC(nu=4) "Total HVAC energy";
Modelica.Blocks.Continuous.Integrator EPum "Total pump energy";
Modelica.Blocks.Sources.CombiTimeTable TSetRooHea(
table=[
0, 15 + 273.15;
8*3600, 20 + 273.15;
18*3600, 15 + 273.15;
24*3600, 15 + 273.15],
smoothness=Modelica.Blocks.Types.Smoothness.ConstantSegments,
extrapolation=Modelica.Blocks.Types.Extrapolation.Periodic)
"Heating setpoint for room temperature";
Modelica.Blocks.Sources.CombiTimeTable TSetRooCoo(
table=[
0, 30 + 273.15;
8*3600, 25 + 273.15;
18*3600, 30 + 273.15;
24*3600, 30 + 273.15],
smoothness=Modelica.Blocks.Types.Smoothness.ConstantSegments,
extrapolation=Modelica.Blocks.Types.Extrapolation.Periodic)
"Cooling setpoint for room temperature";
BoundaryConditions.WeatherData.Bus weaBus "Weather data bus";
equation
connect(weaDat.weaBus, weaBus);
connect(con.yFan, hvac.uFan);
connect(con.yHea, hvac.uHea);
connect(con.yCooCoiVal, hvac.uCooVal);
connect(con.yOutAirFra, hvac.uEco);
connect(hvac.chiOn, con.chiOn);
connect(con.TSetSupChi, hvac.TSetChi);
connect(con.TMix, hvac.TMixAir);
connect(hvac.supplyAir, zon.supplyAir);
connect(hvac.returnAir, zon.returnAir);
connect(con.TOut, weaBus.TDryBul);
connect(hvac.weaBus, weaBus);
connect(zon.weaBus, weaBus);
connect(con.TSup, hvac.TSup);
connect(con.TRoo, zon.TRooAir);
connect(TSetRooHea.y[1], con.TSetRooHea);
connect(TSetRooCoo.y[1], con.TSetRooCoo);
connect(hvac.PFan, EFan.u);
connect(hvac.QHea_flow, EHea.u);
connect(hvac.PCoo, ECoo.u);
connect(hvac.PPum, EPum.u);
connect(EFan.y, EHVAC.u[1]);
connect(EHea.y, EHVAC.u[2]);
connect(ECoo.y, EHVAC.u[3]);
connect(EPum.y, EHVAC.u[4]);
end ChillerDXHeatingEconomizer;