Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx
600 series of ANSI/ASHRAE BESTEST
Information
This package contains the validation cases of the 600 series of the BESTEST validation (ANSI/ASHRAE 2007).
References
ANSI/ASHRAE. 2007. ANSI/ASHRAE Standard 140-2007, Standard Method of Test for the Evaluation of Building Energy Analysis Computer Programs.
Extends from Modelica.Icons.ExamplesPackage (Icon for packages containing runnable examples).
Package Content
| Name | Description |
|---|---|
 Case600
|
Case 600FF, but with dual-setpoint for heating and cooling |
| Case600FF
|
Basic test with light-weight construction and free floating temperature |
| Case610
|
Case 600 with south shading |
| Case620
|
Case 600, but with windows on East and West side walls |
| Case630
|
Case 620, but with added overhang and sidefins |
| Case640
|
Case 600, but with heating schedule |
| Case650
|
Case 600, but cooling based on schedule, night venting, and no heating |
| Case650FF
|
Case 600, no heating, no cooling, and ventilation as in case 650 |
| Case660
|
Case 600, but with low-emissivity windows with Argon gas |
| Case670
|
Case 600, but has single pane window with clear glass |
| Case680
|
Case 600, but with increased exterior wall and roof insulation |
| Case680FF
|
Case 600FF, but with increased exterior wall and roof insulation |
| Case685
|
Case 600, but with single setpoint for heating and cooling |
| Case695
|
Case 600, but with increased exterior wall and roof insulation and single cooling and heating setpoint |
Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case600
Case 600FF, but with dual-setpoint for heating and cooling
Information
This model is used for the basic test case 600 of the BESTEST validation suite. Case 600 is a light-weight building with room temperature control set to 20°C for heating and 27°C for cooling. The room has no shade and a window that faces south.
Extends from Case600FF (Basic test with light-weight construction and free floating temperature).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Angle | S_ | Buildings.Types.Azimuth.S | Azimuth for south walls [rad] |
| Angle | E_ | Buildings.Types.Azimuth.E | Azimuth for east walls [rad] |
| Angle | W_ | Buildings.Types.Azimuth.W | Azimuth for west walls [rad] |
| Angle | N_ | Buildings.Types.Azimuth.N | Azimuth for north walls [rad] |
| Angle | C_ | Buildings.Types.Tilt.Ceiling | Tilt for ceiling [rad] |
| Angle | F_ | Buildings.Types.Tilt.Floor | Tilt for floor [rad] |
| Angle | Z_ | Buildings.Types.Tilt.Wall | Tilt for wall [rad] |
| Integer | nConExtWin | 1 | Number of constructions with a window |
| Integer | nConBou | 1 | Number of surface that are connected to constructions that are modeled inside the room |
| Generic | matExtWal | Exterior wall | |
| Generic | matFlo | Floor | |
| Generic | roof | Roof | |
| Win600 | window600 | redeclare parameter Building... | Window |
| CriteriaLimits | heaCri | heaCri(lowerLimit=3.75*3.6e9... | Annual heating load limits of the test acceptance criteria from ASHRAE/ANSI Standard 140 |
| CriteriaLimits | cooCri | cooCri(lowerLimit=-5*3.6e9, ... | Annual cooling load limits of the test acceptance criteria from ASHRAE/ANSI Standard 140 |
| DaySchedule | TSetHea | TSetHea(table=[0.0, 273.15 +... | Heating setpoint |
| DaySchedule | TSetCoo | TSetCoo(table=[0.0, 273.15 +... | Cooling setpoint |
Connectors
| Type | Name | Description |
|---|---|---|
| Bus | weaBus | Weather data bus |
Modelica definition
model Case600 "Case 600FF, but with dual-setpoint for heating and cooling"
extends Case600FF(
redeclare Buildings.ThermalZones.Detailed.Validation.BESTEST.Data.StandardResults
staRes(
annualHea(
Min=3.993*3.6e9,
Max=4.504*3.6e9,
Mean=4.213*3.6e9),
annualCoo(
Min=-5.432*3.6e9,
Max=-6.162*3.6e9,
Mean=-5.856*3.6e9),
peakHea(Min=3.020*1000, Max=3.359*1000, Mean=3.184*1000),
peakCoo(Min=-5.422*1000, Max=-6.481*1000, Mean=-6.024*1000)));
replaceable parameter Buildings.ThermalZones.Detailed.Validation.BESTEST.Data.CriteriaLimits
heaCri(lowerLimit=3.75*3.6e9, upperLimit=4.98*3.6e9)
"Annual heating load limits of the test acceptance criteria from ASHRAE/ANSI Standard 140";
replaceable parameter Buildings.ThermalZones.Detailed.Validation.BESTEST.Data.CriteriaLimits
cooCri(lowerLimit=-5*3.6e9, upperLimit=-6.83*3.6e9)
"Annual cooling load limits of the test acceptance criteria from ASHRAE/ANSI Standard 140";
Buildings.Controls.OBC.CDL.Reals.PID conHea(
k=0.1,
Ti=300,
controllerType=Buildings.Controls.OBC.CDL.Types.SimpleController.PI)
"Controller for heating";
Buildings.Controls.OBC.CDL.Reals.PID conCoo(
k=0.1,
Ti=300,
reverseActing=false,
controllerType=Buildings.Controls.OBC.CDL.Types.SimpleController.PI)
"Controller for cooling";
Buildings.Controls.OBC.CDL.Reals.MultiplyByParameter gaiHea(k=1E6)
"Gain for heating";
Buildings.Controls.OBC.CDL.Reals.MultiplyByParameter gaiCoo(k=-1E6)
"Gain for cooling";
Modelica.Blocks.Math.Sum sumHeaCoo(nin=2)
"Sum of heating and cooling heat flow rate";
Modelica.Blocks.Routing.Multiplex2 multiplex2;
Modelica.Thermal.HeatTransfer.Sources.PrescribedHeatFlow preHea
"Prescribed heat flow for heating and cooling";
Modelica.Blocks.Continuous.Integrator EHea(
k=1,
initType=Modelica.Blocks.Types.Init.InitialState,
y_start=0,
u(unit="W"),
y(unit="J")) "Heating energy in Joules";
Modelica.Blocks.Continuous.Integrator ECoo(
k=1,
initType=Modelica.Blocks.Types.Init.InitialState,
y_start=0,
u(unit="W"),
y(unit="J")) "Cooling energy in Joules";
replaceable BaseClasses.DaySchedule TSetHea(table=[0.0,273.15 + 20])
"Heating setpoint";
replaceable BaseClasses.DaySchedule TSetCoo(table=[0.0,273.15 + 27])
"Cooling setpoint";
Buildings.Controls.OBC.CDL.Reals.MovingAverage PHea(delta=3600)
"Hourly averaged heating power";
Buildings.Controls.OBC.CDL.Reals.MovingAverage PCoo(delta=3600)
"Hourly averaged cooling power";
equation
connect(TRooAir.T,conHea. u_m);
connect(conCoo.u_m, TRooAir.T);
connect(conHea.y,gaiHea. u);
connect(conCoo.y,gaiCoo. u);
connect(gaiHea.y,multiplex2. u1[1]);
connect(gaiCoo.y,multiplex2. u2[1]);
connect(multiplex2.y, sumHeaCoo.u);
connect(sumHeaCoo.y, preHea.Q_flow);
connect(EHea.u,gaiHea. y);
connect(ECoo.u,gaiCoo. y);
connect(TSetHea.y[1],conHea. u_s);
connect(TSetCoo.y[1],conCoo. u_s);
connect(PCoo.u,gaiCoo. y);
connect(PHea.u,gaiHea. y);
connect(preHea.port, roo.heaPorAir);
end Case600;
Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case600FF
Basic test with light-weight construction and free floating temperature
Information
This model is used for the test case 600FF of the BESTEST validation suite. Case 600FF is a light-weight building. The room temperature is free floating.
Extends from Modelica.Icons.Example (Icon for runnable examples).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Angle | S_ | Buildings.Types.Azimuth.S | Azimuth for south walls [rad] |
| Angle | E_ | Buildings.Types.Azimuth.E | Azimuth for east walls [rad] |
| Angle | W_ | Buildings.Types.Azimuth.W | Azimuth for west walls [rad] |
| Angle | N_ | Buildings.Types.Azimuth.N | Azimuth for north walls [rad] |
| Angle | C_ | Buildings.Types.Tilt.Ceiling | Tilt for ceiling [rad] |
| Angle | F_ | Buildings.Types.Tilt.Floor | Tilt for floor [rad] |
| Angle | Z_ | Buildings.Types.Tilt.Wall | Tilt for wall [rad] |
| Integer | nConExtWin | 1 | Number of constructions with a window |
| Integer | nConBou | 1 | Number of surface that are connected to constructions that are modeled inside the room |
| Generic | matExtWal | matExtWal(nLay=3, absIR_a=0.... | Exterior wall |
| Generic | matFlo | matFlo(final nLay=2, absIR_a... | Floor |
| Generic | roof | roof(nLay=3, absIR_a=0.9, ab... | Roof |
| Win600 | window600 | window600(haveExteriorShade=... | Window |
| StandardResultsFreeFloating | staRes | staRes(minT(Min=-13.8 + 273.... | Reference results from ASHRAE/ANSI Standard 140 |
Connectors
| Type | Name | Description |
|---|---|---|
| Bus | weaBus | Weather data bus |
Modelica definition
model Case600FF
"Basic test with light-weight construction and free floating temperature"
extends Modelica.Icons.Example;
package MediumA = Buildings.Media.Air "Medium model";
parameter Modelica.Units.SI.Angle S_=Buildings.Types.Azimuth.S
"Azimuth for south walls";
parameter Modelica.Units.SI.Angle E_=Buildings.Types.Azimuth.E
"Azimuth for east walls";
parameter Modelica.Units.SI.Angle W_=Buildings.Types.Azimuth.W
"Azimuth for west walls";
parameter Modelica.Units.SI.Angle N_=Buildings.Types.Azimuth.N
"Azimuth for north walls";
parameter Modelica.Units.SI.Angle C_=Buildings.Types.Tilt.Ceiling
"Tilt for ceiling";
parameter Modelica.Units.SI.Angle F_=Buildings.Types.Tilt.Floor
"Tilt for floor";
parameter Modelica.Units.SI.Angle Z_=Buildings.Types.Tilt.Wall
"Tilt for wall";
parameter Integer nConExtWin = 1 "Number of constructions with a window";
parameter Integer nConBou = 1
"Number of surface that are connected to constructions that are modeled inside the room";
parameter Buildings.HeatTransfer.Data.OpaqueConstructions.Generic matExtWal(
nLay=3,
absIR_a=0.9,
absIR_b=0.9,
absSol_a=0.6,
absSol_b=0.6,
material={Buildings.HeatTransfer.Data.Solids.Generic(
x=0.009,
k=0.140,
c=900,
d=530,
nStaRef=nStaRef),Buildings.HeatTransfer.Data.Solids.Generic(
x=0.066,
k=0.040,
c=840,
d=12,
nStaRef=nStaRef),Buildings.HeatTransfer.Data.Solids.Generic(
x=0.012,
k=0.160,
c=840,
d=950,
nStaRef=nStaRef)},
roughness_a=Buildings.HeatTransfer.Types.SurfaceRoughness.Rough) "Exterior wall";
parameter Buildings.HeatTransfer.Data.OpaqueConstructions.Generic
matFlo(
final nLay=2,
absIR_a=0.9,
absIR_b=0.9,
absSol_a=0.6,
absSol_b=0.6,
material={Buildings.HeatTransfer.Data.Solids.Generic(
x=1.003,
k=0.040,
c=0,
d=0,
nStaRef=nStaRef),Buildings.HeatTransfer.Data.Solids.Generic(
x=0.025,
k=0.140,
c=1200,
d=650,
nStaRef=nStaRef)},
roughness_a=Buildings.HeatTransfer.Types.SurfaceRoughness.Rough)
"Floor";
Buildings.ThermalZones.Detailed.MixedAir roo(
redeclare package Medium = MediumA,
hRoo=2.7,
nConExtWin=nConExtWin,
nConBou=1,
linearizeRadiation=false,
nPorts=3,
energyDynamics=Modelica.Fluid.Types.Dynamics.FixedInitial,
AFlo=48,
datConBou(
layers={matFlo},
each A=48,
each til=F_),
datConExt(
layers={roof,matExtWal,matExtWal,matExtWal},
A={48,6*2.7,6*2.7,8*2.7},
til={C_,Z_,Z_,Z_},
azi={S_,W_,E_,N_}),
nConExt=4,
nConPar=0,
nSurBou=0,
datConExtWin(
layers={matExtWal},
A={8*2.7},
glaSys={window600},
wWin={2*3},
hWin={2},
fFra={1e-10},
til={Z_},
azi={S_})) "Room model";
Modelica.Blocks.Sources.Constant qConGai_flow(k=80/48) "Convective heat gain";
Modelica.Blocks.Sources.Constant qRadGai_flow(k=120/48) "Radiative heat gain";
Modelica.Blocks.Routing.Multiplex3 multiplex3_1
"Multiplex for internal gains";
Modelica.Blocks.Sources.Constant qLatGai_flow(k=0) "Latent heat gain";
Buildings.BoundaryConditions.WeatherData.ReaderTMY3 weaDat(filNam=
Modelica.Utilities.Files.loadResource("modelica://Buildings/Resources/weatherdata/USA_CO_Denver.Intl.AP.725650_TMY3.mos"),
computeWetBulbTemperature=false,
pAtmSou=Buildings.BoundaryConditions.Types.DataSource.File);
Modelica.Blocks.Sources.Constant uSha(k=0)
"Control signal for the shading device";
Modelica.Blocks.Routing.Replicator replicator(nout=max(1,nConExtWin));
parameter Buildings.HeatTransfer.Data.OpaqueConstructions.Generic roof(
nLay=3,
absIR_a=0.9,
absIR_b=0.9,
absSol_a=0.6,
absSol_b=0.6,
material={Buildings.HeatTransfer.Data.Solids.Generic(
x=0.019,
k=0.140,
c=900,
d=530,
nStaRef=nStaRef),Buildings.HeatTransfer.Data.Solids.Generic(
x=0.1118,
k=0.040,
c=840,
d=12,
nStaRef=nStaRef),Buildings.HeatTransfer.Data.Solids.Generic(
x=0.010,
k=0.160,
c=840,
d=950,
nStaRef=nStaRef)},
roughness_a=Buildings.HeatTransfer.Types.SurfaceRoughness.Rough) "Roof";
replaceable parameter Buildings.ThermalZones.Detailed.Validation.BESTEST.Data.Win600
window600(
haveExteriorShade=false,
haveInteriorShade=false) "Window";
Buildings.Fluid.Sources.MassFlowSource_T sinInf(
redeclare package Medium = MediumA,
use_m_flow_in=true,
nPorts=1) "Sink model for air infiltration";
Buildings.Fluid.Sources.Outside souInf(redeclare package Medium = MediumA,
nPorts=1) "Source model for air infiltration";
Modelica.Blocks.Sources.Constant InfiltrationRate(k=-48*2.7*0.414/3600)
"0.414 ACH adjusted for the altitude (0.5 at sea level)";
Modelica.Blocks.Math.Product product
"Product to compute infiltration mass flow rate";
Buildings.Fluid.Sensors.Density density(
redeclare package Medium = MediumA,
warnAboutOnePortConnection=false)
"Air density inside the building";
Buildings.BoundaryConditions.WeatherData.Bus weaBus
"Weather data bus";
Modelica.Thermal.HeatTransfer.Sensors.TemperatureSensor TRooAir
"Room air temperature";
replaceable parameter Buildings.ThermalZones.Detailed.Validation.BESTEST.Data.StandardResultsFreeFloating
staRes(
minT( Min=-13.8+273.15, Max=-9.9+273.15, Mean=-12.7+273.15),
maxT( Min=62.4+273.15, Max=68.4+273.15, Mean=64.6+273.15),
meanT(Min=24.3+273.15, Max=26.1+273.15, Mean=25.2+273.15))
constrainedby Modelica.Icons.Record
"Reference results from ASHRAE/ANSI Standard 140";
Modelica.Blocks.Math.MultiSum multiSum(nu=1)
"Multi sum for infiltration air flow rate";
Controls.OBC.CDL.Reals.MovingAverage TRooHou(
delta=3600,
y(final unit="K",
displayUnit="degC"))
"Hourly averaged room air temperature";
Controls.OBC.CDL.Reals.MovingAverage TRooAnn(
delta=86400*365,
y(final unit="K",
displayUnit="degC"))
"Annual averaged room air temperature";
HeatTransfer.Convection.Exterior conOpa(
A=48,
roughness=Buildings.HeatTransfer.Types.SurfaceRoughness.Rough,
final til=Buildings.Types.Tilt.Floor,
final azi=0,
conMod=Buildings.HeatTransfer.Types.ExteriorConvection.TemperatureWind)
"Convection model for opaque part of the wall";
Modelica.Blocks.Sources.Constant zerWin(k=0) "Zero wind speed";
Modelica.Blocks.Sources.Constant zerDir(k=0) "Zero wind direction";
Fluid.FixedResistances.PressureDrop res(
redeclare package Medium = MediumA,
m_flow_nominal=0.0147,
from_dp=true,
dp_nominal=5)
"Flow resistance to decouple pressure from weather file from room pressure";
protected
HeatTransfer.Sources.PrescribedTemperature TAirConExt
"Outside air temperature for exterior constructions";
equation
connect(qRadGai_flow.y,multiplex3_1. u1[1]);
connect(qLatGai_flow.y,multiplex3_1. u3[1]);
connect(multiplex3_1.y, roo.qGai_flow);
connect(roo.uSha, replicator.y);
connect(qConGai_flow.y, multiplex3_1.u2[1]);
connect(weaDat.weaBus, roo.weaBus);
connect(uSha.y, replicator.u);
connect(product.y, sinInf.m_flow_in);
connect(density.port, roo.ports[1]);
connect(weaDat.weaBus, weaBus);
connect(weaBus, souInf.weaBus);
connect(roo.heaPorAir, TRooAir.port);
connect(sinInf.ports[1], roo.ports[2]);
connect(multiSum.y, product.u1);
connect(InfiltrationRate.y, multiSum.u[1]);
connect(TRooAir.T, TRooHou.u);
connect(TRooAir.T, TRooAnn.u);
connect(conOpa.fluid, TAirConExt.port);
connect(weaBus.TDryBul, TAirConExt.T);
connect(conOpa.solid, roo.surf_conBou[1]);
connect(zerWin.y, conOpa.v);
connect(zerDir.y, conOpa.dir);
connect(density.d, product.u2);
connect(souInf.ports[1], res.port_a);
connect(res.port_b, roo.ports[3]);
end Case600FF;
Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case610
Case 600 with south shading
Information
This model is the case 610 of the BESTEST validation suite. Case 610 differs from case 600 in that the window has an overhang.
Implementation
Two overhangs have been added, one for each window, because each window only sees its own overhang.
Extends from Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case600 (Case 600FF, but with dual-setpoint for heating and cooling).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Angle | S_ | Buildings.Types.Azimuth.S | Azimuth for south walls [rad] |
| Angle | E_ | Buildings.Types.Azimuth.E | Azimuth for east walls [rad] |
| Angle | W_ | Buildings.Types.Azimuth.W | Azimuth for west walls [rad] |
| Angle | N_ | Buildings.Types.Azimuth.N | Azimuth for north walls [rad] |
| Angle | C_ | Buildings.Types.Tilt.Ceiling | Tilt for ceiling [rad] |
| Angle | F_ | Buildings.Types.Tilt.Floor | Tilt for floor [rad] |
| Angle | Z_ | Buildings.Types.Tilt.Wall | Tilt for wall [rad] |
| Integer | nConExtWin | 1 | Number of constructions with a window |
| Integer | nConBou | 1 | Number of surface that are connected to constructions that are modeled inside the room |
| Generic | matExtWal | Exterior wall | |
| Generic | matFlo | Floor | |
| Generic | roof | Roof | |
| Win600 | window600 | redeclare parameter Building... | Window |
| DaySchedule | TSetHea | redeclare BaseClasses.DaySch... | Heating setpoint |
| DaySchedule | TSetCoo | redeclare BaseClasses.DaySch... | Cooling setpoint |
Connectors
| Type | Name | Description |
|---|---|---|
| Bus | weaBus | Weather data bus |
Modelica definition
model Case610 "Case 600 with south shading"
extends Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case600(
roo(
datConExtWin(
ove(
wR={0.5},
wL={0.5},
dep={1},
gap={0.5}))),
staRes(
annualHea(Min=4.066*3.6e9, Max=4.592*3.6e9, Mean=4.311*3.6e9),
annualCoo(Min=-4.117*3.6e9, Max=-4.382*3.6e9, Mean=-4.256*3.6e9),
peakHea(Min=3.021*1000, Max=3.360*1000, Mean=3.168*1000),
peakCoo(Min=-5.331*1000, Max=-6.432*1000, Mean=-5.861*1000)),
heaCri(lowerLimit=3.61*3.6e9, upperLimit=5.27*3.6e9),
cooCri(lowerLimit=-2.74*3.6e9, upperLimit=-6.03*3.6e9));
end Case610;
Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case620
Case 600, but with windows on East and West side walls
Information
This model is the case 620 of the BESTEST validation suite. Case 620 differs from case 600 in that the west and east facing walls have a window, but there is no window in the south facing wall.
Extends from Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case600 (Case 600FF, but with dual-setpoint for heating and cooling).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Angle | S_ | Buildings.Types.Azimuth.S | Azimuth for south walls [rad] |
| Angle | E_ | Buildings.Types.Azimuth.E | Azimuth for east walls [rad] |
| Angle | W_ | Buildings.Types.Azimuth.W | Azimuth for west walls [rad] |
| Angle | N_ | Buildings.Types.Azimuth.N | Azimuth for north walls [rad] |
| Angle | C_ | Buildings.Types.Tilt.Ceiling | Tilt for ceiling [rad] |
| Angle | F_ | Buildings.Types.Tilt.Floor | Tilt for floor [rad] |
| Angle | Z_ | Buildings.Types.Tilt.Wall | Tilt for wall [rad] |
| Integer | nConExtWin | 1 | Number of constructions with a window |
| Integer | nConBou | 1 | Number of surface that are connected to constructions that are modeled inside the room |
| Generic | matExtWal | Exterior wall | |
| Generic | matFlo | Floor | |
| Generic | roof | Roof | |
| Win600 | window600 | redeclare parameter Building... | Window |
| DaySchedule | TSetHea | redeclare BaseClasses.DaySch... | Heating setpoint |
| DaySchedule | TSetCoo | redeclare BaseClasses.DaySch... | Cooling setpoint |
Connectors
| Type | Name | Description |
|---|---|---|
| Bus | weaBus | Weather data bus |
Modelica definition
model Case620 "Case 600, but with windows on East and West side walls"
extends Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case600(
roo(
nConExtWin=2,
datConExtWin(
layers={matExtWal, matExtWal},
each A=6*2.7,
glaSys={window600, window600},
each wWin=3,
each hWin=2,
each fFra=0.001,
each til=Z_,
azi={W_,E_}),
nConExt=3,
datConExt(
layers={roof,matExtWal,matExtWal},
A={48,8*2.7,8*2.7},
til={C_,Z_,Z_},
azi={S_,S_,N_})),
staRes(
annualHea(Min=4.094*3.6e9, Max=4.719*3.6e9, Mean=4.413*3.6e9),
annualCoo(Min=-3.841*3.6e9, Max=-4.404*3.6e9, Mean=-4.090*3.6e9),
peakHea(Min=3.038*1000, Max=3.385*1000, Mean=3.186*1000),
peakCoo(Min=-3.955*1000, Max=-4.797*1000, Mean=-4.527*1000)),
heaCri(lowerLimit=3.67*3.6e9, upperLimit=5.38*3.6e9),
cooCri(lowerLimit=-2.76*3.6e9, upperLimit=-5.19*3.6e9));
end Case620;
Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case630
Case 620, but with added overhang and sidefins
Information
This model is case 630 of the BESTEST validation suite. Case 630 differs from case 620 in that the windows on the west and east walls have an overhang and side fins.
Extends from Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case620 (Case 600, but with windows on East and West side walls).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Angle | S_ | Buildings.Types.Azimuth.S | Azimuth for south walls [rad] |
| Angle | E_ | Buildings.Types.Azimuth.E | Azimuth for east walls [rad] |
| Angle | W_ | Buildings.Types.Azimuth.W | Azimuth for west walls [rad] |
| Angle | N_ | Buildings.Types.Azimuth.N | Azimuth for north walls [rad] |
| Angle | C_ | Buildings.Types.Tilt.Ceiling | Tilt for ceiling [rad] |
| Angle | F_ | Buildings.Types.Tilt.Floor | Tilt for floor [rad] |
| Angle | Z_ | Buildings.Types.Tilt.Wall | Tilt for wall [rad] |
| Integer | nConExtWin | 1 | Number of constructions with a window |
| Integer | nConBou | 1 | Number of surface that are connected to constructions that are modeled inside the room |
| Generic | matExtWal | Exterior wall | |
| Generic | matFlo | Floor | |
| Generic | roof | Roof | |
| Win600 | window600 | redeclare parameter Building... | Window |
| DaySchedule | TSetHea | redeclare BaseClasses.DaySch... | Heating setpoint |
| DaySchedule | TSetCoo | redeclare BaseClasses.DaySch... | Cooling setpoint |
Connectors
| Type | Name | Description |
|---|---|---|
| Bus | weaBus | Weather data bus |
Modelica definition
model Case630 "Case 620, but with added overhang and sidefins"
extends Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case620(
roo(
datConExtWin(
ove(
each wR=0.0,
each wL=0.0,
each dep=1.0,
each gap=0.5),
sidFin(
each h=0.5,
each dep=1.0,
each gap=0.0))),
staRes(
annualHea(Min=4.356*3.6e9, Max=5.139*3.6e9, Mean=4.821*3.6e9),
annualCoo(Min=-2.573*3.6e9, Max=-3.074*3.6e9, Mean=-2.814*3.6e9),
peakHea(Min=3.039*1000, Max=3.388*1000, Mean=3.203*1000),
peakCoo(Min=-3.526*1000, Max=-4.212*1000, Mean=-3.963*1000)),
heaCri(lowerLimit=3.69*3.6e9, upperLimit=6.12*3.6e9),
cooCri(lowerLimit=-1.08*3.6e9, upperLimit=-4.42*3.6e9));
end Case630;
Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case640
Case 600, but with heating schedule
Information
This model is used for the basic test case 640 of the BESTEST validation suite. Case640 is the same as Case600, but with the following modifications:
- From 2300 hours to 0700 hours, heat = on if zone temperature is below 10°C
- From 0700 hours to 0800 hours, the thermostat set point shall vary linearly with time from 10 °C to 20 °C. If the zone temperature is less than the thermostat set point for a subhourly time step, heat shall be added to the zone such that the zone temperature at the end of each subhourly time step shall correspond to the thermostat set point that occurs at the end of each subhourly time step.
- From 0800 hours to 2300 hours, heat = on if zone temperature is below 20°C
- All hours, cool = on if zone temperature above 27°C
- Otherwise, mechanical equipment is off.
Extends from Case600 (Case 600FF, but with dual-setpoint for heating and cooling).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Angle | S_ | Buildings.Types.Azimuth.S | Azimuth for south walls [rad] |
| Angle | E_ | Buildings.Types.Azimuth.E | Azimuth for east walls [rad] |
| Angle | W_ | Buildings.Types.Azimuth.W | Azimuth for west walls [rad] |
| Angle | N_ | Buildings.Types.Azimuth.N | Azimuth for north walls [rad] |
| Angle | C_ | Buildings.Types.Tilt.Ceiling | Tilt for ceiling [rad] |
| Angle | F_ | Buildings.Types.Tilt.Floor | Tilt for floor [rad] |
| Angle | Z_ | Buildings.Types.Tilt.Wall | Tilt for wall [rad] |
| Integer | nConExtWin | 1 | Number of constructions with a window |
| Integer | nConBou | 1 | Number of surface that are connected to constructions that are modeled inside the room |
| Generic | matExtWal | Exterior wall | |
| Generic | matFlo | Floor | |
| Generic | roof | Roof | |
| Win600 | window600 | redeclare parameter Building... | Window |
| DaySchedule | TSetCoo | redeclare BaseClasses.DaySch... | Cooling setpoint |
Connectors
| Type | Name | Description |
|---|---|---|
| Bus | weaBus | Weather data bus |
Modelica definition
model Case640 "Case 600, but with heating schedule"
extends Case600(
TSetHea(table=[ 0, 273.15 + 10;
7*3600, 273.15 + 10;
8*3600, 273.15 + 20;
23*3600, 273.15 + 20;
23*3600,273.15 + 10;
24*3600,273.15 + 10]),
staRes(
annualHea(Min=2.403*3.6e9, Max=2.682*3.6e9, Mean=2.612*3.6e9),
annualCoo(Min=-5.237*3.6e9, Max=-5.893*3.6e9, Mean=-5.636*3.6e9),
peakHea(Min = 4.039*1000, Max = 4.658*1000, Mean = 4.369 * 1000),
peakCoo(Min= -5.365*1000, Max = -6.429*1000, Mean= -5.973 * 1000)),
heaCri(lowerLimit=1.58*3.6e9, upperLimit=3.76*3.6e9),
cooCri(lowerLimit=-4.44*3.6e9, upperLimit=-6.86*3.6e9));
end Case640;
Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case650
Case 600, but cooling based on schedule, night venting, and no heating
Information
This model is used for the test case 650 of the BESTEST validation suite. Case650 is the same as Case600, but with the following modifications:
- From 1800 hours to 0700 hours, vent fan = on
- From 0700 hours to 1800 hours, vent fan = off
- Heating is always off
- From 0700 hours to 1800 hours, cooling is on if zone temperature > 27°C, otherwise cool = off.
- From 1800 hours to 0700 hours, cooling is always off.
- Ventilation fan capacity is 1700 standard m3/h (in addition to specified infiltration rate). After adjustment for the altitude, the capacity is 1409 m3/h.
- No waste heat from fan.
Extends from Case600 (Case 600FF, but with dual-setpoint for heating and cooling).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Angle | S_ | Buildings.Types.Azimuth.S | Azimuth for south walls [rad] |
| Angle | E_ | Buildings.Types.Azimuth.E | Azimuth for east walls [rad] |
| Angle | W_ | Buildings.Types.Azimuth.W | Azimuth for west walls [rad] |
| Angle | N_ | Buildings.Types.Azimuth.N | Azimuth for north walls [rad] |
| Angle | C_ | Buildings.Types.Tilt.Ceiling | Tilt for ceiling [rad] |
| Angle | F_ | Buildings.Types.Tilt.Floor | Tilt for floor [rad] |
| Angle | Z_ | Buildings.Types.Tilt.Wall | Tilt for wall [rad] |
| Integer | nConExtWin | 1 | Number of constructions with a window |
| Integer | nConBou | 1 | Number of surface that are connected to constructions that are modeled inside the room |
| Generic | matExtWal | Exterior wall | |
| Generic | matFlo | Floor | |
| Generic | roof | Roof | |
| Win600 | window600 | redeclare parameter Building... | Window |
Connectors
| Type | Name | Description |
|---|---|---|
| Bus | weaBus | Weather data bus |
Modelica definition
model Case650
"Case 600, but cooling based on schedule, night venting, and no heating"
extends Case600(
TSetHea(table=[0, 273.15 -200]),
TSetCoo(table=[ 0, 273.15+100;
7*3600, 273.15+100;
7*3600, 273.15+27;
18*3600, 273.15+27;
18*3600, 273.15+100;
24*3600, 273.15+100]),
staRes(
annualHea(Min=0*3.6e9, Max=0*3.6e9, Mean=0*3.6e9),
annualCoo(Min=-4.186*3.6e9, Max=-4.945*3.6e9, Mean=-4.644*3.6e9),
peakHea(Min = 0*1000, Max = 0*1000, Mean = 0 * 1000),
peakCoo(Min= -5.045*1000, Max = -6.290*1000, Mean= -5.813*1000)),
gaiHea(k=0),
multiSum(nu=2),
heaCri(lowerLimit=0*3.6e9, upperLimit=0*3.6e9),
cooCri(lowerLimit=-3.46*3.6e9, upperLimit=-5.88*3.6e9));
BaseClasses.DaySchedule vent(table=[ 0, -1409/3600;
7*3600, -1409/3600;
7*3600, 0;
18*3600, 0;
18*3600, -1409/3600;
24*3600, -1409/3600])
"Ventilation air flow rate";
equation
connect(multiSum.u[2], vent.y[1]);
end Case650;
Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case650FF
Case 600, no heating, no cooling, and ventilation as in case 650
Information
This model is used for the test case 650FF of the BESTEST validation suite. Case 650FF is identical to case 650, except that there is no heating and no cooling.
Extends from Case600FF (Basic test with light-weight construction and free floating temperature).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Angle | S_ | Buildings.Types.Azimuth.S | Azimuth for south walls [rad] |
| Angle | E_ | Buildings.Types.Azimuth.E | Azimuth for east walls [rad] |
| Angle | W_ | Buildings.Types.Azimuth.W | Azimuth for west walls [rad] |
| Angle | N_ | Buildings.Types.Azimuth.N | Azimuth for north walls [rad] |
| Angle | C_ | Buildings.Types.Tilt.Ceiling | Tilt for ceiling [rad] |
| Angle | F_ | Buildings.Types.Tilt.Floor | Tilt for floor [rad] |
| Angle | Z_ | Buildings.Types.Tilt.Wall | Tilt for wall [rad] |
| Integer | nConExtWin | 1 | Number of constructions with a window |
| Integer | nConBou | 1 | Number of surface that are connected to constructions that are modeled inside the room |
| Generic | matExtWal | Exterior wall | |
| Generic | matFlo | Floor | |
| Generic | roof | Roof | |
| Win600 | window600 | redeclare parameter Building... | Window |
Connectors
| Type | Name | Description |
|---|---|---|
| Bus | weaBus | Weather data bus |
Modelica definition
model Case650FF
"Case 600, no heating, no cooling, and ventilation as in case 650"
extends Case600FF(
redeclare Buildings.ThermalZones.Detailed.Validation.BESTEST.Data.StandardResultsFreeFloating
staRes(
minT( Min=-17.8+273.15, Max=-16.7+273.15, Mean=-17.3+273.15),
maxT( Min=61.1+273.15, Max=66.8+273.15, Mean=63.1+273.15),
meanT(Min=17.6+273.15, Max=18.9+273.15, Mean=18.3+273.15)),
multiSum(nu=2));
BaseClasses.DaySchedule vent(table=[ 0, -1409/3600;
7*3600, -1409/3600;
7*3600, 0;
18*3600, 0;
18*3600, -1409/3600;
24*3600, -1409/3600])
"Ventilation air flow rate";
equation
connect(multiSum.u[2],vent.y[1]);
end Case650FF;
Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case660
Case 600, but with low-emissivity windows with Argon gas
Information
This model is the case 660 of the BESTEST validation suite. Case 660 differs from case 600 in that it has low-emissivity windwos with Argon gas.
Extends from Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case600 (Case 600FF, but with dual-setpoint for heating and cooling).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Angle | S_ | Buildings.Types.Azimuth.S | Azimuth for south walls [rad] |
| Angle | E_ | Buildings.Types.Azimuth.E | Azimuth for east walls [rad] |
| Angle | W_ | Buildings.Types.Azimuth.W | Azimuth for west walls [rad] |
| Angle | N_ | Buildings.Types.Azimuth.N | Azimuth for north walls [rad] |
| Angle | C_ | Buildings.Types.Tilt.Ceiling | Tilt for ceiling [rad] |
| Angle | F_ | Buildings.Types.Tilt.Floor | Tilt for floor [rad] |
| Angle | Z_ | Buildings.Types.Tilt.Wall | Tilt for wall [rad] |
| Integer | nConExtWin | 1 | Number of constructions with a window |
| Integer | nConBou | 1 | Number of surface that are connected to constructions that are modeled inside the room |
| Generic | matExtWal | Exterior wall | |
| Generic | matFlo | Floor | |
| Generic | roof | Roof | |
| DaySchedule | TSetHea | redeclare BaseClasses.DaySch... | Heating setpoint |
| DaySchedule | TSetCoo | redeclare BaseClasses.DaySch... | Cooling setpoint |
Connectors
| Type | Name | Description |
|---|---|---|
| Bus | weaBus | Weather data bus |
Modelica definition
model Case660
"Case 600, but with low-emissivity windows with Argon gas"
extends Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case600(
redeclare Buildings.ThermalZones.Detailed.Validation.BESTEST.Data.Win660 window600(
UFra=3,
haveExteriorShade=false,
haveInteriorShade=false),
staRes(
annualHea(Min=3.574*3.6e9, Max=3.821*3.6e9, Mean=3.713*3.6e9),
annualCoo(Min=-2.966*3.6e9, Max=-3.340*3.6e9, Mean=-3.172*3.6e9),
peakHea(Min=2.620*1000, Max=2.955*1000, Mean=2.801*1000),
peakCoo(Min=-3.343*1000, Max=-3.933*1000, Mean=-3.565*1000)),
heaCri(lowerLimit=4.68*3.6e9, upperLimit=4.82*3.6e9),
cooCri(lowerLimit=-1.91*3.6e9, upperLimit=-4.33*3.6e9));
end Case660;
Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case670
Case 600, but has single pane window with clear glass
Information
This model is the case 670 of the BESTEST validation suite. Case 670 differs from case 600 in that it has single pane window with clear glass.
Extends from Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case600 (Case 600FF, but with dual-setpoint for heating and cooling).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Angle | S_ | Buildings.Types.Azimuth.S | Azimuth for south walls [rad] |
| Angle | E_ | Buildings.Types.Azimuth.E | Azimuth for east walls [rad] |
| Angle | W_ | Buildings.Types.Azimuth.W | Azimuth for west walls [rad] |
| Angle | N_ | Buildings.Types.Azimuth.N | Azimuth for north walls [rad] |
| Angle | C_ | Buildings.Types.Tilt.Ceiling | Tilt for ceiling [rad] |
| Angle | F_ | Buildings.Types.Tilt.Floor | Tilt for floor [rad] |
| Angle | Z_ | Buildings.Types.Tilt.Wall | Tilt for wall [rad] |
| Integer | nConExtWin | 1 | Number of constructions with a window |
| Integer | nConBou | 1 | Number of surface that are connected to constructions that are modeled inside the room |
| Generic | matExtWal | Exterior wall | |
| Generic | matFlo | Floor | |
| Generic | roof | Roof | |
| DaySchedule | TSetHea | redeclare BaseClasses.DaySch... | Heating setpoint |
| DaySchedule | TSetCoo | redeclare BaseClasses.DaySch... | Cooling setpoint |
Connectors
| Type | Name | Description |
|---|---|---|
| Bus | weaBus | Weather data bus |
Modelica definition
model Case670 "Case 600, but has single pane window with clear glass"
extends Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case600(
redeclare Buildings.ThermalZones.Detailed.Validation.BESTEST.Data.Win670 window600(
UFra=3,
haveExteriorShade=false,
haveInteriorShade=false),
staRes(
annualHea(Min=5.300*3.6e9, Max=6.140*3.6e9, Mean=5.681*3.6e9),
annualCoo(Min=-5.954*3.6e9, Max=-6.623*3.6e9, Mean=-6.402*3.6e9),
peakHea(Min=3.655*1000, Max=4.221*1000, Mean=3.943*1000),
peakCoo(Min=-5.839*1000, Max=-6.925*1000, Mean=-6.445*1000)),
heaCri(lowerLimit=4*3.6e9, upperLimit=7.96*3.6e9),
cooCri(lowerLimit=-5.05*3.6e9, upperLimit=-7.67*3.6e9));
end Case670;
Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case680
Case 600, but with increased exterior wall and roof insulation
Information
This model is the case 680 of the BESTEST validation suite. Case 680 differs from case 600 in that it has increased exterior wall and roof insulation.
Extends from Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case600 (Case 600FF, but with dual-setpoint for heating and cooling).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Angle | S_ | Buildings.Types.Azimuth.S | Azimuth for south walls [rad] |
| Angle | E_ | Buildings.Types.Azimuth.E | Azimuth for east walls [rad] |
| Angle | W_ | Buildings.Types.Azimuth.W | Azimuth for west walls [rad] |
| Angle | N_ | Buildings.Types.Azimuth.N | Azimuth for north walls [rad] |
| Angle | C_ | Buildings.Types.Tilt.Ceiling | Tilt for ceiling [rad] |
| Angle | F_ | Buildings.Types.Tilt.Floor | Tilt for floor [rad] |
| Angle | Z_ | Buildings.Types.Tilt.Wall | Tilt for wall [rad] |
| Integer | nConExtWin | 1 | Number of constructions with a window |
| Integer | nConBou | 1 | Number of surface that are connected to constructions that are modeled inside the room |
| Generic | matExtWal | extWalCase680 | Exterior wall |
| Generic | matFlo | Floor | |
| Generic | roof | roofCase680 | Roof |
| Win600 | window600 | redeclare parameter Building... | Window |
| DaySchedule | TSetHea | redeclare BaseClasses.DaySch... | Heating setpoint |
| DaySchedule | TSetCoo | redeclare BaseClasses.DaySch... | Cooling setpoint |
| ExteriorWallCase680 | extWalCase680 | Exterior wall | |
| RoofCase680 | roofCase680 | Roof |
Connectors
| Type | Name | Description |
|---|---|---|
| Bus | weaBus | Weather data bus |
Modelica definition
model Case680
"Case 600, but with increased exterior wall and roof insulation"
extends Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case600(
matExtWal = extWalCase680,
roof = roofCase680,
staRes(
annualHea(Min=1.732*3.6e9, Max=2.286*3.6e9, Mean=2.056*3.6e9),
annualCoo(Min=-5.932*3.6e9, Max=-6.529*3.6e9, Mean=-6.264*3.6e9),
peakHea(Min=1.778*1000, Max=2.126*1000, Mean=1.984*1000),
peakCoo(Min=-5.761*1000, Max=-7.051*1000, Mean=-6.446*1000)),
heaCri(lowerLimit=1.21*3.6e9, upperLimit=3.08*3.6e9),
cooCri(lowerLimit=-5.13*3.6e9, upperLimit=-7.7*3.6e9));
parameter Buildings.ThermalZones.Detailed.Validation.BESTEST.Data.ExteriorWallCase680
extWalCase680
"Exterior wall";
parameter Buildings.ThermalZones.Detailed.Validation.BESTEST.Data.RoofCase680
roofCase680
"Roof";
end Case680;
Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case680FF
Case 600FF, but with increased exterior wall and roof insulation
Information
This model is used for the test case 680FF of the BESTEST validation suite. Case 680FF is a light-weight building with increased exterior wall and roof insulation. The room temperature is free floating.
Extends from Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case600FF (Basic test with light-weight construction and free floating temperature).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Angle | S_ | Buildings.Types.Azimuth.S | Azimuth for south walls [rad] |
| Angle | E_ | Buildings.Types.Azimuth.E | Azimuth for east walls [rad] |
| Angle | W_ | Buildings.Types.Azimuth.W | Azimuth for west walls [rad] |
| Angle | N_ | Buildings.Types.Azimuth.N | Azimuth for north walls [rad] |
| Angle | C_ | Buildings.Types.Tilt.Ceiling | Tilt for ceiling [rad] |
| Angle | F_ | Buildings.Types.Tilt.Floor | Tilt for floor [rad] |
| Angle | Z_ | Buildings.Types.Tilt.Wall | Tilt for wall [rad] |
| Integer | nConExtWin | 1 | Number of constructions with a window |
| Integer | nConBou | 1 | Number of surface that are connected to constructions that are modeled inside the room |
| Generic | matExtWal | extWalCase680 | Exterior wall |
| Generic | matFlo | Floor | |
| Generic | roof | roofCase680 | Roof |
| Win600 | window600 | redeclare parameter Building... | Window |
| ExteriorWallCase680 | extWalCase680 | extWalCase680(roughness_a=Bu... | Exterior wall |
| RoofCase680 | roofCase680 | roofCase680(roughness_a=Buil... | Roof |
Connectors
| Type | Name | Description |
|---|---|---|
| Bus | weaBus | Weather data bus |
Modelica definition
model Case680FF
"Case 600FF, but with increased exterior wall and roof insulation"
extends Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case600FF
(
matExtWal = extWalCase680,
roof = roofCase680,
redeclare Buildings.ThermalZones.Detailed.Validation.BESTEST.Data.StandardResultsFreeFloating
staRes(
minT( Min=-8.1+273.15, Max=-5.7+273.15, Mean=-6.9+273.15),
maxT( Min=69.8+273.15, Max=78.5+273.15, Mean=73.0+273.15),
meanT(Min=30.2+273.15, Max=33.3+273.15, Mean=31.8+273.15)));
parameter Buildings.ThermalZones.Detailed.Validation.BESTEST.Data.ExteriorWallCase680
extWalCase680(
roughness_a=Buildings.HeatTransfer.Types.SurfaceRoughness.Rough)
"Exterior wall";
parameter Buildings.ThermalZones.Detailed.Validation.BESTEST.Data.RoofCase680
roofCase680(
roughness_a=Buildings.HeatTransfer.Types.SurfaceRoughness.Rough)
"Roof";
end Case680FF;
Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case685
Case 600, but with single setpoint for heating and cooling
Information
This model is the case 685 of the BESTEST validation suite. Case 685 differs from case 600 in that it has single heating and cooling setpoint.
- Heat = on if zone temperature is below 20°C
- Cool = on if zone temperature is above 20°C
Extends from Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case600 (Case 600FF, but with dual-setpoint for heating and cooling).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Angle | S_ | Buildings.Types.Azimuth.S | Azimuth for south walls [rad] |
| Angle | E_ | Buildings.Types.Azimuth.E | Azimuth for east walls [rad] |
| Angle | W_ | Buildings.Types.Azimuth.W | Azimuth for west walls [rad] |
| Angle | N_ | Buildings.Types.Azimuth.N | Azimuth for north walls [rad] |
| Angle | C_ | Buildings.Types.Tilt.Ceiling | Tilt for ceiling [rad] |
| Angle | F_ | Buildings.Types.Tilt.Floor | Tilt for floor [rad] |
| Angle | Z_ | Buildings.Types.Tilt.Wall | Tilt for wall [rad] |
| Integer | nConExtWin | 1 | Number of constructions with a window |
| Integer | nConBou | 1 | Number of surface that are connected to constructions that are modeled inside the room |
| Generic | matExtWal | Exterior wall | |
| Generic | matFlo | Floor | |
| Generic | roof | Roof | |
| Win600 | window600 | redeclare parameter Building... | Window |
Connectors
| Type | Name | Description |
|---|---|---|
| Bus | weaBus | Weather data bus |
Modelica definition
model Case685
"Case 600, but with single setpoint for heating and cooling"
extends Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case600(
redeclare BaseClasses.DaySchedule TSetCoo(table=[0.0,273.15 + 20.1]),
redeclare BaseClasses.DaySchedule TSetHea(table=[0.0,273.15 + 19.9]),
staRes(
annualHea(Min=4.532*3.6e9, Max=5.042*3.6e9, Mean=4.763*3.6e9),
annualCoo(Min=-8.238*3.6e9, Max=-9.130*3.6e9, Mean=-8.886*3.6e9),
peakHea(Min=3.032*1000, Max=3.374*1000, Mean=3.183*1000),
peakCoo(Min=-6.071*1000, Max=-7.159*1000, Mean=-6.743*1000)),
heaCri(lowerLimit=4.08*3.6e9, upperLimit=5.75*3.6e9),
cooCri(lowerLimit=-7.7*3.6e9, upperLimit=-10.14*3.6e9));
end Case685;
Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case695
Case 600, but with increased exterior wall and roof insulation and single cooling and heating setpoint
Information
This model is the case 695 of the BESTEST validation suite. Case 695 differs from case 600 in that it has increased exterior wall and roof insulation and it has single heating and cooling setpoint.
- Heat = on if zone temperature is below 20°C
- Cool = on if zone temperature is above 20°C
Extends from Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case600 (Case 600FF, but with dual-setpoint for heating and cooling).
Parameters
| Type | Name | Default | Description |
|---|---|---|---|
| Angle | S_ | Buildings.Types.Azimuth.S | Azimuth for south walls [rad] |
| Angle | E_ | Buildings.Types.Azimuth.E | Azimuth for east walls [rad] |
| Angle | W_ | Buildings.Types.Azimuth.W | Azimuth for west walls [rad] |
| Angle | N_ | Buildings.Types.Azimuth.N | Azimuth for north walls [rad] |
| Angle | C_ | Buildings.Types.Tilt.Ceiling | Tilt for ceiling [rad] |
| Angle | F_ | Buildings.Types.Tilt.Floor | Tilt for floor [rad] |
| Angle | Z_ | Buildings.Types.Tilt.Wall | Tilt for wall [rad] |
| Integer | nConExtWin | 1 | Number of constructions with a window |
| Integer | nConBou | 1 | Number of surface that are connected to constructions that are modeled inside the room |
| Generic | matExtWal | extWalCase680 | Exterior wall |
| Generic | matFlo | Floor | |
| Generic | roof | roofCase680 | Roof |
| Win600 | window600 | redeclare parameter Building... | Window |
| ExteriorWallCase680 | extWalCase680 | Exterior wall | |
| RoofCase680 | roofCase680 | Roof |
Connectors
| Type | Name | Description |
|---|---|---|
| Bus | weaBus | Weather data bus |
Modelica definition
model Case695
"Case 600, but with increased exterior wall and roof insulation and single cooling and heating setpoint"
extends Buildings.ThermalZones.Detailed.Validation.BESTEST.Cases6xx.Case600(
redeclare BaseClasses.DaySchedule TSetCoo(table=[0.0,273.15 + 20.1]),
redeclare BaseClasses.DaySchedule TSetHea(table=[0.0,273.15 + 19.9]),
matExtWal = extWalCase680,
roof = roofCase680,
staRes(
annualHea(Min=2.385*3.6e9, Max=2.892*3.6e9, Mean=2.656*3.6e9),
annualCoo(Min=-8.386*3.6e9, Max=-9.172*3.6e9, Mean=-8.912*3.6e9),
peakHea(Min=1.795*1000, Max=2.138*1000, Mean=2.000*1000),
peakCoo(Min=-6.232*1000, Max=-7.541*1000, Mean=-6.979*1000)),
heaCri(lowerLimit=1.7*3.6e9, upperLimit=3.81*3.6e9),
cooCri(lowerLimit=-7.49*3.6e9, upperLimit=-10.58*3.6e9));
parameter Buildings.ThermalZones.Detailed.Validation.BESTEST.Data.ExteriorWallCase680
extWalCase680
"Exterior wall";
parameter Buildings.ThermalZones.Detailed.Validation.BESTEST.Data.RoofCase680
roofCase680
"Roof";
end Case695;