Buildings.Fluid.HeatExchangers.ThermalWheels.Latent.BaseClasses.Validation
Collection of models that validate the module in the base classes
Information
This package contains validation models for the classes in Buildings.Fluid.HeatExchangers.ThermalWheels.Latent.BaseClasses.
Extends from Modelica.Icons.ExamplesPackage (Icon for packages containing runnable examples).
Package Content
| Name | Description |
|---|---|
 Effectiveness
|
Test model for calculating the input effectiveness of a sensible and latent heat exchanger |
| HeatExchangerWithInputEffectiveness
|
Test model for the heat exchanger with input effectiveness |
Buildings.Fluid.HeatExchangers.ThermalWheels.Latent.BaseClasses.Validation.Effectiveness
Test model for calculating the input effectiveness of a sensible and latent heat exchanger
Information
Validation test for the block Buildings.Fluid.HeatExchangers.ThermalWheels.Latent.BaseClasses.Effectiveness.
The input signals are configured as follows:
- The supply air flow rate, VSup, and the exhaust air flow rate, VExh, change from 0.6 to 1 and 0.8 to 1 respectively.
The expected outputs are:
-
The sensible effectiveness
epsSenand yhe latent effectivenessepsLatincreases in the whole simulation period.
Extends from Modelica.Icons.Example (Icon for runnable examples).
Modelica definition
model Effectiveness
"Test model for calculating the input effectiveness of a sensible and latent heat exchanger"
extends Modelica.Icons.Example;
Buildings.Fluid.HeatExchangers.ThermalWheels.Latent.BaseClasses.Effectiveness
epsCal(
epsSen_nominal=0.8,
epsSenPL=0.75,
epsLat_nominal=0.6,
epsLatPL=0.5,
mSup_flow_nominal=1)
"Effectiveness calculator";
Modelica.Blocks.Sources.Ramp VSup(
height=0.4,
duration=120,
offset=0.6,
startTime=0)
"Supply air flow rate";
Modelica.Blocks.Sources.Ramp VExh(
height=0.2,
duration=120,
offset=0.8,
startTime=0)
"Exhaust air flow rate";
equation
connect(VSup.y, epsCal.mSup_flow);
connect(VExh.y, epsCal.mExh_flow);
end Effectiveness;
Buildings.Fluid.HeatExchangers.ThermalWheels.Latent.BaseClasses.Validation.HeatExchangerWithInputEffectiveness
Test model for the heat exchanger with input effectiveness
Information
Validation test for the block Buildings.Fluid.HeatExchangers.ThermalWheels.Latent.BaseClasses.HeatExchangerWithInputEffectiveness.
The input signals are configured as follows:
- The supply air temperature TSup changes from 273.15 + 30 K to 273.15 + 40 K during the period from 120 seconds to 180 seconds.
- The sensible heat exchanger effectiveness epsSen changes from 0.7 to 0.8 during the period from 120 seconds to 180 seconds.
- The latent heat exchanger effectiveness epsLat changes from 0.4 to 0.8 during the period from 180 seconds to 240 seconds.
The expected outputs are:
- During the period from 60 seconds to 120 seconds, the difference between the entering exhaust air humidity and the leaving exhaust air humidity increases. This difference then decreases during the period from 180 seconds to 240 seconds.
- During the period from 120 seconds to 180 seconds, the difference between the entering exhaust air temperature and the leaving exhaust air temperature increases.
Extends from Modelica.Icons.Example (Icon for runnable examples).
Modelica definition
model HeatExchangerWithInputEffectiveness
"Test model for the heat exchanger with input effectiveness"
extends Modelica.Icons.Example;
package Medium1 = Buildings.Media.Air
"Supply air";
package Medium2 = Buildings.Media.Air
"Exhaust air";
Buildings.Fluid.Sources.Boundary_pT sin_2(
redeclare package Medium = Medium2,
p(displayUnit="Pa")=101325,
T=273.15+10,
nPorts=1)
"Ambient";
Buildings.Fluid.Sources.Boundary_pT sou_2(
redeclare package Medium = Medium2,
p(displayUnit="Pa")=101325+100,
nPorts=1)
"Exhaust air source";
Modelica.Blocks.Sources.Ramp TSup(
height=10,
duration=60,
offset=273.15+30,
startTime=120)
"Supply air temperature";
Buildings.Fluid.Sources.Boundary_pT sin_1(
redeclare package Medium = Medium1,
T(displayUnit="K")=273.15+30,
X={0.012,1 - 0.012},
p(displayUnit="Pa")=1E5-110,
nPorts=1)
"Supply air sink";
Buildings.Fluid.Sources.Boundary_pT sou_1(
redeclare package Medium = Medium1,
T=273.15 + 50,
X={0.012,1 - 0.012},
use_T_in=true,
p(displayUnit="Pa")=100000,
nPorts=1)
"Supply air source";
Buildings.Fluid.HeatExchangers.ThermalWheels.Latent.BaseClasses.HeatExchangerWithInputEffectiveness
hex(
redeclare package Medium1 = Medium1,
redeclare package Medium2 = Medium2,
m1_flow_nominal=5,
m2_flow_nominal=5,
dp1_nominal=100,
dp2_nominal=100)
"Heat exchanger";
Modelica.Blocks.Sources.Ramp epsSen(
height=0.1,
duration=60,
offset=0.7,
startTime=120)
"Sensible heat exchanger effectiveness";
Modelica.Blocks.Sources.Ramp epsLat(
height=0.4,
duration=60,
offset=0.4,
startTime=180)
"Latent heat exchanger effectiveness";
Buildings.Fluid.Sensors.TemperatureTwoPort senExhTemOut(
redeclare package Medium = Medium2,
m_flow_nominal=5)
"Temperature sensor for exhuast air outlet";
Buildings.Fluid.Sensors.TemperatureTwoPort senExhTemIn(
redeclare package Medium = Medium2,
m_flow_nominal=5)
"Temperature sensor for exhuast air inlet";
Buildings.Fluid.Sensors.RelativeHumidityTwoPort senExhRelHumIn(
redeclare package Medium = Medium2,
m_flow_nominal=5)
"Humidity sensor for exhuast air inlet";
Buildings.Fluid.Sensors.RelativeHumidityTwoPort senExhRelHumOut(
redeclare package Medium = Medium2,
m_flow_nominal=5)
"Humidity sensor for exhuast air outlet";
equation
connect(TSup.y, sou_1.T_in);
connect(sou_1.ports[1], hex.port_a1);
connect(hex.port_b1, sin_1.ports[1]);
connect(epsSen.y, hex.epsSen);
connect(hex.epsLat, epsLat.y);
connect(senExhTemOut.port_b, sin_2.ports[1]);
connect(hex.port_a2, senExhTemIn.port_b);
connect(senExhRelHumIn.port_a, sou_2.ports[1]);
connect(senExhRelHumIn.port_b, senExhTemIn.port_a);
connect(hex.port_b2, senExhRelHumOut.port_a);
connect(senExhTemOut.port_a, senExhRelHumOut.port_b);
end HeatExchangerWithInputEffectiveness;