Modelica.Electrical.Machines.BasicMachines.AsynchronousInductionMachines

Information

• AIM_SquirrelCage: asynchronous induction machine with squirrel cage
• AIM_SlipRing: asynchronous induction machine with wound rotor

Extends from Modelica.Icons.Library (Icon for library).

Package Content

Name	Description
AIM_SquirrelCage	Asynchronous induction machine with squirrel cage rotor
AIM_SlipRing	Asynchronous induction machine with slipring rotor

Modelica.Electrical.Machines.BasicMachines.AsynchronousInductionMachines.AIM_SquirrelCage

Information

Extends from Machines.Interfaces.PartialBasicInductionMachine (Partial model for induction machine).

Parameters

Type	Name	Default	Description
Inertia	Jr	Jr(start=0.29)	rotor's moment of inertia [kg.m2]
Boolean	useSupport	false	enable / disable (=fixed stator) support
Inertia	Js		stator's moment of inertia [kg.m2]
Integer	p		number of pole pairs (Integer)
Frequency	fsNominal		nominal frequency [Hz]
Current	idq_ss[2]	airGapS.i_ss	stator space phasor current / stator fixed frame [A]
Current	idq_sr[2]	airGapS.i_sr	stator space phasor current / rotor fixed frame [A]
Current	idq_rs[2]	airGapS.i_rs	rotor space phasor current / stator fixed frame [A]
Current	idq_rr[2]	airGapS.i_rr	rotor space phasor current / rotor fixed frame [A]
Nominal resistances and inductances
Resistance	Rs		warm stator resistance per phase [Ohm]
Inductance	Lssigma		stator stray inductance per phase [H]
Inductance	Lm		main field inductance [H]
Inductance	Lrsigma		rotor stray inductance (equivalent three phase winding) [H]
Resistance	Rr		warm rotor resistance (equivalent three phase winding) [Ohm]

Connectors

Type	Name	Description
Flange_a	flange
Flange_a	support	support at which the reaction torque is acting
PositivePlug	plug_sp
NegativePlug	plug_sn

Modelica definition

model AIM_SquirrelCage 
  "Asynchronous induction machine with squirrel cage rotor"
  extends Machines.Interfaces.PartialBasicInductionMachine(
    final idq_ss = airGapS.i_ss,
    final idq_sr = airGapS.i_sr,
    final idq_rs = airGapS.i_rs,
    final idq_rr = airGapS.i_rr);
  Components.AirGapS airGapS(            final p=p, final m=3, final Lm=Lm);
  parameter Modelica.SIunits.Inductance Lm(start=3*sqrt(1 - 0.0667)/(2*pi*fsNominal)) 
    "main field inductance";
  parameter Modelica.SIunits.Inductance Lrsigma(start=3*(1 - sqrt(1 - 0.0667))/(2*pi*fsNominal)) 
    "rotor stray inductance (equivalent three phase winding)";
  parameter Modelica.SIunits.Resistance Rr(start=0.04) 
    "warm rotor resistance (equivalent three phase winding)";
  Machines.BasicMachines.Components.SquirrelCage squirrelCageR(final Lrsigma=
                Lrsigma, final Rr=Rr);
equation 
  connect(airGapS.spacePhasor_r, squirrelCageR.spacePhasor_r);
  connect(spacePhasorS.spacePhasor, airGapS.spacePhasor_s);
  connect(airGapS.support, internalSupport);
  connect(airGapS.flange, inertiaRotor.flange_a);
end AIM_SquirrelCage;

Modelica.Electrical.Machines.BasicMachines.AsynchronousInductionMachines.AIM_SlipRing

Information

Parameter turnsRatio could be obtained from the following relationship at standstill with open rotor circuit at nominal voltage and nominal frequency,
using the locked-rotor voltage VR, no-load stator current I0 and powerfactor PF0:
turnsRatio * V_R = V_s - (R_s + j X_s,sigma) I₀

Extends from Machines.Interfaces.PartialBasicInductionMachine (Partial model for induction machine).

Parameters

Type	Name	Default	Description
Inertia	Jr	Jr(start=0.29)	rotor's moment of inertia [kg.m2]
Boolean	useSupport	false	enable / disable (=fixed stator) support
Inertia	Js		stator's moment of inertia [kg.m2]
Integer	p		number of pole pairs (Integer)
Frequency	fsNominal		nominal frequency [Hz]
Current	idq_ss[2]	airGapS.i_ss	stator space phasor current / stator fixed frame [A]
Current	idq_sr[2]	airGapS.i_sr	stator space phasor current / rotor fixed frame [A]
Current	idq_rs[2]	airGapS.i_rs	rotor space phasor current / stator fixed frame [A]
Current	idq_rr[2]	airGapS.i_rr	rotor space phasor current / rotor fixed frame [A]
Boolean	useTurnsRatio		use turnsRatio or calculate from locked-rotor voltage?
Real	turnsRatio		(ws*xis) / (wr*xir)
Voltage	VsNominal		nominal stator voltage per phase [V]
Voltage	VrLockedRotor		locked-rotor voltage per phase [V]
Nominal resistances and inductances
Resistance	Rs		warm stator resistance per phase [Ohm]
Inductance	Lssigma		stator stray inductance per phase [H]
Inductance	Lm		main field inductance [H]
Inductance	Lrsigma		rotor stray inductance per phase [H]
Resistance	Rr		warm rotor resistance per phase [Ohm]

Connectors

Type	Name	Description
Flange_a	flange
Flange_a	support	support at which the reaction torque is acting
PositivePlug	plug_sp
NegativePlug	plug_sn
PositivePlug	plug_rp
NegativePlug	plug_rn

Modelica definition

model AIM_SlipRing 
  "Asynchronous induction machine with slipring rotor"
  extends Machines.Interfaces.PartialBasicInductionMachine(
    final idq_ss = airGapS.i_ss,
    final idq_sr = airGapS.i_sr,
    final idq_rs = airGapS.i_rs,
    final idq_rr = airGapS.i_rr);
  Components.AirGapS airGapS(final p=p, final m=3, final Lm=Lm);
  parameter Modelica.SIunits.Inductance Lm(start=3*sqrt(1 - 0.0667)/(2*pi*fsNominal)) 
    "main field inductance";
  parameter Modelica.SIunits.Inductance Lrsigma(start=3*(1 - sqrt(1 - 0.0667))/(2*pi*fsNominal)) 
    "rotor stray inductance per phase";
  parameter Modelica.SIunits.Resistance Rr(start=0.04) 
    "warm rotor resistance per phase";
  parameter Boolean useTurnsRatio(start=true) 
    "use turnsRatio or calculate from locked-rotor voltage?";
  parameter Real turnsRatio(final min=Modelica.Constants.small, start=1) 
    "(ws*xis) / (wr*xir)";
  parameter Modelica.SIunits.Voltage VsNominal(start=100) 
    "nominal stator voltage per phase";
  parameter Modelica.SIunits.Voltage VrLockedRotor(start=100*(2*pi*fsNominal*Lm)/sqrt(Rs^2+(2*pi*fsNominal*(Lm+Lssigma))^2)) 
    "locked-rotor voltage per phase";
  output Modelica.SIunits.Current i_0_r(stateSelect=StateSelect.prefer) = spacePhasorR.zero.i 
    "rotor zero-sequence current";
  output Modelica.SIunits.Voltage vr[m] = plug_rp.pin.v - plug_rn.pin.v 
    "rotor instantaneous voltages";
  output Modelica.SIunits.Current ir[m] = plug_rp.pin.i 
    "rotor instantaneous currents";
protected 
  final parameter Real internalTurnsRatio=if useTurnsRatio then turnsRatio else 
    VsNominal/VrLockedRotor*(2*pi*fsNominal*Lm)/sqrt(Rs^2+(2*pi*fsNominal*(Lm+Lssigma))^2);
public 
  Machines.SpacePhasors.Components.SpacePhasor spacePhasorR(final turnsRatio=internalTurnsRatio);
  Modelica.Electrical.MultiPhase.Basic.Inductor lrsigma(final m=m, final L=fill(Lrsigma, m));
  Modelica.Electrical.MultiPhase.Basic.Resistor rr(
    final m=m,
    final R=fill(Rr, m),
    final T_ref=fill(293.15,m),
    final alpha=zeros(m),
    final useHeatPort=false,
    final T=rr.T_ref);
  Modelica.Electrical.MultiPhase.Interfaces.PositivePlug plug_rp(final m=m);
  Modelica.Electrical.MultiPhase.Interfaces.NegativePlug plug_rn(final m=m);
equation 
  connect(rr.plug_n, lrsigma.plug_p);
  connect(rr.plug_p, plug_rp);
  connect(spacePhasorR.ground, spacePhasorR.zero);

  connect(airGapS.spacePhasor_r, spacePhasorR.spacePhasor);
  connect(spacePhasorS.spacePhasor, airGapS.spacePhasor_s);
  connect(airGapS.support, internalSupport);

  connect(airGapS.flange, inertiaRotor.flange_a);
  connect(lrsigma.plug_n, spacePhasorR.plug_p);
  connect(spacePhasorR.plug_n, plug_rn);
end AIM_SlipRing;