Buildings.HeatTransfer.Radiosity

Information

This package provides component models for the infrared radiative heat exchange of window assemblies. The models are according to TARCOG 2006, except for the outdoor radiosity, which is computed by Buildings.HeatTransfer.Radiosity.OutdoorRadiosity. The outdoor radiosity is different from the TARCOG implementation so that the same equations are used for windows as are used for opaque walls in the room heat transfer model of the package Buildings.Rooms.

References

TARCOG 2006: Carli, Inc., TARCOG: Mathematical models for calculation of thermal performance of glazing systems with our without shading devices, Technical Report, Oct. 17, 2006.

Extends from Modelica.Icons.VariantsPackage (Icon for package containing variants).

Package Content

Name	Description
Constant	Generate constant radiosity signal
OpaqueSurface	Model for an opaque surface
IndoorRadiosity	Model for indoor radiosity
OutdoorRadiosity	Model for the outdoor radiosity that strikes the window
RadiositySplitter	Splits the incoming radiosity into two flows based on an input signal
Examples	Collection of models that illustrate model use and test models
BaseClasses	Package with base classes for Buildings.HeatTransfer.Radiosity

Buildings.HeatTransfer.Radiosity.Constant

Information

Constant radiosity source. This model requires k ≤ 0 because the radiosity leaves the component and hence needs to be negative or zero.

This model is used in Buildings.HeatTransfer.BaseClasses.DummyConstructionExterior.

Extends from Modelica.Blocks.Interfaces.BlockIcon (Basic graphical layout of input/output block).

Parameters

Type	Name	Default	Description
Real	k		Radiosity that leaves this component (k <= 0)

Connectors

Type	Name	Description
output RadiosityOutflow	JOut	[W]

Modelica definition

block Constant "Generate constant radiosity signal"
  parameter Real k(max=0, start=0) 
    "Radiosity that leaves this component (k <= 0)";
  extends Modelica.Blocks.Interfaces.BlockIcon;

  Interfaces.RadiosityOutflow JOut;
equation 
  JOut = k;
end Constant;

Buildings.HeatTransfer.Radiosity.OpaqueSurface

Information

Extends from Buildings.HeatTransfer.Radiosity.BaseClasses.RadiosityOneSurface (Model for the radiosity balance of a device with one surface), Buildings.HeatTransfer.Radiosity.BaseClasses.ParametersOneSurface (Parameters that are used to model one surface).

Parameters

Type	Name	Default	Description
Area	A		Surface area [m2]
Emissivity	absIR		Infrared absorptivity [1]
ReflectionCoefficient	rhoIR	1 - absIR	Infrared reflectivity [1]
TransmissionCoefficient	tauIR	1 - rhoIR - absIR	Infrared transmissivity [1]
Boolean	linearize	false	Set to true to linearize emissive power
Temperature	T0	293.15	Temperature used to linearize radiative heat transfer [K]

Connectors

Type	Name	Description
input RadiosityInflow	JIn	Incoming radiosity [W]
output RadiosityOutflow	JOut	Outgoing radiosity [W]
HeatPort_a	heatPort	Heat port of this surface

Modelica definition

model OpaqueSurface "Model for an opaque surface"
  extends Buildings.HeatTransfer.Radiosity.BaseClasses.RadiosityOneSurface;
  extends Buildings.HeatTransfer.Radiosity.BaseClasses.ParametersOneSurface(
      final tauIR=1 - rhoIR - absIR, final rhoIR=1 - absIR);

  Modelica.Thermal.HeatTransfer.Interfaces.HeatPort_a heatPort 
    "Heat port of this surface";
protected 
  final parameter Real T03(
    min=0,
    unit="K3") = T0^3 "3rd power of temperature T0";
  final parameter Real T04(
    min=0,
    unit="K4") = T0^4 "4th power of temperature T0";
  Real T4(
    min=1E8,
    start=293.15^4,
    nominal=1E10,
    unit="K4") "4th power of temperature";

equation 
  T4 = if linearize then 4*T03*heatPort.T - 3*T04 else heatPort.T^4;
  0 = JOut + A*absIR*Modelica.Constants.sigma*T4 + rhoIR*JIn;
  0 = heatPort.Q_flow + JIn + JOut;

end OpaqueSurface;

Buildings.HeatTransfer.Radiosity.IndoorRadiosity

Information

References

TARCOG 2006: Carli, Inc., TARCOG: Mathematical models for calculation of thermal performance of glazing systems with our without shading devices, Technical Report, Oct. 17, 2006.

Extends from Buildings.HeatTransfer.Radiosity.BaseClasses.RadiosityOneSurface (Model for the radiosity balance of a device with one surface), Buildings.HeatTransfer.Radiosity.BaseClasses.ParametersOneSurface (Parameters that are used to model one surface).

Parameters

Type	Name	Default	Description
Area	A		Surface area [m2]
Emissivity	absIR	1	Infrared absorptivity [1]
ReflectionCoefficient	rhoIR	0	Infrared reflectivity [1]
TransmissionCoefficient	tauIR	0	Infrared transmissivity [1]
Boolean	linearize	false	Set to true to linearize emissive power
Temperature	T0	293.15	Temperature used to linearize radiative heat transfer [K]

Connectors

Type	Name	Description
input RadiosityInflow	JIn	Incoming radiosity [W]
output RadiosityOutflow	JOut	Outgoing radiosity [W]
HeatPort_a	heatPort	Heat port of this surface

Modelica definition

model IndoorRadiosity "Model for indoor radiosity"
  extends Buildings.HeatTransfer.Radiosity.BaseClasses.RadiosityOneSurface;
  extends Buildings.HeatTransfer.Radiosity.BaseClasses.ParametersOneSurface(
    final absIR=1,
    final tauIR=0,
    final rhoIR=0);
  Modelica.Thermal.HeatTransfer.Interfaces.HeatPort_a heatPort 
    "Heat port of this surface";
protected 
  final parameter Real T03(
    min=0,
    unit="K3") = T0^3 "3rd power of temperature T0";
  final parameter Real T04(
    min=0,
    unit="K4") = T0^4 "4th power of temperature T0";
  Real T4(
    min=1E8,
    start=293.15^4,
    nominal=1E10,
    unit="K4") "4th power of temperature";
equation 
  T4 = if linearize then 4*T03*heatPort.T - 3*T04 else heatPort.T^4;
  JOut = -A*Modelica.Constants.sigma*T4;
  0 = heatPort.Q_flow + JIn + JOut;
end IndoorRadiosity;

Buildings.HeatTransfer.Radiosity.OutdoorRadiosity

Information

Model for the infrared radiosity balance of the outdoor environment.

Parameters

Type	Name	Default	Description
Area	A		Area of receiving surface [m2]
Real	vieFacSky		View factor from receiving surface to sky (=1 for roofs)
Boolean	linearize	false	Set to true to linearize emissive power
Temperature	T0	293.15	Temperature used to linearize radiative heat transfer [K]

Connectors

Type	Name	Description
input RealInput	TOut	Outside temperature [K]
input RealInput	TBlaSky	Black body sky temperature [K]
output RadiosityOutflow	JOut	Radiosity that flows out of component [W]

Modelica definition

model OutdoorRadiosity 
  "Model for the outdoor radiosity that strikes the window"
  parameter Modelica.SIunits.Area A "Area of receiving surface";
  parameter Real vieFacSky(min=0, max=1) 
    "View factor from receiving surface to sky (=1 for roofs)";
  parameter Boolean linearize=false "Set to true to linearize emissive power";
  parameter Modelica.SIunits.Temperature T0=293.15 
    "Temperature used to linearize radiative heat transfer";
  Real TRad4(unit="K4") "4th power of the mean outdoor temperature";
  Modelica.SIunits.Temperature TRad "Mean radiant temperature";

  Modelica.Blocks.Interfaces.RealInput TOut(
    final quantity="ThermodynamicTemperature",
    final unit="K",
    min=0) "Outside temperature";
  Modelica.Blocks.Interfaces.RealInput TBlaSky(
    final quantity="ThermodynamicTemperature",
    final unit="K",
    min=0) "Black body sky temperature";
  Buildings.HeatTransfer.Interfaces.RadiosityOutflow JOut 
    "Radiosity that flows out of component";
protected 
  final parameter Real T03(
    min=0,
    unit="K3") = T0^3 "3rd power of temperature T0";
  final parameter Real T04(
    min=0,
    unit="K4") = T0^4 "4th power of temperature T0";
equation 
  TRad4 = (vieFacSky*TBlaSky^4 + (1 - vieFacSky)*TOut^4);
  JOut = -A*Modelica.Constants.sigma*TRad4;
  TRad = if linearize then (TRad4 + 3*T04)/(4*T03) else TRad4^(1/4);

end OutdoorRadiosity;

Buildings.HeatTransfer.Radiosity.RadiositySplitter

Information

This blocks splits the incoming radiosity into two fluxes according to

J_Out,1 = - u J_In,
J_Out,2 = - (1-u) J_In.

This block may be used to split the radiosity flux into a fraction that strikes the shaded part of a window, and a fraction that strikes the non-shaded part.

Extends from Modelica.Blocks.Interfaces.BlockIcon (Basic graphical layout of input/output block).

Connectors

Type	Name	Description
input RadiosityInflow	JIn	[W]
input RealInput	u	u times incoming radiosity
output RadiosityOutflow	JOut_1	[W]
output RadiosityOutflow	JOut_2	(1-u) times incoming radiosity [W]

Modelica definition

block RadiositySplitter 
  "Splits the incoming radiosity into two flows based on an input signal"
  extends Modelica.Blocks.Interfaces.BlockIcon;

  Interfaces.RadiosityInflow JIn;
  Modelica.Blocks.Interfaces.RealInput u(min=0, max=1) 
    "u times incoming radiosity";
  Interfaces.RadiosityOutflow JOut_1;

  Interfaces.RadiosityOutflow JOut_2 "(1-u) times incoming radiosity";
equation 
  JOut_1 = - u    * JIn;
  JOut_2 = - (1-u)* JIn;
end RadiositySplitter;