Buildings.Fluid.Chillers.Examples

Information

Extends from Buildings.BaseClasses.BaseIconExamples (Icon for Examples packages).

Package Content

Name	Description
Carnot	Test model for chiller based on Carnot efficiency
ElectricReformulatedEIR	Test model for chiller electric reformulated EIR
ElectricEIR	Test model for chiller electric EIR
BaseClasses	Package with base classes for example models

Buildings.Fluid.Chillers.Examples.Carnot

Parameters

Type	Name	Default	Description
Power	P_nominal	10E3	Nominal compressor power (at y=1) [W]
TemperatureDifference	dTEva_nominal	10	Temperature difference evaporator inlet-outlet [K]
TemperatureDifference	dTCon_nominal	10	Temperature difference condenser outlet-inlet [K]
Real	COPc_nominal	3	Chiller COP
MassFlowRate	m2_flow_nominal	P_nominal*COPc_nominal/dTEva...	Nominal mass flow rate at chilled water side [kg/s]
MassFlowRate	m1_flow_nominal	m2_flow_nominal*(COPc_nomina...	Nominal mass flow rate at condenser water wide [kg/s]

Modelica definition

model Carnot "Test model for chiller based on Carnot efficiency"
  import Buildings;
 package Medium1 = Buildings.Media.ConstantPropertyLiquidWater "Medium model";
 package Medium2 = Buildings.Media.ConstantPropertyLiquidWater "Medium model";

  parameter Modelica.SIunits.Power P_nominal=10E3 
    "Nominal compressor power (at y=1)";
  parameter Modelica.SIunits.TemperatureDifference dTEva_nominal=10 
    "Temperature difference evaporator inlet-outlet";
  parameter Modelica.SIunits.TemperatureDifference dTCon_nominal=10 
    "Temperature difference condenser outlet-inlet";
  parameter Real COPc_nominal = 3 "Chiller COP";

  parameter Modelica.SIunits.MassFlowRate m2_flow_nominal=
     P_nominal*COPc_nominal/dTEva_nominal/4200 
    "Nominal mass flow rate at chilled water side";
  parameter Modelica.SIunits.MassFlowRate m1_flow_nominal=
    m2_flow_nominal*(COPc_nominal+1)/COPc_nominal 
    "Nominal mass flow rate at condenser water wide";

  Buildings.Fluid.Chillers.Carnot chi(
    redeclare package Medium1 = Medium1,
    redeclare package Medium2 = Medium2,
    P_nominal=P_nominal,
    dTEva_nominal=dTEva_nominal,
    dTCon_nominal=dTCon_nominal,
    COP_nominal=COPc_nominal,
    use_eta_Carnot=true,
    etaCar=0.3,
    dp1_nominal=6000,
    dp2_nominal=6000,
    m1_flow_nominal=m1_flow_nominal,
    m2_flow_nominal=m2_flow_nominal) "Chiller model";
  Buildings.Fluid.Sources.MassFlowSource_T sou1(nPorts=1,
    redeclare package Medium = Medium1,
    use_T_in=true,
    m_flow=m1_flow_nominal,
    T=298.15);
  Buildings.Fluid.Sources.MassFlowSource_T sou2(nPorts=1,
    redeclare package Medium = Medium2,
    use_T_in=true,
    m_flow=m2_flow_nominal,
    T=291.15);
  Buildings.Fluid.Sources.FixedBoundary sin1(nPorts=1, redeclare package Medium
      = Medium1);
  Buildings.Fluid.Sources.FixedBoundary sin2(nPorts=1, redeclare package Medium
      = Medium2);
  Modelica.Blocks.Sources.Ramp uCom(
    height=-1,
    duration=60,
    offset=1,
    startTime=1800) "Compressor control signal";
  inner Modelica.Fluid.System system;
  Modelica.Blocks.Sources.Ramp TCon_in(
    height=10,
    duration=60,
    offset=273.15 + 20,
    startTime=60) "Condenser inlet temperature";
  Modelica.Blocks.Sources.Ramp TEva_in(
    height=10,
    duration=60,
    startTime=900,
    offset=273.15 + 15) "Evaporator inlet temperature";
equation 
  connect(sou1.ports[1], chi.port_a1);
  connect(sou2.ports[1], chi.port_a2);
  connect(chi.port_b1, sin1.ports[1]);
  connect(sin2.ports[1], chi.port_b2);
  connect(TCon_in.y, sou1.T_in);
  connect(TEva_in.y, sou2.T_in);
  connect(uCom.y, chi.y);
end Carnot;

Buildings.Fluid.Chillers.Examples.ElectricReformulatedEIR

Information

Parameters

Type	Name	Default	Description
Power	P_nominal	-per.QEva_flow_nominal/per.C...	Nominal compressor power (at y=1) [W]
TemperatureDifference	dTEva_nominal	10	Temperature difference evaporator inlet-outlet [K]
TemperatureDifference	dTCon_nominal	10	Temperature difference condenser outlet-inlet [K]
Real	COPc_nominal	3	Chiller COP
MassFlowRate	mEva_flow_nominal	per.mEva_flow_nominal	Nominal mass flow rate at evaporator [kg/s]
MassFlowRate	mCon_flow_nominal	per.mCon_flow_nominal	Nominal mass flow rate at condenser [kg/s]

Modelica definition

model ElectricReformulatedEIR 
  "Test model for chiller electric reformulated EIR"
  import Buildings;
  extends Buildings.Fluid.Chillers.Examples.BaseClasses.PartialElectric(
      redeclare Buildings.Fluid.Chillers.ElectricReformulatedEIR chi(per=per),
      redeclare Buildings.Fluid.Chillers.Data.ElectricReformulatedEIR.ReformEIRChiller_McQuay_WSC_471kW_5_89COP_Vanes
      per);
end ElectricReformulatedEIR;

Buildings.Fluid.Chillers.Examples.ElectricEIR

Information

Parameters

Type	Name	Default	Description
Power	P_nominal	-per.QEva_flow_nominal/per.C...	Nominal compressor power (at y=1) [W]
TemperatureDifference	dTEva_nominal	10	Temperature difference evaporator inlet-outlet [K]
TemperatureDifference	dTCon_nominal	10	Temperature difference condenser outlet-inlet [K]
Real	COPc_nominal	3	Chiller COP
MassFlowRate	mEva_flow_nominal	per.mEva_flow_nominal	Nominal mass flow rate at evaporator [kg/s]
MassFlowRate	mCon_flow_nominal	per.mCon_flow_nominal	Nominal mass flow rate at condenser [kg/s]

Modelica definition

model ElectricEIR "Test model for chiller electric EIR"
  import Buildings;
  extends Buildings.Fluid.Chillers.Examples.BaseClasses.PartialElectric(
      redeclare Buildings.Fluid.Chillers.ElectricEIR chi(per=per), redeclare Buildings.Fluid.Chillers.Data.ElectricEIR.ElectricEIRChiller_McQuay_WSC_471kW_5_89COP_Vanes
      per);
end ElectricEIR;