Buildings.Media.Interfaces.PartialSimpleIdealGasMedium

Information

This is the most simple incompressible medium model, where specific enthalpy h and specific internal energy u are only a function of temperature T and all other provided medium quantities are assumed to be constant.

This partial package is identical to Modelica.Media.Interfaces.PartialSimpleIdealGasMedium but it fixes two bugs in the original implementation. Namely, in the functions Modelica.Media.Interfaces.PartialSimpleIdealGasMedium.specificEnthalpy and Modelica.Media.Interfaces.PartialSimpleIdealGasMedium.specificInternalEnergy the computation of the enthalpy or internal energy does not use the reference temperature T0. With this implementation, initial states of fluid volumes can be far away from the steady-state value because of this inconsistent implementation. Because these two functions are not replaceable, we needed to make a copy of the whole package, and reimplement these functions. When the Buildings library is upgraded to to Modelica 3.0.0, it should be safe to remove this package as the bug is fixed since Modelica 3.0.0 (but not in Modelica 2.2.2).

Package Content

Name	Description
cp_const	Constant specific heat capacity at constant pressure
cv_const=cp_const/R_gas	Constant specific heat capacity at constant volume
R_gas	medium specific gas constant
MM_const	Molar mass
eta_const	Constant dynamic viscosity
lambda_const	Constant thermal conductivity
T_min	Minimum temperature valid for medium model
T_max	Maximum temperature valid for medium model
T0=reference_T	Zero enthalpy temperature
ThermodynamicState	thermodynamic state
BaseProperties	Base properties
setState_pTX	Return thermodynamic state from p, T, and X or Xi
setState_phX	Return thermodynamic state from p, h, and X or Xi
setState_psX	Return thermodynamic state from p, s, and X or Xi
setState_dTX	Return thermodynamic state from d, T, and X or Xi
pressure	return pressure of ideal gas
temperature	return temperature of ideal gas
density	return density of ideal gas
specificEnthalpy	Return specific enthalpy
specificInternalEnergy	Return specific internal energy
specificEntropy	Return specific entropy
specificGibbsEnergy	Return specific Gibbs energy
specificHelmholtzEnergy	Return specific Helmholtz energy
dynamicViscosity	Return dya_constnamic viscosity
thermalConductivity	Return thermal conductivity
specificHeatCapacityCp	Return specific heat capacity at constant pressure
specificHeatCapacityCv	Return specific heat capacity at constant volume
isentropicExponent	Return isentropic exponent
velocityOfSound	Velocity of sound
specificEnthalpy_pTX	Return specific enthalpy from p, T, and X or Xi
temperature_phX	Return temperature from p, h, and X or Xi
density_phX	Return density from p, h, and X or Xi

Types and constants

  constant SpecificHeatCapacity cp_const 
  "Constant specific heat capacity at constant pressure";

  constant SpecificHeatCapacity cv_const= cp_const/R_gas 
  "Constant specific heat capacity at constant volume";

  constant SpecificHeatCapacity R_gas "medium specific gas constant";

  constant MolarMass MM_const "Molar mass";

  constant DynamicViscosity eta_const "Constant dynamic viscosity";

  constant ThermalConductivity lambda_const "Constant thermal conductivity";

  constant Temperature T_min "Minimum temperature valid for medium model";

  constant Temperature T_max "Maximum temperature valid for medium model";

  constant Temperature T0= reference_T "Zero enthalpy temperature";

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.ThermodynamicState

Modelica definition

redeclare replaceable record extends ThermodynamicState 
  "thermodynamic state" 
  AbsolutePressure p "Absolute pressure of medium";
  Temperature T "Temperature of medium";
end ThermodynamicState;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.BaseProperties

Parameters

Type	Name	Default	Description
Advanced
Boolean	preferredMediumStates	false	= true if StateSelect.prefer shall be used for the independent property variables of the medium

Modelica definition

redeclare replaceable model extends BaseProperties(
        T(stateSelect=StateSelect.prefer)) "Base properties" 
equation 
      assert(T >= T_min and T <= T_max, "
Temperature T (= " + String(T) + " K) is not
in the allowed range (" + String(T_min) + " K <= T <= " + String(T_max)
         + " K)
required from medium model \"" + mediumName + "\".
");
  h = specificEnthalpy_pTX(p,T,X);
  u = h-R*T;
  R = R_gas;
  d = p/(R*T);
  MM = MM_const;
  state.T = T;
  state.p = p;
  
end BaseProperties;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.setState_pTX

Inputs

Type	Name	Default	Description
AbsolutePressure	p		Pressure [Pa]
Temperature	T		Temperature [K]
MassFraction	X[:]	fill(0, 0)	Mass fractions [kg/kg]

Outputs

Type	Name	Description
ThermodynamicState	state

Modelica definition

redeclare function setState_pTX 
  "Return thermodynamic state from p, T, and X or Xi" 
  extends Modelica.Icons.Function;
  input AbsolutePressure p "Pressure";
  input Temperature T "Temperature";
  input MassFraction X[:] = fill(0,0) "Mass fractions";
  output ThermodynamicState state;
algorithm 
  state := ThermodynamicState(p=p,T=T);
end setState_pTX;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.setState_phX

Inputs

Type	Name	Default	Description
AbsolutePressure	p		Pressure [Pa]
SpecificEnthalpy	h		Specific enthalpy [J/kg]
MassFraction	X[:]	fill(0, 0)	Mass fractions [kg/kg]

Outputs

Type	Name	Description
ThermodynamicState	state

Modelica definition

redeclare function setState_phX 
  "Return thermodynamic state from p, h, and X or Xi" 
  extends Modelica.Icons.Function;
  input AbsolutePressure p "Pressure";
  input SpecificEnthalpy h "Specific enthalpy";
  input MassFraction X[:] = fill(0,0) "Mass fractions";
  output ThermodynamicState state;
algorithm 
  state := ThermodynamicState(p=p,T=T0+h/cp_const);
end setState_phX;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.setState_psX

Inputs

Type	Name	Default	Description
AbsolutePressure	p		Pressure [Pa]
SpecificEntropy	s		Specific entropy [J/(kg.K)]
MassFraction	X[:]	fill(0, 0)	Mass fractions [kg/kg]

Outputs

Type	Name	Description
ThermodynamicState	state

Modelica definition

redeclare replaceable function setState_psX 
  "Return thermodynamic state from p, s, and X or Xi" 
  extends Modelica.Icons.Function;
  input AbsolutePressure p "Pressure";
  input SpecificEntropy s "Specific entropy";
  input MassFraction X[:] = fill(0,0) "Mass fractions";
  output ThermodynamicState state;
algorithm 
  state := ThermodynamicState(p=p,T=Modelica.Math.exp(s/cp_const + Modelica.Math.log(reference_T))
                              + R_gas*Modelica.Math.log(p/reference_p));
end setState_psX;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.setState_dTX

Inputs

Type	Name	Default	Description
Density	d		density [kg/m3]
Temperature	T		Temperature [K]
MassFraction	X[:]	fill(0, 0)	Mass fractions [kg/kg]

Outputs

Type	Name	Description
ThermodynamicState	state

Modelica definition

redeclare function setState_dTX 
  "Return thermodynamic state from d, T, and X or Xi" 
  extends Modelica.Icons.Function;
  input Density d "density";
  input Temperature T "Temperature";
  input MassFraction X[:] = fill(0,0) "Mass fractions";
  output ThermodynamicState state;
algorithm 
  state := ThermodynamicState(p=d*R_gas*T,T=T);
end setState_dTX;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.pressure

Inputs

Type	Name	Default	Description
ThermodynamicState	state

Outputs

Type	Name	Description
AbsolutePressure	p	Pressure [Pa]

Modelica definition

redeclare function extends pressure "return pressure of ideal gas" 
algorithm 
  p := state.p;
end pressure;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.temperature

Inputs

Type	Name	Default	Description
ThermodynamicState	state

Outputs

Type	Name	Description
Temperature	T	Temperature [K]

Modelica definition

redeclare function extends temperature 
  "return temperature of ideal gas" 
algorithm 
  T := state.T;
end temperature;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.density

Inputs

Type	Name	Default	Description
ThermodynamicState	state

Outputs

Type	Name	Description
Density	d	Density [kg/m3]

Modelica definition

redeclare function extends density "return density of ideal gas" 
algorithm 
  d := state.p/(R_gas*state.T);
end density;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.specificEnthalpy

Inputs

Type	Name	Default	Description
ThermodynamicState	state

Outputs

Type	Name	Description
SpecificEnthalpy	h	Specific enthalpy [J/kg]

Modelica definition

redeclare function extends specificEnthalpy 
  "Return specific enthalpy" 
    extends Modelica.Icons.Function;
algorithm 
  h := cp_const*(state.T-T0); // this is one of the bug fixes
end specificEnthalpy;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.specificInternalEnergy

Inputs

Type	Name	Default	Description
ThermodynamicState	state

Outputs

Type	Name	Description
SpecificEnergy	u	Specific internal energy [J/kg]

Modelica definition

redeclare function extends specificInternalEnergy 
  "Return specific internal energy" 
  extends Modelica.Icons.Function;
algorithm 
  u := cp_const*(state.T-T0) - R_gas*state.T; // this is one of the bug fixes
end specificInternalEnergy;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.specificEntropy

Inputs

Type	Name	Default	Description
ThermodynamicState	state

Outputs

Type	Name	Description
SpecificEntropy	s	Specific entropy [J/(kg.K)]

Modelica definition

redeclare function extends specificEntropy "Return specific entropy" 
    extends Modelica.Icons.Function;
algorithm 
  s := cp_const*Modelica.Math.log(state.T/T0) - R_gas*Modelica.Math.log(state.p/reference_p);
end specificEntropy;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.specificGibbsEnergy

Inputs

Type	Name	Default	Description
ThermodynamicState	state

Outputs

Type	Name	Description
SpecificEnergy	g	Specific Gibbs energy [J/kg]

Modelica definition

redeclare function extends specificGibbsEnergy 
  "Return specific Gibbs energy" 
  extends Modelica.Icons.Function;
algorithm 
  g := cp_const*state.T - state.T*specificEntropy(state);
end specificGibbsEnergy;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.specificHelmholtzEnergy

Inputs

Type	Name	Default	Description
ThermodynamicState	state

Outputs

Type	Name	Description
SpecificEnergy	f	Specific Helmholtz energy [J/kg]

Modelica definition

redeclare function extends specificHelmholtzEnergy 
  "Return specific Helmholtz energy" 
  extends Modelica.Icons.Function;
algorithm 
  f := cp_const*state.T - R_gas*state.T - state.T*specificEntropy(state);
end specificHelmholtzEnergy;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.dynamicViscosity

Inputs

Type	Name	Default	Description
ThermodynamicState	state

Outputs

Type	Name	Description
DynamicViscosity	eta	Dynamic viscosity [Pa.s]

Modelica definition

redeclare function extends dynamicViscosity 
  "Return dya_constnamic viscosity" 
algorithm 
  eta := eta_const;
end dynamicViscosity;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.thermalConductivity

Inputs

Type	Name	Default	Description
ThermodynamicState	state

Outputs

Type	Name	Description
ThermalConductivity	lambda	Thermal conductivity [W/(m.K)]

Modelica definition

redeclare function extends thermalConductivity 
  "Return thermal conductivity" 
algorithm 
  lambda := lambda_const;
end thermalConductivity;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.specificHeatCapacityCp

Inputs

Type	Name	Default	Description
ThermodynamicState	state

Outputs

Type	Name	Description
SpecificHeatCapacity	cp	Specific heat capacity at constant pressure [J/(kg.K)]

Modelica definition

redeclare function extends specificHeatCapacityCp 
  "Return specific heat capacity at constant pressure" 
algorithm 
  cp := cp_const;
end specificHeatCapacityCp;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.specificHeatCapacityCv

Inputs

Type	Name	Default	Description
ThermodynamicState	state

Outputs

Type	Name	Description
SpecificHeatCapacity	cv	Specific heat capacity at constant volume [J/(kg.K)]

Modelica definition

redeclare function extends specificHeatCapacityCv 
  "Return specific heat capacity at constant volume" 
algorithm 
  cv := cv_const;
end specificHeatCapacityCv;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.isentropicExponent

Inputs

Type	Name	Default	Description
ThermodynamicState	state

Outputs

Type	Name	Description
IsentropicExponent	gamma	Isentropic exponent [1]

Modelica definition

redeclare function extends isentropicExponent 
  "Return isentropic exponent" 
algorithm 
  gamma := cp_const/cv_const;
end isentropicExponent;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.velocityOfSound

Inputs

Type	Name	Default	Description
ThermodynamicState	state

Outputs

Type	Name	Description
VelocityOfSound	a	Velocity of sound [m/s]

Modelica definition

redeclare function extends velocityOfSound "Velocity of sound " 
algorithm 
  a := sqrt(cp_const/cv_const*R_gas*state.T);
end velocityOfSound;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.specificEnthalpy_pTX

Inputs

Type	Name	Default	Description
AbsolutePressure	p		Pressure [Pa]
Temperature	T		Temperature [K]
MassFraction	X[nX]		Mass fractions [kg/kg]

Outputs

Type	Name	Description
SpecificEnthalpy	h	Specific enthalpy at p, T, X [J/kg]

Modelica definition

redeclare function specificEnthalpy_pTX 
  "Return specific enthalpy from p, T, and X or Xi" 
  extends Modelica.Icons.Function;
  input AbsolutePressure p "Pressure";
  input Temperature T "Temperature";
  input MassFraction X[nX] "Mass fractions";
  output SpecificEnthalpy h "Specific enthalpy at p, T, X";
algorithm 
  h := cp_const*(T-T0);
end specificEnthalpy_pTX;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.temperature_phX

Inputs

Type	Name	Default	Description
AbsolutePressure	p		Pressure [Pa]
SpecificEnthalpy	h		Specific enthalpy [J/kg]
MassFraction	X[nX]		Mass fractions [kg/kg]

Outputs

Type	Name	Description
Temperature	T	Temperature [K]

Modelica definition

redeclare function temperature_phX 
  "Return temperature from p, h, and X or Xi" 
  extends Modelica.Icons.Function;
  input AbsolutePressure p "Pressure";
  input SpecificEnthalpy h "Specific enthalpy";
  input MassFraction X[nX] "Mass fractions";
  output Temperature T "Temperature";
algorithm 
  T := h/cp_const + T0;
end temperature_phX;

Buildings.Media.Interfaces.PartialSimpleIdealGasMedium.density_phX

Inputs

Type	Name	Default	Description
AbsolutePressure	p		Pressure [Pa]
SpecificEnthalpy	h		Specific enthalpy [J/kg]
MassFraction	X[nX]		Mass fractions [kg/kg]

Outputs

Type	Name	Description
Density	d	density [kg/m3]

Modelica definition

redeclare function density_phX 
  "Return density from p, h, and X or Xi" 
  extends Modelica.Icons.Function;
  input AbsolutePressure p "Pressure";
  input SpecificEnthalpy h "Specific enthalpy";
  input MassFraction X[nX] "Mass fractions";
  output Density d "density";
algorithm 
  d := density(setState_phX(p,h,X));
end density_phX;