f90client.f90

Go to the documentation of this file.

program first
! Note: This program uses fixed array size. 
!       Variable array size (using ALLOCATE) do not work: The c
!       function only gets a value of 0 for all elements.
!       This is also the case if a fortran pointer is passed as an argument
!       instead of the array itself.

  IMPLICIT NONE

  ! These parameters are also declared in an interface below. 
  ! Change all together.
  INTEGER, PARAMETER :: ndblmax = 2      ! Maximum number of doubles

  interface 
     function establishclientsocket(fileName)
       CHARACTER(len=*) :: filename  ! file from which socket port number will be read
       INTEGER establishclientsocket ! socket file descriptor
     end function establishclientsocket
  end interface

  interface 
     function exchangedoubleswithsocket( socketFD, &
          flawri, flarea, &
          ndblwri, ndblrea, & 
          simtimwri, dblvalwri, &
          simtimrea, dblvalrea)
       ! These parameters are also declared in an interface below. 
       ! Change all together.
       INTEGER, PARAMETER :: ndblmax = 2      ! Maximum number of doubles

       INTEGER socketfd ! socket file descriptor

       INTEGER flawri   ! flag to write to the socket
       INTEGER flarea   ! flag read from the socket

       INTEGER ndblwri ! number of doubles to write to socket
       INTEGER ndblrea ! number of doubles to read from socket

       DOUBLE PRECISION simtimwri ! simulation time to write to socket
       ! if ':' instead of '2' is specified, then 1.7042624463E-313 is exchanged.
       DOUBLE PRECISION, DIMENSION(nDblMax) :: dblvalwri  

       DOUBLE PRECISION simtimrea  ! simulation time to read from socket
       DOUBLE PRECISION, DIMENSION(nDblMax) :: dblvalrea
       INTEGER exchangedoubleswithsocket
     end function exchangedoubleswithsocket
  end interface

  interface 
     function closesocket(socketFD)
       INTEGER socketfd ! socket file descriptor
       INTEGER closesocket
     end function closesocket
  end interface


!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! Declarations for room model
  INTEGER, PARAMETER :: nroo = 2      ! Number of rooms
  DOUBLE PRECISION :: tini      ! Initial room temperature
  DOUBLE PRECISION :: tau       ! Room time constant
  DOUBLE PRECISION :: q0hea     ! Nominal heating power
  DOUBLE PRECISION :: deltim    ! Time step
  DOUBLE PRECISION :: ua        ! UA value
  DOUBLE PRECISION :: tout      ! current outside temperature
  DOUBLE PRECISION :: simtimrea ! simulation time read from the socket
  DOUBLE PRECISION :: simtim    ! current simulation time


  DOUBLE PRECISION, DIMENSION(nRoo) :: c       ! Room heat capacity
  DOUBLE PRECISION, DIMENSION(nRoo) :: u       ! control signal
  DOUBLE PRECISION, DIMENSION(nRoo) :: troo    ! current room temperature



!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! Declarations for IPC
  CHARACTER(len=*), PARAMETER :: simcfgfilnam="socket.cfg"
  INTEGER portno
  INTEGER i
  INTEGER retval
  INTEGER socketfd
  INTEGER flawri, flarea
  INTEGER ndblwri
  INTEGER ndblrea
  DOUBLE PRECISION, DIMENSION(nDblMax) :: dblvalwri
  DOUBLE PRECISION, DIMENSION(nDblMax) :: dblvalrea

! Buffer for the command line argument
  CHARACTER *100 buffer  

! Get the command line argument
  IF ( iargc() .LT. 1 ) THEN
     WRITE(*,*) "Error: Wrong arguments in client"
     WRITE(*,*) "Usage: programName simulationTimeStepInSeconds"
     stop
  ENDIF
  
  CALL getarg(1,buffer)
  READ(buffer,*) deltim
  WRITE(*,'(A, G10.3)') "Simulator set time step to ", deltim
  
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! Initializations
  OPEN (unit=11,file='client.log', status='replace', action='write')

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! Declare how many variables are written and read
  ndblwri= nroo
  ndblrea= nroo
  flawri = 0
  flarea = 0

! Initialize room variables
  tini   = 10     
  tau    = 2*3600 
  q0hea  = 100    
  ua = q0hea / 20 
  c(1)  =   tau * ua   
  c(2)  = 2*tau * ua   

  troo = tini
  tout = 5
 
  simtim = 0
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! Do time stepping
  write(11,*) "*** Starting simulation"
! Open socket
  socketfd = establishclientsocket(simcfgfilnam)
!!stop 'manual exit'
  write(11, *) "Socket file descriptor = ", socketfd
  IF (socketfd .LT. 0) THEN
     write(*, *) "Error: Could not open socket."
     write(11, *) "Error: Could not open socket."
     close(11)
     stop
  END IF
 
  simulate:  DO 
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! Fill arrays for IPC

     DO i=1,nroo
        dblvalwri(i)=troo(i)
     END DO
     ! Exchange data   
     retval = exchangedoubleswithsocket(socketfd, &
          flawri, flarea, &
          ndblwri, ndblrea, &
          simtim,    dblvalwri, &
          simtimrea, dblvalrea)
     ! Check for errors, in which case we terminate the simulation loop
     IF (retval .NE. 0) THEN
        write(*, *) "Error: Received retVal = ", retval
        write(11,*) "Error: Received retVal = ", retval
        EXIT simulate
     END IF
     ! Check communication flag
     IF (flarea .NE. 0) THEN
        write(*, *) "Received end of simulation flag = ", flarea
        write(*, *) "Exit simulation."
        write(11,*) "Received end of simulation flag = ", flarea
        write(11,*) "Exit simulation."
        EXIT simulate
     END IF

     ! No errors found. Assign exchanged variables
     DO i=1,nroo
        u(i) = dblvalrea(i)
     END DO
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! Having obtained y_k, we compute the new state x_k+1 = f(u_k)
! This is the actual simulation time step of the client
     DO i=1,nroo
        troo(i) = troo(i) + &
             deltim/c(i) * ( ua * (tout-troo(i) ) + q0hea * u(i) )
     END DO
     simtim = simtim + deltim
  END DO simulate
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!  
  write(11,*) "*** Ending simulation"
  close(11)
  close(socketfd)
end program