Modelica.Magnetic.FluxTubes.Shapes.FixedShape

Information

Please have a look at UsersGuide.ReluctanceForceCalculation for an explanation of the different flux tube categories and resulting sub-packages.

Due to the restrictions on reluctance force calculation outlined there, flux tube elements with a possibly non-linear material characteristic mu_r(B) must have a fixed shape during simulation of converter motion. Hence, the dimensions of these flux tubes are defined as parameters in the model components that extend the base class Interfaces.PartialFixedShape.

For initial design of magnetic circuits, the relative permeability of possibly non-linear flux tube elements can easily be set to a constant value mu_rConst (non-linearPermeability set to false). In some cases, this can simplify the rough geometric design of a device's magnetic circuit. Once an initial geometry is found, the magnetic subsystem can be simulated and fine-tuned with more realistic non-linear characteristics of ferromagnetic materials. Doing so requires setting of the parameter non-linearPermeability to true and selection of one of the soft magnetic materials of Material.SoftMagnetic.

Extends from Modelica.Icons.VariantsPackage (Icon for package containing variants).

Package Content

Name	Description
HollowCylinderAxialFlux	(Hollow) cylinder with axial flux; fixed shape; linear or non-linear material characteristics
HollowCylinderRadialFlux	Hollow cylinder with radial flux; fixed shape; linear or non-linear material characteristics
Cuboid	Flux tube with rectangular cross-section; fixed shape; linear or non-linear material characteristics

Modelica.Magnetic.FluxTubes.Shapes.FixedShape.HollowCylinderAxialFlux

Information

Please refer to the enclosing sub-package FixedShape for a description of all elements of this package and to [Ro41] for derivation and/or coefficients of the equation for permeance G_m.

Set the inner radius r_i=0 for modelling of a solid cylindric flux tube.

Extends from Modelica.Magnetic.FluxTubes.Interfaces.PartialFixedShape (Base class for flux tubes with fixed shape during simulation; linear or non-linear material characteristics).

Parameters

Type	Name	Default	Description
Material
Boolean	nonLinearPermeability	true	= true, if non-linear rel. permeability is used, otherwise constant rel. permeability
RelativePermeability	mu_rConst	1	Constant relative permeability; used if nonLinearPermeability = false [1]
BaseData	material	Modelica.Magnetic.FluxTubes....	Ferromagnetic material characteristics; used if nonLinearPermeability = true
Fixed geometry
Length	l		Axial length (in direction of flux) [m]
Radius	r_i		Inner radius of hollow cylinder (zero for cylinder) [m]
Radius	r_o		Outer radius of (hollow) cylinder [m]

Connectors

Type	Name	Description
PositiveMagneticPort	port_p	Positive magnetic port
NegativeMagneticPort	port_n	Negative magnetic port

Modelica definition

model HollowCylinderAxialFlux 
  "(Hollow) cylinder with axial flux; fixed shape; linear or non-linear material characteristics"

  extends Modelica.Magnetic.FluxTubes.Interfaces.PartialFixedShape;

  parameter SI.Length l( start = 0.01) "Axial length (in direction of flux)";
  parameter SI.Radius r_i( start = 0) 
    "Inner radius of hollow cylinder (zero for cylinder)";
  parameter SI.Radius r_o( start = 0.01) "Outer radius of (hollow) cylinder";

equation 
  A = pi*(r_o^2 - r_i^2);
  G_m = (mu_0 * mu_r * A)/ l;

end HollowCylinderAxialFlux;

Modelica.Magnetic.FluxTubes.Shapes.FixedShape.HollowCylinderRadialFlux

Information

Please refer to the enclosing sub-package FixedShape for a description of all elements of this package and to [Ro41] for derivation and/or coefficients of the equation for permeance G_m.

For hollow cylindric flux tubes with a radial magnetic flux, the flux density is a function of the radius. For that reason, the characteristic mu_r(B) is evaluated for the flux density at the flux tube's mean radius.

For those flux tube sections of a magnetic device that have a nonlinear material characteristic mu_r(B) and a large aspect ratio of outer to inner radius r_o/r_i, the section can be split up in a series connection of several hollow cylindric flux tubes with radial flux. This allows for more realistic modelling of the dependence of flux density on the radius compared to modelling with just one flux tube element.

Extends from Modelica.Magnetic.FluxTubes.Interfaces.PartialFixedShape (Base class for flux tubes with fixed shape during simulation; linear or non-linear material characteristics).

Parameters

Type	Name	Default	Description
Material
Boolean	nonLinearPermeability	true	= true, if non-linear rel. permeability is used, otherwise constant rel. permeability
RelativePermeability	mu_rConst	1	Constant relative permeability; used if nonLinearPermeability = false [1]
BaseData	material	Modelica.Magnetic.FluxTubes....	Ferromagnetic material characteristics; used if nonLinearPermeability = true
Fixed geometry
Length	l		Width (orthogonal to flux direction) [m]
Radius	r_i		Inner radius of hollow cylinder [m]
Radius	r_o		Outer radius of hollow cylinder [m]

Connectors

Type	Name	Description
PositiveMagneticPort	port_p	Positive magnetic port
NegativeMagneticPort	port_n	Negative magnetic port

Modelica definition

model HollowCylinderRadialFlux 
  "Hollow cylinder with radial flux; fixed shape; linear or non-linear material characteristics"

  extends Modelica.Magnetic.FluxTubes.Interfaces.PartialFixedShape;

  parameter SI.Length l( start = 0.01) "Width (orthogonal to flux direction)";
  parameter SI.Radius r_i( start = 0.01) "Inner radius of hollow cylinder";
  parameter SI.Radius r_o( start = 0.02) "Outer radius of hollow cylinder";

equation 
  A = l * pi*(r_o + r_i); // Area at arithmetic mean radius for calculation of average flux density
  G_m = 2* pi* mu_0* mu_r* l/ Modelica.Math.log(r_o/r_i);

end HollowCylinderRadialFlux;

Modelica.Magnetic.FluxTubes.Shapes.FixedShape.Cuboid

Information

Please refer to the enclosing sub-package FixedShape for a description of all elements of this package and to [Ro41] for derivation and/or coefficients of the equation for permeance G_m.

Extends from Modelica.Magnetic.FluxTubes.Interfaces.PartialFixedShape (Base class for flux tubes with fixed shape during simulation; linear or non-linear material characteristics).

Parameters

Type	Name	Default	Description
Material
Boolean	nonLinearPermeability	true	= true, if non-linear rel. permeability is used, otherwise constant rel. permeability
RelativePermeability	mu_rConst	1	Constant relative permeability; used if nonLinearPermeability = false [1]
BaseData	material	Modelica.Magnetic.FluxTubes....	Ferromagnetic material characteristics; used if nonLinearPermeability = true
Fixed geometry
Length	l	0.01	Length in direction of flux [m]
Length	a	0.01	Width of rectangular cross-section [m]
Length	b	0.01	Height of rectangular cross-section [m]

Connectors

Type	Name	Description
PositiveMagneticPort	port_p	Positive magnetic port
NegativeMagneticPort	port_n	Negative magnetic port

Modelica definition

model Cuboid 
  "Flux tube with rectangular cross-section; fixed shape; linear or non-linear material characteristics"

  extends Modelica.Magnetic.FluxTubes.Interfaces.PartialFixedShape;

  parameter SI.Length l = 0.01 "Length in direction of flux";
  parameter SI.Length a = 0.01 "Width of rectangular cross-section";
  parameter SI.Length b = 0.01 "Height of rectangular cross-section";

equation 
  A = a * b;
  G_m = (mu_0 * mu_r * A)/ l;

end Cuboid;