Buildings.Fluid.HydronicConfigurations.BaseClasses
Package with base classes
Information
This package contains base classes that are used to construct the models in Buildings.Fluid.HydronicConfigurations.
Extends from Modelica.Icons.BasesPackage (Icon for packages containing base classes).
Package Content
| Name | Description |
|---|---|
 SingleMixing
|
Single mixing circuit |
Buildings.Fluid.HydronicConfigurations.BaseClasses.SingleMixing
Single mixing circuit
Information
Variable primary
This is a typical configuration for constant flow secondary circuits that have a design supply temperature identical to the primary circuit. The control valve should be sized with a pressure drop at least equal to the maximum of Δp1 and 3e3 Pa. Its authority is β = ΔpA-AB / (ΔpA-AB + Δp1).
In most cases the bypass balancing valve is not needed. However, it may be needed to counter negative back pressure created by other served circuits.
Parameterization
By default the secondary pump is parameterized with
m2_flow_nominal and
dp2_nominal + dpBal2_nominal + max({val.dpValve_nominal, val.dp3Valve_nominal}) + dpBal3_nominal
at maximum speed.
Extends from Fluid.HydronicConfigurations.Interfaces.PartialHydronicConfiguration.
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| replaceable package Medium | Water | Medium in the component | |
| Configuration | |||
| Boolean | use_siz | true | Set to true for built-in sizing of control valve and optional pump |
| Boolean | use_dp1 | use_siz | Set to true to enable dp1_nominal |
| Boolean | use_dp2 | use_siz and typPum <> Buildi... | Set to true to enable dp2_nominal |
| Valve | typVal | Buildings.Fluid.HydronicConf... | Type of control valve |
| Boolean | have_typVar | false | Set to true to enable the choice of the controlled variable |
| Nominal condition | |||
| MassFlowRate | m1_flow_nominal | m2_flow_nominal | Mass flow rate in primary circuit at design conditions [kg/s] |
| MassFlowRate | m2_flow_nominal | Mass flow rate in consumer circuit at design conditions [kg/s] | |
| PressureDifference | dp1_nominal | Primary circuit pressure differential at design conditions [Pa] | |
| PressureDifference | dp2_nominal | Consumer circuit pressure differential at design conditions [Pa] | |
| Control valve | |||
| ValveCharacteristic | typCha | Buildings.Fluid.HydronicConf... | Control valve characteristic |
| PressureDifference | dpValve_nominal | max(dp1_nominal, 3E3) | Control valve pressure drop at design conditions [Pa] |
| Generic | flowCharacteristics | Table with flow characteristics | |
| Generic | flowCharacteristics1 | Table with flow characteristics for direct flow path at port_1 | |
| Generic | flowCharacteristics3 | Table with flow characteristics for bypass flow path at port_3 | |
| Pump | |||
| Pump | typPum | Buildings.Fluid.HydronicConf... | Type of secondary pump |
| PumpModel | typPumMod | Buildings.Fluid.HydronicConf... | Type of pump model |
| MassFlowRate | mPum_flow_nominal | m2_flow_nominal | Pump head at design conditions [kg/s] |
| PressureDifference | dpPum_nominal | dp2_nominal + dpBal2_nominal... | Pump head at design conditions [Pa] |
| Generic | perPum | redeclare parameter Movers.D... | Pump parameters |
| Controls | |||
| Control | typCtl | Buildings.Fluid.HydronicConf... | Type of built-in controls |
| ControlVariable | typVar | Buildings.Fluid.HydronicConf... | Controlled variable |
| SimpleController | controllerType | Buildings.Controls.OBC.CDL.T... | Type of controller |
| Real | k | 0.1 | Gain of controller |
| Real | Ti | 120 | Time constant of integrator block [s] |
| Balancing valves | |||
| PressureDifference | dpBal1_nominal | 0 | Primary balancing valve pressure drop at design conditions [Pa] |
| PressureDifference | dpBal2_nominal | 0 | Secondary balancing valve pressure drop at design conditions [Pa] |
| PressureDifference | dpBal3_nominal | 0 | Bypass balancing valve pressure drop at design conditions [Pa] |
| Assumptions | |||
| Boolean | use_lumFloRes | true | Set to true to use a lumped flow resistance when possible |
| Boolean | allowFlowReversal | true | = false to simplify equations, assuming, but not enforcing, no flow reversal for medium 1 |
| Dynamics | |||
| Conservation equations | |||
| Dynamics | energyDynamics | Modelica.Fluid.Types.Dynamic... | Type of energy balance: dynamic (3 initialization options) or steady state |
| Advanced | |||
| Diagnostics | |||
| Boolean | show_T | false | = true, if actual temperature at port is computed |
Connectors
| Type | Name | Description |
|---|---|---|
| FluidPort_a | port_a1 | Primary supply port |
| FluidPort_b | port_b1 | Primary return port |
| FluidPort_a | port_a2 | Secondary return port |
| FluidPort_b | port_b2 | Secondary supply port |
| input RealInput | yVal | Valve control signal [1] |
| input RealInput | set | Set point [K] |
| input RealInput | yPum | Pump control signal (variable speed) [1] |
| input IntegerInput | mode | Operating mode |
| output RealOutput | yVal_actual | Valve position feedback [1] |
| output RealOutput | yPum_actual | Actual pump input value that is used for computations [1] |
| output RealOutput | PPum | Pump electrical power [W] |
Modelica definition
model SingleMixing "Single mixing circuit"
extends Fluid.HydronicConfigurations.Interfaces.PartialHydronicConfiguration(
set(final unit="K", displayUnit="degC"),
dpValve_nominal=max(dp1_nominal, 3E3),
dpPum_nominal=dp2_nominal + dpBal2_nominal +
max({val.dpValve_nominal, val.dp3Valve_nominal + dpBal3_nominal}),
final m1_flow_nominal=m2_flow_nominal,
final typVal=Buildings.Fluid.HydronicConfigurations.Types.Valve.ThreeWay,
final use_dp1=use_siz,
final use_dp2=use_siz and typPum<>Buildings.Fluid.HydronicConfigurations.Types.Pump.None,
final have_typVar=false);
Buildings.Fluid.HydronicConfigurations.Components.ThreeWayValve val(
redeclare final package Medium=Medium,
final typCha=typCha,
final energyDynamics=energyDynamics,
use_inputFilter=energyDynamics<>Modelica.Fluid.Types.Dynamics.SteadyState,
final portFlowDirection_1=if allowFlowReversal then
Modelica.Fluid.Types.PortFlowDirection.Bidirectional else
Modelica.Fluid.Types.PortFlowDirection.Entering,
final portFlowDirection_2=if allowFlowReversal then
Modelica.Fluid.Types.PortFlowDirection.Bidirectional else
Modelica.Fluid.Types.PortFlowDirection.Leaving,
final portFlowDirection_3=if allowFlowReversal then
Modelica.Fluid.Types.PortFlowDirection.Bidirectional else
Modelica.Fluid.Types.PortFlowDirection.Entering,
final m_flow_nominal=m2_flow_nominal,
final dpValve_nominal=dpValve_nominal,
final dpFixed_nominal=if use_lumFloRes then {dpBal1_nominal, dpBal3_nominal} else {0,0},
final flowCharacteristics1=flowCharacteristics1,
final flowCharacteristics3=flowCharacteristics3)
"Control valve";
FixedResistances.Junction jun(
redeclare final package Medium = Medium,
final energyDynamics=energyDynamics,
final portFlowDirection_1=if allowFlowReversal then Modelica.Fluid.Types.PortFlowDirection.Bidirectional
else Modelica.Fluid.Types.PortFlowDirection.Entering,
final portFlowDirection_2=if allowFlowReversal then Modelica.Fluid.Types.PortFlowDirection.Bidirectional
else Modelica.Fluid.Types.PortFlowDirection.Leaving,
final portFlowDirection_3=if allowFlowReversal then Modelica.Fluid.Types.PortFlowDirection.Bidirectional
else Modelica.Fluid.Types.PortFlowDirection.Leaving,
final m_flow_nominal=m1_flow_nominal .* {1,-1,-1},
final dp_nominal=fill(0, 3))
"Junction";
FixedResistances.PressureDrop res1(
redeclare final package Medium = Medium,
final allowFlowReversal=allowFlowReversal,
final m_flow_nominal=m1_flow_nominal,
final dp_nominal=if use_lumFloRes then 0 else dpBal1_nominal)
"Primary balancing valve";
FixedResistances.PressureDrop res2(
redeclare final package Medium = Medium,
final allowFlowReversal=allowFlowReversal,
final m_flow_nominal=m2_flow_nominal,
final dp_nominal=dpBal2_nominal)
"Secondary balancing valve";
Buildings.Fluid.HydronicConfigurations.Components.Pump pum(
redeclare final package Medium = Medium,
final typ=typPum,
final typMod=typPumMod,
final m_flow_nominal=mPum_flow_nominal,
final dp_nominal=dpPum_nominal,
final energyDynamics=energyDynamics,
final allowFlowReversal=allowFlowReversal,
use_inputFilter=energyDynamics<>Modelica.Fluid.Types.Dynamics.SteadyState,
final per=perPum)
"Pump";
Sensors.TemperatureTwoPort T2Sup(
redeclare final package Medium = Medium,
final m_flow_nominal=m2_flow_nominal,
final allowFlowReversal=allowFlowReversal,
tau=if energyDynamics == Modelica.Fluid.Types.Dynamics.SteadyState then 0
else 1) "Consumer circuit supply temperature sensor";
Controls.PIDWithOperatingMode ctl(
u_s(final unit="K", displayUnit="degC"),
u_m(final unit="K", displayUnit="degC"),
final reverseActing=typCtl == Buildings.Fluid.HydronicConfigurations.Types.Control.Heating,
final yMin=0,
final yMax=1,
final controllerType=controllerType,
final k=k,
final Ti=Ti)
if typCtl <> Buildings.Fluid.HydronicConfigurations.Types.Control.None
"Controller";
Buildings.Controls.OBC.CDL.Integers.GreaterThreshold isEna(
final t=Controls.OperatingModes.disabled)
"Returns true if enabled";
Sensors.TemperatureTwoPort T2Ret(
redeclare final package Medium = Medium,
final m_flow_nominal=m2_flow_nominal,
final allowFlowReversal=allowFlowReversal,
tau=if energyDynamics == Modelica.Fluid.Types.Dynamics.SteadyState then 0
else 1) "Consumer circuit return temperature sensor";
FixedResistances.PressureDrop res3(
redeclare final package Medium = Medium,
final allowFlowReversal=allowFlowReversal,
final m_flow_nominal=m2_flow_nominal,
final dp_nominal=if use_lumFloRes then 0 else dpBal3_nominal)
"Bypass balancing valve";
equation
connect(port_b1,res1. port_b);
connect(pum.port_b, T2Sup.port_a);
connect(T2Sup.port_b, port_b2);
connect(ctl.y, val.y);
connect(mode, ctl.mode);
connect(T2Sup.T, ctl.u_m);
connect(set, ctl.u_s);
connect(yVal, val.y);
connect(mode, isEna.u);
connect(jun.port_2,res1. port_a);
connect(res2.port_b, jun.port_1);
connect(val.port_2, pum.port_a);
connect(val.port_1, port_a1);
connect(pum.P, PPum);
connect(pum.y_actual, yPum_actual);
connect(port_a2, T2Ret.port_a);
connect(T2Ret.port_b,res2. port_a);
connect(jun.port_3, res3.port_a);
connect(res3.port_b, val.port_3);
connect(val.y_actual, yVal_actual);
connect(isEna.y, pum.y1);
connect(yPum, pum.y);
end SingleMixing;