Buildings.Obsolete.Air.Systems.SingleZone.VAV.Examples
Collection of models that illustrate model use and test models
Information
This package contains examples for the use of models that can be found in Buildings.Air.Systems.SingleZone.VAV.
Extends from Modelica.Icons.ExamplesPackage (Icon for packages containing runnable examples).
Package Content
| Name | Description |
|---|---|
 Guideline36
|
Variable air volume flow system with single themal zone and ASHRAE Guideline 36 sequence control |
 OptimalStart
|
Example models of the block OptimalStart |
Buildings.Obsolete.Air.Systems.SingleZone.VAV.Examples.Guideline36
Variable air volume flow system with single themal zone and ASHRAE Guideline 36 sequence control
Information
Implementation of Buildings.Air.Systems.SingleZone.VAV.Examples.BaseClasses.PartialOpenLoop with ASHRAE Guideline 36 control sequence.
Extends from Modelica.Icons.Example (Icon for runnable examples), Buildings.Air.Systems.SingleZone.VAV.Examples.BaseClasses.PartialOpenLoop (Partial model of a single zone variable air volume flow system and thermal zone).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Temperature | TSupChi_nominal | 279.15 | Design value for chiller leaving water temperature [K] |
Connectors
| Type | Name | Description |
|---|---|---|
| Bus | weaBus | Weather bus |
Modelica definition
model Guideline36
"Variable air volume flow system with single themal zone and ASHRAE Guideline 36 sequence control"
extends Modelica.Icons.Example;
extends Buildings.Air.Systems.SingleZone.VAV.Examples.BaseClasses.PartialOpenLoop
(hvac(QCoo_flow_nominal=-10000));
parameter Modelica.Units.SI.Temperature TSupChi_nominal=279.15
"Design value for chiller leaving water temperature";
Buildings.Obsolete.Controls.OBC.ASHRAE.G36_PR1.AHUs.SingleZone.VAV.Controller
con(
have_winSen=true,
TZonHeaOn=293.15,
TZonCooOff=303.15,
kCoo=4,
kCooCoi=1,
yHeaMax=0.2,
AFlo=48,
VOutMin_flow=0.0144,
VOutDes_flow=0.025,
yMin=0.1,
kHea=4,
kMod=4,
have_occSen=false,
TZonHeaOff=288.15,
TZonCooOn=298.15,
TSupSetMax=343.15,
TSupSetMin=286.15,
yDam_VOutMin_minSpe=0.2304,
yDam_VOutMin_maxSpe=0.02304,
yDam_VOutDes_minSpe=0.4,
yDam_VOutDes_maxSpe=0.04)
"VAV controller";
Buildings.Controls.OBC.CDL.Reals.Hysteresis hysChiPla(
uLow=-1,
uHigh=0)
"Hysteresis with delay to switch on cooling";
Modelica.Blocks.Math.Feedback errTRooCoo
"Control error on room temperature for cooling";
Buildings.Controls.SetPoints.OccupancySchedule occSch(occupancy=3600*{8,18})
"Occupancy schedule";
Modelica.Blocks.Sources.BooleanConstant uWin(k=false) "Window opening signal";
Buildings.Controls.OBC.CDL.Integers.Sources.Constant demLim(final k=0)
"Cooling and heating demand imit level";
Buildings.Controls.OBC.CDL.Reals.Sources.Constant cooWarTim(final k=0)
"Cooldown and warm-up time";
protected
Modelica.Blocks.Sources.Constant TSetSupChiConst(final k=TSupChi_nominal)
"Set point for chiller temperature";
equation
connect(con.yFan, hvac.uFan);
connect(con.yHeaCoi, hvac.uHea);
connect(con.yOutDamPos, hvac.uEco);
connect(TSetSupChiConst.y, hvac.TSetChi);
connect(errTRooCoo.y, hysChiPla.u);
connect(zon.TRooAir, errTRooCoo.u1);
connect(hysChiPla.y, hvac.chiOn);
connect(weaBus.TDryBul, con.TOut);
connect(zon.TRooAir, con.TZon);
connect(hvac.TSup, con.TSup);
connect(hvac.TMix, con.TMix);
connect(occSch.tNexOcc, con.tNexOcc);
connect(con.uOcc, occSch.occupied);
connect(uWin.y, con.uWin);
connect(con.TZonCooSet, errTRooCoo.u2);
connect(hvac.TRet, con.TCut);
connect(demLim.y, con.uCooDemLimLev);
connect(demLim.y, con.uHeaDemLimLev);
connect(cooWarTim.y, con.warUpTim);
connect(cooWarTim.y, con.cooDowTim);
connect(con.yCooCoi, hvac.uCooVal);
end Guideline36;