Modelica.Fluid.Pipes.BaseClasses.HeatTransfer

Information

Package Content

Name	Description
PartialFlowHeatTransfer	base class for any pipe heat transfer correlation
IdealFlowHeatTransfer	IdealHeatTransfer: Ideal heat transfer without thermal resistance
ConstantFlowHeatTransfer	ConstantHeatTransfer: Constant heat transfer coefficient
PartialPipeFlowHeatTransfer	Base class for pipe heat transfer correlation in terms of Nusselt number heat transfer in a circular pipe for laminar and turbulent one-phase flow
LocalPipeFlowHeatTransfer	LocalPipeFlowHeatTransfer: Laminar and turbulent forced convection in pipes, local coefficients

Modelica.Fluid.Pipes.BaseClasses.HeatTransfer.PartialFlowHeatTransfer

Information

The geometry is specified in the interface with the surfaceAreas[n], the roughnesses[n] and the lengths[n] along the flow path. Moreover the fluid flow is characterized for different types of devices by the characteristic dimensions[n+1] and the average velocities vs[n+1] of fluid flow. See Pipes.BaseClasses.CharacteristicNumbers.ReynoldsNumber for examplary definitions.

Extends from Modelica.Fluid.Interfaces.PartialHeatTransfer (Common interface for heat transfer models).

Parameters

Type	Name	Default	Description
Ambient
CoefficientOfHeatTransfer	k	0	Heat transfer coefficient to ambient [W/(m2.K)]
Temperature	T_ambient	system.T_ambient	Ambient temperature [K]
Internal Interface
replaceable package Medium		PartialMedium	Medium in the component
Integer	n	1	Number of heat transfer segments
Boolean	use_k	false	= true to use k value for thermal isolation
Geometry
Real	nParallel		number of identical parallel flow devices

Connectors

Type	Name	Description
HeatPorts_a	heatPorts[n]	Heat port to component boundary

Modelica definition

partial model PartialFlowHeatTransfer 
  "base class for any pipe heat transfer correlation"
  extends Modelica.Fluid.Interfaces.PartialHeatTransfer;

  // Additional inputs provided to flow heat transfer model
  input SI.Velocity[n] vs "Mean velocities of fluid flow in segments";

  // Geometry parameters and inputs for flow heat transfer
  parameter Real nParallel "number of identical parallel flow devices";
  input SI.Length[n] lengths "Lengths along flow path";
  input SI.Length[n] dimensions 
    "Characteristic dimensions for fluid flow (diameter for pipe flow)";
  input SI.Height[n] roughnesses "Average heights of surface asperities";

end PartialFlowHeatTransfer;

Modelica.Fluid.Pipes.BaseClasses.HeatTransfer.IdealFlowHeatTransfer

Information

Extends from PartialFlowHeatTransfer (base class for any pipe heat transfer correlation).

Parameters

Type	Name	Default	Description
Ambient
CoefficientOfHeatTransfer	k	0	Heat transfer coefficient to ambient [W/(m2.K)]
Temperature	T_ambient	system.T_ambient	Ambient temperature [K]
Internal Interface
replaceable package Medium		PartialMedium	Medium in the component
Integer	n	1	Number of heat transfer segments
Boolean	use_k	false	= true to use k value for thermal isolation
Geometry
Real	nParallel		number of identical parallel flow devices

Connectors

Type	Name	Description
HeatPorts_a	heatPorts[n]	Heat port to component boundary

Modelica definition

model IdealFlowHeatTransfer 
  "IdealHeatTransfer: Ideal heat transfer without thermal resistance"
  extends PartialFlowHeatTransfer;
equation 
  Ts = heatPorts.T;
end IdealFlowHeatTransfer;

Modelica.Fluid.Pipes.BaseClasses.HeatTransfer.ConstantFlowHeatTransfer

Information

Extends from PartialFlowHeatTransfer (base class for any pipe heat transfer correlation).

Parameters

Type	Name	Default	Description
CoefficientOfHeatTransfer	alpha0		heat transfer coefficient [W/(m2.K)]
Ambient
CoefficientOfHeatTransfer	k	0	Heat transfer coefficient to ambient [W/(m2.K)]
Temperature	T_ambient	system.T_ambient	Ambient temperature [K]
Internal Interface
replaceable package Medium		PartialMedium	Medium in the component
Integer	n	1	Number of heat transfer segments
Boolean	use_k	false	= true to use k value for thermal isolation
Geometry
Real	nParallel		number of identical parallel flow devices

Connectors

Type	Name	Description
HeatPorts_a	heatPorts[n]	Heat port to component boundary

Modelica definition

model ConstantFlowHeatTransfer 
  "ConstantHeatTransfer: Constant heat transfer coefficient"
  extends PartialFlowHeatTransfer;
  parameter SI.CoefficientOfHeatTransfer alpha0 "heat transfer coefficient";
equation 
  Q_flows = {alpha0*surfaceAreas[i]*(heatPorts[i].T - Ts[i])*nParallel for i in 1:n};
end ConstantFlowHeatTransfer;

Modelica.Fluid.Pipes.BaseClasses.HeatTransfer.PartialPipeFlowHeatTransfer

Information

Extends from PartialFlowHeatTransfer (base class for any pipe heat transfer correlation).

Parameters

Type	Name	Default	Description
CoefficientOfHeatTransfer	alpha0	100	guess value for heat transfer coefficients [W/(m2.K)]
Ambient
CoefficientOfHeatTransfer	k	0	Heat transfer coefficient to ambient [W/(m2.K)]
Temperature	T_ambient	system.T_ambient	Ambient temperature [K]
Internal Interface
replaceable package Medium		PartialMedium	Medium in the component
Integer	n	1	Number of heat transfer segments
Boolean	use_k	false	= true to use k value for thermal isolation
Geometry
Real	nParallel		number of identical parallel flow devices

Connectors

Type	Name	Description
HeatPorts_a	heatPorts[n]	Heat port to component boundary

Modelica definition

partial model PartialPipeFlowHeatTransfer 
  "Base class for pipe heat transfer correlation in terms of Nusselt number heat transfer in a circular pipe for laminar and turbulent one-phase flow"
  extends PartialFlowHeatTransfer;
  parameter SI.CoefficientOfHeatTransfer alpha0=100 
    "guess value for heat transfer coefficients";
  SI.CoefficientOfHeatTransfer[n] alphas(each start=alpha0) 
    "CoefficientOfHeatTransfer";
  Real[n] Res "Reynolds numbers";
  Real[n] Prs "Prandtl numbers";
  Real[n] Nus "Nusselt numbers";
  Medium.Density[n] ds "Densities";
  Medium.DynamicViscosity[n] mus "Dynamic viscosities";
  Medium.ThermalConductivity[n] lambdas "Thermal conductivity";
  SI.Length[n] diameters = dimensions "Hydraulic diameters for pipe flow";
equation 
  ds=Medium.density(states);
  mus=Medium.dynamicViscosity(states);
  lambdas=Medium.thermalConductivity(states);
  Prs = Medium.prandtlNumber(states);
  Res = CharacteristicNumbers.ReynoldsNumber(vs/nParallel, ds, mus, diameters);
  Nus = CharacteristicNumbers.NusseltNumber(alphas, diameters, lambdas);
  Q_flows={alphas[i]*surfaceAreas[i]*(heatPorts[i].T - Ts[i])*nParallel for i in 1:n};
end PartialPipeFlowHeatTransfer;

Modelica.Fluid.Pipes.BaseClasses.HeatTransfer.LocalPipeFlowHeatTransfer

Information

• fully developed pipe flow
• forced convection
• one phase Newtonian fluid
• (spatial) constant wall temperature in the laminar region
• 0 ≤ Re ≤ 1e6, 0.6 ≤ Pr ≤ 100, d/L ≤ 1
• The correlation holds for non-circular pipes only in the turbulent region. Use diameter=4*crossArea/perimeter as characteristic length.

References

Verein Deutscher Ingenieure (1997):

VDI Wärmeatlas. Springer Verlag, Ed. 8, 1997.

Extends from PartialPipeFlowHeatTransfer (Base class for pipe heat transfer correlation in terms of Nusselt number heat transfer in a circular pipe for laminar and turbulent one-phase flow).

Parameters

Type	Name	Default	Description
CoefficientOfHeatTransfer	alpha0	100	guess value for heat transfer coefficients [W/(m2.K)]
Ambient
CoefficientOfHeatTransfer	k	0	Heat transfer coefficient to ambient [W/(m2.K)]
Temperature	T_ambient	system.T_ambient	Ambient temperature [K]
Internal Interface
replaceable package Medium		PartialMedium	Medium in the component
Integer	n	1	Number of heat transfer segments
Boolean	use_k	false	= true to use k value for thermal isolation
Geometry
Real	nParallel		number of identical parallel flow devices

Connectors

Type	Name	Description
HeatPorts_a	heatPorts[n]	Heat port to component boundary

Modelica definition

model LocalPipeFlowHeatTransfer 
  "LocalPipeFlowHeatTransfer: Laminar and turbulent forced convection in pipes, local coefficients"
  extends PartialPipeFlowHeatTransfer;
protected 
  Real[n] Nus_turb "Nusselt number for turbulent flow";
  Real[n] Nus_lam "Nusselt number for laminar flow";
  Real Nu_1;
  Real[n] Nus_2;
  Real[n] Xis;
equation 
  Nu_1=3.66;
  for i in 1:n loop
   Nus_turb[i]=smooth(0,(Xis[i]/8)*abs(Res[i])*Prs[i]/(1+12.7*(Xis[i]/8)^0.5*(Prs[i]^(2/3)-1))*(1+1/3*(diameters[i]/lengths[i]/(if vs[i]>=0 then (i-0.5) else (n-i+0.5)))^(2/3)));
   Xis[i]=(1.8*Modelica.Math.log10(max(1e-10,Res[i]))-1.5)^(-2);
   Nus_lam[i]=(Nu_1^3+0.7^3+(Nus_2[i]-0.7)^3)^(1/3);
   Nus_2[i]=smooth(0,1.077*(abs(Res[i])*Prs[i]*diameters[i]/lengths[i]/(if vs[i]>=0 then (i-0.5) else (n-i+0.5)))^(1/3));
   Nus[i]=spliceFunction(Nus_turb[i], Nus_lam[i], Res[i]-6150, 3850);
  end for;
end LocalPipeFlowHeatTransfer;