Buildings.Fluid.CHPs.OrganicRankine.BaseClasses
Package with base classes
Information
Package for base classes.
Extends from Modelica.Icons.BasesPackage (Icon for packages containing base classes).
Package Content
| Name | Description |
|---|---|
 FixedEvaporating
|
Thermodynamic computations of the ORC with fixed evaporating temperature |
 InterpolateStates
|
Interpolate states of a working fluid |
 Validation
|
Package for validation models |
Buildings.Fluid.CHPs.OrganicRankine.BaseClasses.FixedEvaporating
Thermodynamic computations of the ORC with fixed evaporating temperature
Information
This model computes the pinch points and the energy exchange, and interfaces with the input and output variables. The evaporating temperature is fixed as a parameter. See the documentation of Buildings.Fluid.CHPs.OrganicRankine.ConstantEvaporation for more details.
Extends from Buildings.Fluid.CHPs.OrganicRankine.BaseClasses.InterpolateStates (Interpolate states of a working fluid).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| ThermodynamicTemperature | TEva | TWorEva | Evaporating temperature [K] |
| ThermodynamicTemperature | TCon | TWorCon | Condensing temperature [K] |
| Boolean | useLowCondenserPressureWarning | true | If true, issues warning if pCon < 101325 Pa |
| ORC inputs | |||
| Generic | pro | redeclare parameter Building... | Property records of the working fluid |
| Evaporator | |||
| TemperatureDifference | dTPinEva_set | Set evaporator pinch point temperature difference [K] | |
| SpecificHeatCapacity | cpHot | Constant specific heat capacity [J/(kg.K)] | |
| ThermodynamicTemperature | TWorEva | Working fluid evaporator temperature [K] | |
| Condenser | |||
| TemperatureDifference | dTPinCon | Pinch point temperature difference of condenser [K] | |
| SpecificHeatCapacity | cpCol | Constant specific heat capacity [J/(kg.K)] | |
| Cycle | |||
| MassFlowRate | mWor_flow_max | Upper bound of working fluid flow rate [kg/s] | |
| MassFlowRate | mWor_flow_min | Lower bound of working fluid flow rate [kg/s] | |
| MassFlowRate | mWor_flow_hysteresis | Hysteresis for turning off the cycle when flow too low [kg/s] | |
| MassFlowRate | mWor_flow | Mass flow rate of the working fluid [kg/s] | |
| Advanced | |||
| SpecificEnthalpy | h_small | (max(pro.hSatVap) - min(pro.... | A small value for specific enthalpy regularisation [J/kg] |
Connectors
| Type | Name | Description |
|---|---|---|
| input RealInput | THotIn | Incoming temperature of hot fluid in evaporator [K] |
| input RealInput | mHot_flow | Evaporator hot fluid flow rate [kg/s] |
| input RealInput | TColIn | Incoming temperature of cold fluid in condenser [K] |
| input RealInput | mCol_flow | Condenser cold fluid flow rate [kg/s] |
| input BooleanInput | ena | Enable cycle; set false to force working fluid flow to zero |
| output RealOutput | QEva_flow | Evaporator heat flow rate into the cycle [W] |
| output RealOutput | QCon_flow | Condenser heat flow rate out of the cycle [W] |
| output RealOutput | PExp | Expander power generation [W] |
| output RealOutput | PPum | Electrical power consumption of the pump [W] |
| output BooleanOutput | on_actual | Actual on off status of the cycle |
Modelica definition
model FixedEvaporating
"Thermodynamic computations of the ORC with fixed evaporating temperature"
extends Buildings.Fluid.CHPs.OrganicRankine.BaseClasses.InterpolateStates(
TEva=TWorEva,
TCon=TWorCon);
parameter Modelica.Units.SI.TemperatureDifference dTPinEva_set(
final min = 0)
"Set evaporator pinch point temperature difference";
parameter Modelica.Units.SI.SpecificHeatCapacity cpHot
"Constant specific heat capacity";
parameter Modelica.Units.SI.ThermodynamicTemperature TWorEva
"Working fluid evaporator temperature";
parameter Modelica.Units.SI.TemperatureDifference dTPinCon
"Pinch point temperature difference of condenser";
parameter Modelica.Units.SI.SpecificHeatCapacity cpCol
"Constant specific heat capacity";
parameter Boolean useLowCondenserPressureWarning = true
"If true, issues warning if pCon < 101325 Pa";
parameter Modelica.Units.SI.MassFlowRate mWor_flow_max(
final min = 0)
"Upper bound of working fluid flow rate";
parameter Modelica.Units.SI.MassFlowRate mWor_flow_min(
final min = 0)
"Lower bound of working fluid flow rate";
parameter Modelica.Units.SI.MassFlowRate mWor_flow_hysteresis(
final min = 0)
"Hysteresis for turning off the cycle when flow too low";
Modelica.Blocks.Interfaces.RealInput THotIn(
final quantity="ThermodynamicTemperature",
final unit="K",
displayUnit="degC") "Incoming temperature of hot fluid in evaporator";
Modelica.Blocks.Interfaces.RealInput mHot_flow(
final quantity="MassFlowRate",
final unit="kg/s") "Evaporator hot fluid flow rate";
Modelica.Blocks.Interfaces.RealInput TColIn(
final quantity="ThermodynamicTemperature",
final unit="K",
displayUnit="degC") "Incoming temperature of cold fluid in condenser";
Modelica.Blocks.Interfaces.RealInput mCol_flow(
final quantity="MassFlowRate",
final unit="kg/s") "Condenser cold fluid flow rate";
Modelica.Blocks.Interfaces.BooleanInput ena
"Enable cycle; set false to force working fluid flow to zero";
Modelica.Blocks.Interfaces.RealOutput QEva_flow(
final quantity="HeatFlowRate",
final unit="W") "Evaporator heat flow rate into the cycle";
Modelica.Blocks.Interfaces.RealOutput QCon_flow(
final quantity="HeatFlowRate",
final unit="W") "Condenser heat flow rate out of the cycle";
Modelica.Blocks.Interfaces.RealOutput PExp(
final quantity="Power",
final unit="W") "Expander power generation";
Modelica.Blocks.Interfaces.RealOutput PPum(
final quantity="Power",
final unit="W")
"Electrical power consumption of the pump";
Modelica.Blocks.Interfaces.BooleanOutput on_actual = ena and hys.y
"Actual on off status of the cycle";
Modelica.Units.SI.ThermodynamicTemperature THotOut(
start = TWorEva + dTPinEva_set)
"Outgoing temperature of the evaporator hot fluid";
Modelica.Units.SI.ThermodynamicTemperature THotPin(
start = TWorEva + dTPinEva_set)
"Hot fluid temperature at pinch point";
Modelica.Units.SI.TemperatureDifference dTPinEva(start = dTPinEva_set)
"Pinch point temperature difference of evaporator";
Modelica.Units.SI.ThermodynamicTemperature TWorCon
"Working fluid condensing temperature";
Modelica.Units.SI.ThermodynamicTemperature TColOut
"Fluid temperature out of the condenser";
Modelica.Units.SI.ThermodynamicTemperature TColPin(
start = 300)
"Cold fluid temperature at pinch point";
Modelica.Units.SI.MassFlowRate mWor_flow
"Mass flow rate of the working fluid";
Modelica.Blocks.Logical.Hysteresis hys(
uLow = mWor_flow_min,
uHigh = mWor_flow_min + mWor_flow_hysteresis,
u = mWor_flow_internal,
y(start = false))
"Hysteresis for turning off cycle when working fluid flow too low";
protected
Modelica.Units.SI.MassFlowRate mWor_flow_internal(
start = (mWor_flow_max + mWor_flow_min) / 2)
"Working fluid flow rate, intermediate variable";
Modelica.Units.SI.ThermodynamicTemperature THotPin_internal
"Hot fluid temperature at pinch point, intermedaite variable";
Modelica.Units.SI.ThermodynamicTemperature THotOut_internal
"Hot fluid outgoing temperature, intermediate variable";
Modelica.Units.SI.HeatFlowRate QEva_flow_internal
"Evaporator heat flow rate, intermediate variable";
equation
assert(not (TWorCon > TWorEva - 1 and ena),
"*** In " + getInstanceName() +
": Working fluid condensing temperature is too high and close to evaporating temperature.
This is likely caused by the flow rate of cold fluid in the condenser being too low
when the ORC is on.");
assert(not (pCon < 101325 - 1 and ena and useLowCondenserPressureWarning),
"*** In " + getInstanceName() +
": Working fluid condensing pressure is lower than 101325 Pa.
If this is intended, set useLowCondenserPressureWarning = false to turn off this warning.",
level=AssertionLevel.warning);
if ena then
// Evaporator
QEva_flow = mHot_flow * cpHot * (THotOut - THotIn);
QEva_flow = mWor_flow * (hPumOut - hExpInl);
(THotPin - THotOut) * (hExpInl - hPumOut)
= (hPinEva - hPumOut) * (THotIn - THotOut);
// Condenser
QCon_flow = mCol_flow * cpCol * (TColOut - TColIn);
QCon_flow = mWor_flow * (hExpOut - hPumInl);
(TColPin - TColIn) * (hExpOut - hPumInl)
= (hPinCon - hPumInl) * (TColOut - TColIn);
else
// Evaporator
QEva_flow = 0;
THotOut = THotIn;
THotPin = THotOut;
// Condenser
QCon_flow = 0;
TColOut = TColIn;
TColPin = TColIn;
end if;
dTPinEva = THotPin - TWorEva; // Evaporator
dTPinCon = TWorCon - TColPin; // Condenser
// Evaporator internal computation
QEva_flow_internal = mHot_flow * cpHot * (THotOut_internal - THotIn);
QEva_flow_internal = mWor_flow_internal * (hPumOut - hExpInl);
(THotPin_internal - THotOut_internal) * (hExpInl - hPumOut)
= (hPinEva - hPumOut) * (THotIn - THotOut_internal);
dTPinEva_set = THotPin_internal - TWorEva;
// Other components
PExp = mWor_flow * (hExpOut - hExpInl);
PPum = mWor_flow * (hPumOut - hPumInl);
mWor_flow =
if on_actual
then
Buildings.Utilities.Math.Functions.smoothMin(
x1=mWor_flow_internal,
x2=mWor_flow_max,
deltaX=mWor_flow_min*1E-2)
else 0;
end FixedEvaporating;
Buildings.Fluid.CHPs.OrganicRankine.BaseClasses.InterpolateStates
Interpolate states of a working fluid
Information
This model performs the property interpolations of a given working fluid. See the documentation of Buildings.Fluid.CHPs.OrganicRankine.ConstantEvaporation for more details.
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| ORC inputs | |||
| Generic | pro | redeclare parameter Building... | Property records of the working fluid |
| Advanced | |||
| SpecificEnthalpy | h_small | (max(pro.hSatVap) - min(pro.... | A small value for specific enthalpy regularisation [J/kg] |
Modelica definition
model InterpolateStates "Interpolate states of a working fluid"
// Input properties
replaceable parameter Buildings.Fluid.CHPs.OrganicRankine.Data.Generic pro
"Property records of the working fluid";
parameter Modelica.Units.SI.SpecificEnthalpy h_small =
(max(pro.hSatVap) - min(pro.hSatLiq)) * 1E-4
"A small value for specific enthalpy regularisation";
input Modelica.Units.SI.ThermodynamicTemperature TEva
"Evaporating temperature";
input Modelica.Units.SI.ThermodynamicTemperature TCon
"Condensing temperature";
input Modelica.Units.SI.Efficiency etaExp
"Expander efficiency";
input Modelica.Units.SI.Efficiency etaPum
"Pump efficiency";
// Once-interpolated properties
Modelica.Units.SI.AbsolutePressure pEva(
displayUnit = "kPa") =
Buildings.Utilities.Math.Functions.interpolate(
u = TEva,
xd = pro.T,
yd = pro.p,
d = pDer_T)
"Evaporating pressure";
Modelica.Units.SI.AbsolutePressure pCon(
displayUnit = "kPa") =
Buildings.Utilities.Math.Functions.interpolate(
u = TCon,
xd = pro.T,
yd = pro.p,
d = pDer_T)
"Condensing pressure";
Modelica.Units.SI.Density rhoLiq =
Buildings.Utilities.Math.Functions.interpolate(
u = TCon,
xd = pro.T,
yd = pro.rhoLiq,
d = rhoLiqDer_T)
"Saturated liquid density";
Modelica.Units.SI.SpecificEntropy sPumInl =
Buildings.Utilities.Math.Functions.interpolate(
u = TCon,
xd = pro.T,
yd = pro.sSatLiq,
d = sSatLiqDer_T)
"Specific entropy at pump inlet";
Modelica.Units.SI.SpecificEnthalpy hPumInl(
displayUnit = "kJ/kg") =
Buildings.Utilities.Math.Functions.interpolate(
u = TCon,
xd = pro.T,
yd = pro.hSatLiq,
d = hSatLiqDer_T)
"Specific enthalpy at pump inlet";
Modelica.Units.SI.SpecificEnthalpy hPinEva(
displayUnit = "kJ/kg") =
Buildings.Utilities.Math.Functions.interpolate(
u = TEva,
xd = pro.T,
yd = pro.hSatLiq,
d = hSatLiqDer_T)
"Specific enthalpy at evaporator-side pinch point";
Modelica.Units.SI.SpecificEnthalpy hPinCon(
displayUnit = "kJ/kg") =
Buildings.Utilities.Math.Functions.interpolate(
u = TCon,
xd = pro.T,
yd = pro.hSatVap,
d = hSatVapDer_T)
"Specific enthalpy at condenser-side pinch point";
Modelica.Units.SI.SpecificEntropy sSatVapCon(
start = max(pro.sSatVap) * 0.1 + min(pro.sSatVap) * 0.9) =
Buildings.Utilities.Math.Functions.interpolate(
u = TCon,
xd = pro.T,
yd = pro.sSatVap,
d = sSatVapDer_T)
"Specific entropy of saturated vapor at the condenser";
Modelica.Units.SI.SpecificEntropy sRefCon =
Buildings.Utilities.Math.Functions.interpolate(
u = pCon,
xd = pro.p,
yd = pro.sRef,
d = sRefDer_p)
"Specific entropy on reference line at condensing pressure";
Modelica.Units.SI.SpecificEntropy sSatVapEva =
Buildings.Utilities.Math.Functions.interpolate(
u = TEva,
xd = pro.T,
yd = pro.sSatVap,
d = sSatVapDer_T)
"Specific entropy of saturated vapor at evaporating temperature";
Modelica.Units.SI.SpecificEnthalpy hSatVapEva(
displayUnit = "kJ/kg") =
Buildings.Utilities.Math.Functions.interpolate(
u = TEva,
xd = pro.T,
yd = pro.hSatVap,
d = hSatVapDer_T)
"Specific enthalpy of saturated vapor at evaporating temperature";
Modelica.Units.SI.SpecificEntropy sRefEva =
Buildings.Utilities.Math.Functions.interpolate(
u = pEva,
xd = pro.p,
yd = pro.sRef,
d = sRefDer_p)
"Specific entropy on reference line at evaporating pressure";
Modelica.Units.SI.SpecificEnthalpy hSatVapCon(
displayUnit = "kJ/kg") =
Buildings.Utilities.Math.Functions.interpolate(
u = TCon,
xd = pro.T,
yd = pro.hSatVap,
d = hSatVapDer_T)
"Specific enthalpy of saturated vapor at the condensing temperature";
Modelica.Units.SI.SpecificEnthalpy hRefCon(
displayUnit = "kJ/kg") =
Buildings.Utilities.Math.Functions.interpolate(
u = pCon,
xd = pro.p,
yd = pro.hRef,
d = hRefDer_p)
"Specific enthalpy on reference line at condensing pressure";
Modelica.Units.SI.SpecificEnthalpy hRefEva(
displayUnit = "kJ/kg") =
Buildings.Utilities.Math.Functions.interpolate(
u = pEva,
xd = pro.p,
yd = pro.hRef,
d = hRefDer_p)
"Specific enthalpy on reference line at evaporating pressure";
// Computed properties not interpolated
Modelica.Units.SI.SpecificEnthalpy hPumOut(displayUnit = "kJ/kg") =
hPumInl + wPum
"Specific enthalpy at pump outlet";
Modelica.Units.SI.SpecificEnthalpy hExpInl(displayUnit = "kJ/kg") =
Buildings.Utilities.Math.Functions.regStep(
x = h_reg,
y1 = hSatVapEva,
y2 = hExpInlWet,
x_small = h_small)
"Specific enthalpy at expander inlet";
Modelica.Units.SI.SpecificEnthalpy hExpOut(displayUnit = "kJ/kg") =
Buildings.Utilities.Math.Functions.regStep(
x = h_reg,
y1 = hExpOutDry,
y2 = hSatVapCon,
x_small = h_small)
"Specific enthalpy at expander inlet";
Modelica.Units.SI.TemperatureDifference dTSup = max(0, dTSupWet)
"Superheating temperature differential";
// Energy transfer
Modelica.Units.SI.SpecificEnergy qEva = hPumOut - hExpInl
"Evaporator specific energy transfer into the cycle";
Modelica.Units.SI.SpecificEnergy qCon = hExpOut - hPumInl
"Condenser specific energy transfer out of the cycle";
Modelica.Units.SI.SpecificEnergy wExp = hExpOut - hExpInl
"Expander specific work";
Modelica.Units.SI.SpecificEnergy wPum = (pEva - pCon) / (rhoLiq * etaPum)
"Pump specific work";
Modelica.Units.SI.Efficiency etaThe(min=0) =
(wExp + wPum) / qEva "Thermal efficiency";
protected
Modelica.Units.SI.SpecificEnthalpy h_reg = hExpOutDry - hSatVapCon
"For regularisation; if > 0, dry cycle";
// Intermediate property computation
// 1. Dry cycle
// expander inlet = saturated vapor at evaporating pressure (known),
// expander outlet = superheated vapor at condensing pressure (solved).
Modelica.Units.SI.SpecificEntropy sExpOutDryIse = sSatVapEva
"Specific entropy at isentropic expander outlet, assuming dry cycle";
Modelica.Units.SI.SpecificEnthalpy hExpOutDryIse(
displayUnit = "kJ/kg") =
if sExpOutDryIse > sSatVapCon
then (hRefCon - hSatVapCon) * (sExpOutDryIse - sSatVapCon)
/ (sRefCon - sSatVapCon) + hSatVapCon
else (hSatVapCon - hPumInl) * (sExpOutDryIse - sPumInl)
/ (sSatVapCon - sPumInl) + hPumInl
"Specific enthalpy at expander outlet, assuming dry cycle";
Modelica.Units.SI.SpecificEnthalpy hExpOutDry(
displayUnit = "kJ/kg") =
hSatVapEva - (hSatVapEva - hExpOutDryIse) * etaExp
"Specific enthalpy at expander outlet, assuming dry cycle";
// 2. Wet cycle
// expander inlet = superheated vapor at evaporating pressure (solved),
// expander outlet = saturated vapor at condensing pressure (known).
Modelica.Units.SI.SpecificEntropy sExpInlWetIse = sSatVapCon
"Specific entropy at isentropic expander inlet, assuming wet cycle";
Modelica.Units.SI.SpecificEnthalpy hExpInlWetIse(
displayUnit = "kJ/kg") =
(hRefEva - hSatVapEva) * (sExpInlWetIse - sSatVapEva)
/ (sRefEva - sSatVapEva) + hSatVapEva
"Specific enthalpy at expander inlet, assuming wet cycle";
Modelica.Units.SI.SpecificEnthalpy hExpInlWet(
displayUnit = "kJ/kg") =
(hExpInlWetIse - hSatVapCon) * etaExp + hSatVapCon
"Specific enthalpy at expander inlet, assuming wet cycle";
Modelica.Units.SI.TemperatureDifference dTSupWet(
displayUnit = "K") =
(hExpInlWet - hSatVapEva) * pro.dTRef / (hRefEva - hSatVapEva)
"Superheating temperature differential, assuming wet cycle";
// Derivatives
final parameter Real pDer_T[pro.n]=
Buildings.Utilities.Math.Functions.splineDerivatives(
x = pro.T,
y = pro.p,
ensureMonotonicity = true)
"Derivative of saturation pressure vs. saturation temperature for cubic spline";
final parameter Real rhoLiqDer_T[pro.n]=
Buildings.Utilities.Math.Functions.splineDerivatives(
x = pro.T,
y = pro.rhoLiq,
ensureMonotonicity = true)
"Derivative of saturated liquid density vs. temperature for cubic spline";
final parameter Real sSatLiqDer_T[pro.n]=
Buildings.Utilities.Math.Functions.splineDerivatives(
x = pro.T,
y = pro.sSatLiq,
ensureMonotonicity = true)
"Derivative of saturated liquid entropy vs. temperature for cubic spline";
final parameter Real sSatVapDer_T[pro.n]=
Buildings.Utilities.Math.Functions.splineDerivatives(
x = pro.T,
y = pro.sSatVap,
ensureMonotonicity = false)
"Derivative of saturated vapor entropy vs. temperature for cubic spline";
final parameter Real sRefDer_p[pro.n]=
Buildings.Utilities.Math.Functions.splineDerivatives(
x = pro.p,
y = pro.sRef,
ensureMonotonicity = false)
"Derivative of reference entropy vs. pressure for cubic spline";
final parameter Real hSatLiqDer_T[pro.n]=
Buildings.Utilities.Math.Functions.splineDerivatives(
x = pro.T,
y = pro.hSatLiq,
ensureMonotonicity = true)
"Derivative of saturated liquid enthalpy vs. temperature for cubic spline";
final parameter Real hSatVapDer_T[pro.n]=
Buildings.Utilities.Math.Functions.splineDerivatives(
x = pro.T,
y = pro.hSatVap,
ensureMonotonicity = false)
"Derivative of saturated vapor enthalpy vs. temperature for cubic spline";
final parameter Real hRefDer_p[pro.n]=
Buildings.Utilities.Math.Functions.splineDerivatives(
x = pro.p,
y = pro.hRef,
ensureMonotonicity = false)
"Derivative of reference enthaly vs. pressure for cubic spline";
end InterpolateStates;